meta-agl-bsp/meta-rcar-gen3/recipes-backport/gstreamer_bp_krogoth/gstreamer1.0-plugins-ugly_git.bb

   1 DEFAULT_PREFERENCE = "-1"
   2
   3 include gstreamer1.0-plugins-ugly.inc
   4
   5 LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
   6                     file://tests/check/elements/xingmux.c;beginline=1;endline=21;md5=4c771b8af188724855cb99cadd390068"
   7
   8 SRC_URI = " \
   9     git://anongit.freedesktop.org/gstreamer/gst-plugins-ugly;name=base \
  10     git://anongit.freedesktop.org/gstreamer/common;destsuffix=git/common;name=common \
  11 "
  12
  13 PV = "1.7.2+git${SRCPV}"
  14
  15 UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>(\d+(\.\d+)+))"
  16
  17 SRCREV_base = "8bdb68edbc605e21314b608e7a39bdbaab7302b8"
  18 SRCREV_common = "b64f03f6090245624608beb5d2fff335e23a01c0"
  19 SRCREV_FORMAT = "base"
  20
  21 S = "${WORKDIR}/git"
  22
  23 # The mpg123 plugin was added prior to the 1.7.2 release
  24 # https://cgit.freedesktop.org/gstreamer/gst-plugins-ugly/commit/?id=43bd45ba991ef3247957ca37cdcb52f4b8c0acb1
  25 PACKAGECONFIG[mpg123] = "--enable-mpg123,--disable-mpg123,mpg123"
  26
  27 do_configure_prepend() {
  28         ${S}/autogen.sh --noconfigure
  29 }
  30
  31 # In 1.7.2, the mpg123 plugin was moved from -bad to -ugly
  32 # https://cgit.freedesktop.org/gstreamer/gst-plugins-bad/commit/?id=08d8aefcdaaf89ecb6dd53ec1e4f95cd42d01664
  33 # https://cgit.freedesktop.org/gstreamer/gst-plugins-ugly/commit/?id=43bd45ba991ef3247957ca37cdcb52f4b8c0acb1
  34
  35 PACKAGESPLITFUNCS_append = " handle_mpg123_rename "
  36
  37 python handle_mpg123_rename () {
  38     d.setVar('RPROVIDES_gstreamer1.0-plugins-ugly-mpg123', 'gstreamer1.0-plugins-bad-mpg123')
  39     d.setVar('RREPLACES_gstreamer1.0-plugins-ugly-mpg123', 'gstreamer1.0-plugins-bad-mpg123')
  40     d.setVar('RCONFLICTS_gstreamer1.0-plugins-ugly-mpg123', 'gstreamer1.0-plugins-bad-mpg123')
  41 }