meta-agl-bsp/meta-rcar-gen3/recipes-backport/gstreamer_bp_krogoth/gstreamer1.0-plugins.inc

   1 SUMMARY = "Plugins for the GStreamer multimedia framework 1.x"
   2 HOMEPAGE = "http://gstreamer.freedesktop.org/"
   3 BUGTRACKER = "https://bugzilla.gnome.org/enter_bug.cgi?product=Gstreamer"
   4 SECTION = "multimedia"
   5
   6 DEPENDS = "gstreamer1.0 glib-2.0-native"
   7
   8 inherit autotools pkgconfig upstream-version-is-even gobject-introspection
   9
  10 acpaths = "-I ${S}/common/m4 -I ${S}/m4"
  11
  12 LIBV = "1.0"
  13 require gst-plugins-package.inc
  14
  15 # Orc enables runtime JIT compilation of data processing routines from Orc
  16 # bytecode to SIMD instructions for various architectures (currently SSE, MMX,
  17 # MIPS, Altivec and NEON are supported).
  18
  19 GSTREAMER_ORC ?= "orc"
  20
  21 PACKAGECONFIG[debug] = "--enable-debug,--disable-debug"
  22 PACKAGECONFIG[orc] = "--enable-orc,--disable-orc,orc orc-native"
  23 PACKAGECONFIG[valgrind] = "--enable-valgrind,--disable-valgrind,valgrind"
  24
  25 export ORCC = "${STAGING_DIR_NATIVE}${bindir}/orcc"
  26
  27 EXTRA_OECONF = " \
  28     --disable-examples \
  29 "
  30
  31 SRC_URI_append = " file://0001-introspection.m4-prefix-pkgconfig-paths-with-PKG_CON.patch"
  32
  33 delete_pkg_m4_file() {
  34         # This m4 file is out of date and is missing PKG_CONFIG_SYSROOT_PATH tweaks which we need for introspection
  35         rm "${S}/common/m4/pkg.m4" || true
  36 }
  37
  38 do_configure[prefuncs] += " delete_pkg_m4_file"
  39
  40 PACKAGES_DYNAMIC = "^${PN}-.*"