meta-agl-bsp/meta-rcar-gen3/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base.inc

   1 require gstreamer1.0-plugins.inc
   2
   3 LICENSE = "GPLv2+ & LGPLv2+"
   4
   5 DEPENDS += "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxv', '', d)}"
   6 DEPENDS += "freetype liboil util-linux"
   7
   8 inherit gettext
   9
  10 PACKAGES_DYNAMIC =+ "^libgst.*"
  11
  12 PACKAGECONFIG ??= " \
  13     ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
  14     ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)} \
  15     orc ivorbis ogg theora vorbis pango \
  16     "
  17
  18 X11DEPENDS = "virtual/libx11 libsm libxrender"
  19 X11ENABLEOPTS = "--enable-x --enable-xvideo --enable-xshm"
  20 X11DISABLEOPTS = "--disable-x --disable-xvideo --disable-xshm"
  21 PACKAGECONFIG[x11]     = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}"
  22 PACKAGECONFIG[alsa]    = "--enable-alsa,--disable-alsa,alsa-lib"
  23 PACKAGECONFIG[ivorbis] = "--enable-ivorbis,--disable-ivorbis,tremor"
  24 PACKAGECONFIG[ogg]     = "--enable-ogg,--disable-ogg,libogg"
  25 PACKAGECONFIG[theora]  = "--enable-theora,--disable-theora,libtheora"
  26 PACKAGECONFIG[vorbis]  = "--enable-vorbis,--disable-vorbis,libvorbis"
  27 PACKAGECONFIG[pango]   = "--enable-pango,--disable-pango,pango"
  28 # libvisual do not seem to exist anywhere in OE
  29 PACKAGECONFIG[visual]  = "--enable-libvisual,--disable-libvisual,libvisual"
  30 PACKAGECONFIG[cdparanoia] = "--enable-cdparanoia,--disable-cdparanoia,cdparanoia"
  31
  32 EXTRA_OECONF += " \
  33     --disable-freetypetest \
  34 "
  35
  36 FILES_${MLPREFIX}libgsttag-1.0 += "${datadir}/gst-plugins-base/1.0/license-translations.dict"
  37
  38 CACHED_CONFIGUREVARS_append_x86 = " ac_cv_header_emmintrin_h=no ac_cv_header_xmmintrin_h=no"
  39
  40 do_compile_prepend() {
  41         export GIR_EXTRA_LIBS_PATH="${B}/gst-libs/gst/tag/.libs:${B}/gst-libs/gst/video/.libs:${B}/gst-libs/gst/audio/.libs"
  42 }