meta-agl-bsp/meta-rcar-gen3/recipes-bsp/optee/optee-user-app-template_git.bb

   1 SUMMARY = "OP-TEE user_app_template"
   2
   3 LICENSE = "GPLv2"
   4 LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=cd95ab417e23b94f381dafc453d70c30"
   5
   6 PACKAGE_ARCH = "${MACHINE_ARCH}"
   7
   8 inherit python3native
   9
  10 PV = "0.1+git${SRCPV}"
  11
  12 SRCREV = "0.1"
  13
  14 SRC_URI = " \
  15     git://github.com/iotbzh/optee_user_app_template;branch=master;protocol=https \
  16 "
  17
  18 COMPATIBLE_MACHINE = "(salvator-x|h3ulcb|m3ulcb|m3nulcb|ebisu)"
  19 PLATFORM = "rcar"
  20
  21 DEPENDS = "optee-os optee-client python-pycrypto-native"
  22
  23 CFLAGS += "-Wno-extra -Wno-error=format"
  24 TARGET_CFLAGS += "-Wno-extra -Wno-error=format"
  25
  26 TARGET_CC_ARCH += "${LDFLAGS}"
  27 INSANE_SKIP:${PN} = "ldflags"
  28
  29 TA_DEV_KIT_DIR = "${STAGING_DIR_TARGET}/usr/share/optee/export-ta_arm64"
  30
  31 OPTEE_CLIENT_EXPORT = "${STAGING_DIR_TARGET}/usr"
  32
  33 TEEC_EXPORT = "${STAGING_DIR_TARGET}/usr"
  34
  35 S = "${WORKDIR}/git"
  36 EXTRA_OEMAKE = "\
  37                 TEEC_EXPORT=${TEEC_EXPORT} \
  38                 OPTEE_CLIENT_EXPORT=${OPTEE_CLIENT_EXPORT} \
  39                 TA_DEV_KIT_DIR=${TA_DEV_KIT_DIR} \
  40                 HOST_CROSS_COMPILE=${TARGET_PREFIX} \
  41                 TA_CROSS_COMPILE=${TARGET_PREFIX} \
  42                 PLATFORM=${PLATFORM} \
  43                 V=1 \
  44                 "
  45
  46 do_compile() {
  47     oe_runmake
  48 }
  49
  50 do_install () {
  51     mkdir -p ${D}${nonarch_base_libdir}/optee_armtz
  52     mkdir -p ${D}${bindir}
  53     install -D -p -m0755 ${S}/out/ca/* ${D}${bindir}
  54     install -D -p -m0444 ${S}/out/ta/* ${D}${nonarch_base_libdir}/optee_armtz
  55 }
  56
  57 FILES:${PN} += "${nonarch_base_libdir}/optee_armtz/"