meta-agl-bsp/recipes-kernel/linux/linux-agl.inc

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/linux:"
   2
   3 DEPENDS += "kern-tools-native"
   4
   5 # returns all the elements from the src uri that are .cfg files
   6 def find_cfgs(d):
   7     sources=src_patches(d, True)
   8     sources_list=[]
   9     for s in sources:
  10         if s.endswith('.cfg'):
  11             sources_list.append(s)
  12
  13     return sources_list
  14
  15 do_configure_append () {
  16     [ ! -f .config ] && cp -a ${WORKDIR}/defconfig .config
  17     merge_config.sh -m .config ${@" ".join(find_cfgs(d))}
  18     yes '' | make oldconfig
  19 }
  20
  21 # Extra configuration options for the AGL kernel
  22 SRC_URI_append = "\
  23             file://can-bus.cfg \
  24             file://usb.cfg \
  25             file://uvc.cfg \
  26             file://joystick.cfg \
  27             file://fanotify.cfg \
  28             file://uinput.cfg \
  29             file://hid.cfg \
  30             file://drm.cfg \
  31             file://btusb.cfg \
  32             file://usbaudio.cfg \
  33             file://i2c-led.cfg \
  34             "
  35 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/can-bus.cfg"
  36 # Enable support for usb video class for usb camera devices
  37 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uvc.cfg"
  38 # Enable support for joystick devices
  39 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/joystick.cfg"
  40 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/fanotify.cfg"
  41 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uinput.cfg"
  42 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/hid.cfg"
  43 # Enable DRM support for graphics
  44 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/drm.cfg"
  45 # Enable Bluetooth USB devices
  46 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/btusb.cfg"
  47 # Enable USB audio devices
  48 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/usbaudio.cfg"
  49 # Enable I2C and LED for demontrator
  50 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/i2c-led.cfg"
  51
  52 # Enable required features for the agl-netboot feature
  53 SRC_URI_append_netboot = " file://nbd.cfg \
  54         file://ramdisk.cfg"
  55 KERNEL_CONFIG_FRAGMENTS_append_netboot = " ${WORKDIR}/nbd.cfg ${WORKDIR}/ramdisk.cfg"
  56
  57 # Enable support for TP-Link TL-W722N USB Wifi adapter
  58 SRC_URI_append = " file://ath9k_htc.cfg"
  59 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/ath9k_htc.cfg"
  60
  61 # Enable support for RTLSDR
  62 SRC_URI_append = " file://rtl_sdr.cfg"
  63 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/rtl_sdr.cfg"
  64
  65 # Additional drivers for virtual machines
  66 # OVERRIDES save us some c'n'p below ...
  67 OVERRIDES_prepend_qemux86 = "virtualmachine:"
  68 OVERRIDES_prepend_qemux86-64 = "virtualmachine:"
  69 SRC_URI_append_virtualmachine = " file://vbox-vmware-sata.cfg"
  70 KERNEL_CONFIG_FRAGMENTS_append_virtualmachine = " ${WORKDIR}/vbox-vmware-sata.cfg"
  71
  72 # Enable support for smack
  73 KERNEL_CONFIG_FRAGMENTS_append_with-lsm-smack = "\
  74        ${WORKDIR}/audit.cfg \
  75        ${WORKDIR}/smack.cfg \
  76        ${WORKDIR}/smack-default-lsm.cfg \
  77 "
  78
  79 # snd-aloop support for 4a
  80 SRC_URI_append = " file://4a-sound.cfg"
  81 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/4a-sound.cfg"