meta-agl-bsp/meta-rcar-gen3/recipes-bsp/optee/optee-examples_git.bb

   1 SUMMARY = "OP-TEE examples"
   2
   3 LICENSE = "GPLv2"
   4 LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=cd95ab417e23b94f381dafc453d70c30"
   5
   6
   7 PACKAGE_ARCH = "${MACHINE_ARCH}"
   8
   9 inherit python3native
  10
  11 PV = "3.6.0+git${SRCPV}"
  12
  13 SRCREV = "292da2fd8db0176e0e96989268c63ef9ab910a6c"
  14
  15 SRC_URI = " \
  16     git://github.com/linaro-swg/optee_examples;branch=master;name=master;protocol=https \
  17     file://0001-secure_storage-ta-Add-a-missing-include-file.patch \
  18 "
  19
  20 COMPATIBLE_MACHINE = "(salvator-x|h3ulcb|m3ulcb|m3nulcb|ebisu)"
  21 PLATFORM = "rcar"
  22
  23 DEPENDS = "optee-os optee-client python-pycrypto-native"
  24
  25 CFLAGS += "-Wno-extra -Wno-error=format"
  26 TARGET_CFLAGS += "-Wno-extra -Wno-error=format"
  27
  28 TARGET_CC_ARCH += "${LDFLAGS}"
  29 INSANE_SKIP:${PN} = "ldflags"
  30
  31 TA_DEV_KIT_DIR = "${STAGING_DIR_TARGET}/usr/share/optee/export-ta_arm64"
  32
  33 OPTEE_CLIENT_EXPORT = "${STAGING_DIR_TARGET}/usr"
  34
  35 TEEC_EXPORT = "${STAGING_DIR_TARGET}/usr"
  36
  37 S = "${WORKDIR}/git"
  38 EXTRA_OEMAKE = "\
  39                 TEEC_EXPORT=${TEEC_EXPORT} \
  40                 OPTEE_CLIENT_EXPORT=${OPTEE_CLIENT_EXPORT} \
  41                 TA_DEV_KIT_DIR=${TA_DEV_KIT_DIR} \
  42                 HOST_CROSS_COMPILE=${TARGET_PREFIX} \
  43                 TA_CROSS_COMPILE=${TARGET_PREFIX} \
  44                 PLATFORM=${PLATFORM} \
  45                 V=1 \
  46                 "
  47
  48 do_compile() {
  49     oe_runmake
  50 }
  51
  52 do_install () {
  53     mkdir -p ${D}${nonarch_base_libdir}/optee_armtz
  54     mkdir -p ${D}${bindir}
  55     install -D -p -m0755 ${S}/out/ca/* ${D}${bindir}
  56     install -D -p -m0444 ${S}/out/ta/* ${D}${nonarch_base_libdir}/optee_armtz
  57     mkdir -p ${D}${includedir}
  58     cp ${S}/hello_world/ta/include/* ${D}${includedir}
  59 }
  60
  61 FILES:${PN} += "${nonarch_base_libdir}/optee_armtz/"