meta-agl-bsp/meta-rcar-gen3/recipes-backport/gstreamer_bp_krogoth/gstreamer1.0-libav.inc

   1 SUMMARY = "Libav-based GStreamer 1.x plugin"
   2 HOMEPAGE = "http://gstreamer.freedesktop.org/"
   3 SECTION = "multimedia"
   4
   5 LICENSE = "GPLv2+ & LGPLv2+ & ( (GPLv2+ & LGPLv2.1+) | (GPLv3+ & LGPLv3+) )"
   6 LICENSE_FLAGS = "commercial"
   7
   8 DEPENDS = "gstreamer1.0 gstreamer1.0-plugins-base zlib bzip2 xz"
   9
  10 inherit autotools pkgconfig upstream-version-is-even
  11
  12 # CAUTION: Using the system libav is not recommended. Since the libav API is changing all the time,
  13 # compilation errors (and other, more subtle bugs) can happen. It is usually better to rely on the
  14 # libav copy included in the gst-libav package.
  15 PACKAGECONFIG ??= "orc yasm"
  16
  17 PACKAGECONFIG[gpl] = "--enable-gpl,--disable-gpl,"
  18 PACKAGECONFIG[libav] = "--with-system-libav,,libav"
  19 PACKAGECONFIG[orc] = "--enable-orc,--disable-orc,orc"
  20 PACKAGECONFIG[yasm] = "--enable-yasm,--disable-yasm,yasm-native"
  21
  22 GSTREAMER_1_0_DEBUG ?= "--disable-debug"
  23
  24 LIBAV_EXTRA_CONFIGURE = "--with-libav-extra-configure"
  25
  26 LIBAV_EXTRA_CONFIGURE_COMMON_ARG = "--target-os=linux \
  27   --cc='${CC}' --as='${CC}' --ld='${CC}' --nm='${NM}' --ar='${AR}' \
  28   --ranlib='${RANLIB}' \
  29   ${GSTREAMER_1_0_DEBUG} \
  30   --cross-prefix='${HOST_PREFIX}'"
  31
  32 LIBAV_EXTRA_CONFIGURE_COMMON = \
  33 '${LIBAV_EXTRA_CONFIGURE}="${LIBAV_EXTRA_CONFIGURE_COMMON_ARG}"'
  34
  35 EXTRA_OECONF = "${LIBAV_EXTRA_CONFIGURE_COMMON}"
  36
  37 FILES_${PN} += "${libdir}/gstreamer-1.0/*.so"
  38 FILES_${PN}-dev += "${libdir}/gstreamer-1.0/*.la"
  39 FILES_${PN}-staticdev += "${libdir}/gstreamer-1.0/*.a"
  40
  41 # http://errors.yoctoproject.org/Errors/Details/20493/
  42 ARM_INSTRUCTION_SET_armv4 = "arm"
  43 ARM_INSTRUCTION_SET_armv5 = "arm"
  44
  45 # ffmpeg/libav disables PIC on some platforms (e.g. x86-32)
  46 INSANE_SKIP_${PN} = "textrel"