meta-agl-bsp/meta-rcar-gen3/recipes-backport/gstreamer_bp_krogoth/gstreamer1.0-plugins-base.inc

   1 require gstreamer1.0-plugins.inc
   2
   3 SRC_URI_append = "\
   4     file://0001-Makefile.am-don-t-hardcode-libtool-name-when-running.patch \
   5     file://0002-Makefile.am-prefix-calls-to-pkg-config-with-PKG_CONF.patch \
   6     file://0003-riff-add-missing-include-directories-when-calling-in.patch \
   7     file://0004-rtsp-drop-incorrect-reference-to-gstreamer-sdp-in-Ma.patch \
   8 "
   9
  10 LICENSE = "GPLv2+ & LGPLv2+"
  11
  12 DEPENDS += "iso-codes util-linux zlib"
  13
  14 inherit gettext
  15
  16 PACKAGES_DYNAMIC =+ "^libgst.*"
  17
  18 PACKAGECONFIG ??= " \
  19     ${GSTREAMER_ORC} \
  20     ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)} \
  21     ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
  22     gio-unix-2.0 ivorbis ogg pango theora vorbis \
  23 "
  24
  25 X11DEPENDS = "virtual/libx11 libsm libxrender libxv"
  26 X11ENABLEOPTS = "--enable-x --enable-xvideo --enable-xshm"
  27 X11DISABLEOPTS = "--disable-x --disable-xvideo --disable-xshm"
  28
  29 PACKAGECONFIG[alsa]         = "--enable-alsa,--disable-alsa,alsa-lib"
  30 PACKAGECONFIG[cdparanoia]   = "--enable-cdparanoia,--disable-cdparanoia,cdparanoia"
  31 PACKAGECONFIG[gio-unix-2.0] = "--enable-gio_unix_2_0,--disable-gio_unix_2_0,glib-2.0"
  32 PACKAGECONFIG[ivorbis]      = "--enable-ivorbis,--disable-ivorbis,tremor"
  33 PACKAGECONFIG[ogg]          = "--enable-ogg,--disable-ogg,libogg"
  34 PACKAGECONFIG[pango]        = "--enable-pango,--disable-pango,pango"
  35 PACKAGECONFIG[theora]       = "--enable-theora,--disable-theora,libtheora"
  36 PACKAGECONFIG[visual]       = "--enable-libvisual,--disable-libvisual,libvisual"
  37 PACKAGECONFIG[vorbis]       = "--enable-vorbis,--disable-vorbis,libvorbis"
  38 PACKAGECONFIG[x11]          = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}"
  39
  40 EXTRA_OECONF += " \
  41     --enable-zlib \
  42 "
  43
  44 CACHED_CONFIGUREVARS_append_x86 = " ac_cv_header_emmintrin_h=no ac_cv_header_xmmintrin_h=no"
  45
  46 FILES_${MLPREFIX}libgsttag-1.0 += "${datadir}/gst-plugins-base/1.0/license-translations.dict"
  47
  48 do_compile_prepend() {
  49         export GIR_EXTRA_LIBS_PATH="${B}/gst-libs/gst/tag/.libs:${B}/gst-libs/gst/video/.libs:${B}/gst-libs/gst/audio/.libs:${B}/gst-libs/gst/rtp/.libs"
  50 }