meta-agl-bsp/meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi_4.4.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/${BPN}:"
   2
   3 LINUX_VERSION = "4.4.16"
   4
   5 SRCREV = "26550dcfb86b0308a99f726abbfb55abb1b0f78c"
   6
   7 SRC_URI_append = "\
   8         ${@base_conditional('USE_FAYTECH_MONITOR', '1', 'file://0002-faytech-fix-rpi.patch', '', d)} \
   9 "
  10
  11 do_configure_append_smack() {
  12     # SMACK and Co
  13     kernel_configure_variable IP_NF_SECURITY m
  14     kernel_configure_variable IP6_NF_SECURITY m
  15     kernel_configure_variable EXT2_FS_SECURITY y
  16     kernel_configure_variable EXT3_FS_SECURITY y
  17     kernel_configure_variable EXT4_FS_SECURITY y
  18     kernel_configure_variable SECURITY y
  19     kernel_configure_variable SECURITY_SMACK y
  20     kernel_configure_variable TMPFS_XATTR y
  21     kernel_configure_variable DEFAULT_SECURITY "smack"
  22     kernel_configure_variable DEFAULT_SECURITY_SMACK y
  23     kernel_configure_variable FANOTIFY_ACCESS_PERMISSIONS y
  24 }
  25
  26 do_configure_append_netboot() {
  27     # NBD for netboot
  28     kernel_configure_variable BLK_DEV_NBD y
  29     # ramblk for inird
  30     kernel_configure_variable BLK_DEV_RAM y
  31 }
  32
  33 do_configure_append_sota() {
  34     # ramblk for inird
  35     kernel_configure_variable BLK_DEV_RAM y
  36 }
  37
  38 do_configure_append() {
  39
  40     # VC4 Wayland/Weston
  41     kernel_configure_variable I2C_BCM2835 y
  42     kernel_configure_variable DRM y
  43     kernel_configure_variable DRM_PANEL_RASPBERRYPI_TOUCHSCREEN y
  44     kernel_configure_variable DRM_VC4 y
  45     kernel_configure_variable FB_BCM2708 n
  46
  47     # KEEP until fixed upstream:
  48       # Keep this the last line
  49       # Remove all modified configs and add the rest to .config
  50       sed -e "${CONF_SED_SCRIPT}" < '${WORKDIR}/defconfig' >> '${B}/.config'
  51
  52       yes '' | oe_runmake oldconfig
  53       kernel_do_configure
  54 }
  55
  56
  57 CMDLINE_append = " usbhid.mousepoll=0"
  58
  59 KERNEL_MODULE_AUTOLOAD += "snd-bcm2835"
  60 KERNEL_MODULE_AUTOLOAD += "hid-multitouch"
  61
  62 RDEPENDS_${PN} += "kernel-module-snd-bcm2835"
  63 PACKAGES += "kernel-module-snd-bcm2835"