meta-agl-bsp/meta-rcar-gen3/recipes-multimedia/gstreamer/gstreamer1.0-omx.inc

   1 SUMMARY = "OpenMAX IL plugins for GStreamer"
   2 SECTION = "multimedia"
   3 LICENSE = "LGPLv2.1"
   4 LICENSE_FLAGS = "commercial"
   5 HOMEPAGE = "http://www.gstreamer.net/"
   6 DEPENDS = "gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad"
   7 RDEPENDS_${PN} = "libomxil"
   8
   9 inherit autotools pkgconfig gettext
  10
  11 acpaths = "-I ${S}/common/m4 -I ${S}/m4"
  12
  13 PR = "r1"
  14
  15 GSTREAMER_1_0_OMX_TARGET ?= "bellagio"
  16 GSTREAMER_1_0_OMX_CORE_NAME ?= "${libdir}/libomxil-bellagio.so.0"
  17
  18 EXTRA_OECONF += "--disable-valgrind --with-omx-target=${GSTREAMER_1_0_OMX_TARGET}"
  19
  20 python __anonymous () {
  21     omx_target = d.getVar("GSTREAMER_1_0_OMX_TARGET", True)
  22     if omx_target in ['generic', 'bellagio']:
  23         # Bellagio headers are incomplete (they are missing the OMX_VERSION_MAJOR,#
  24         # OMX_VERSION_MINOR, OMX_VERSION_REVISION, and OMX_VERSION_STEP macros);
  25         # appending a directory path to gst-omx' internal OpenMAX IL headers fixes this
  26         d.appendVar("CFLAGS", " -I${S}/omx/openmax")
  27     elif omx_target == "rpi":
  28         # Dedicated Raspberry Pi OpenMAX IL support makes this package machine specific
  29         d.setVar("PACKAGE_ARCH", d.getVar("MACHINE_ARCH", True))
  30 }
  31
  32 set_omx_core_name() {
  33         sed -i -e "s;^core-name=.*;core-name=${GSTREAMER_1_0_OMX_CORE_NAME};" "${D}${sysconfdir}/xdg/gstomx.conf"
  34 }
  35 do_install[postfuncs] += " set_omx_core_name "
  36
  37 FILES_${PN} += "${libdir}/gstreamer-1.0/*.so"
  38 FILES_${PN}-dbg += "${libdir}/gstreamer-1.0/.debug"
  39 FILES_${PN}-dev += "${libdir}/gstreamer-1.0/*.la"
  40 FILES_${PN}-staticdev += "${libdir}/gstreamer-1.0/*.a"
  41