meta-agl-bsp/meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi_4.4.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/${BPN}:"
   2
   3 LINUX_VERSION = "4.4.16"
   4
   5 SRCREV = "26550dcfb86b0308a99f726abbfb55abb1b0f78c"
   6
   7 SRC_URI_append = "\
   8         ${@base_conditional('USE_FAYTECH_MONITOR', '1', 'file://0002-faytech-fix-rpi.patch', '', d)} \
   9 "
  10
  11 #-------------------------------------------------------------------------
  12 # smack patches for handling bluetooth
  13
  14 SRC_URI_append_smack = "\
  15        file://0001-Smack-File-receive-for-sockets.patch \
  16        file://0002-smack-fix-cache-of-access-labels.patch \
  17        file://0003-Smack-ignore-null-signal-in-smack_task_kill.patch \
  18        file://0004-Smack-Assign-smack_known_web-label-for-kernel-thread.patch \
  19 "
  20
  21
  22
  23 do_configure_append_smack() {
  24     # SMACK and Co
  25     kernel_configure_variable IP_NF_SECURITY m
  26     kernel_configure_variable IP6_NF_SECURITY m
  27     kernel_configure_variable EXT2_FS_SECURITY y
  28     kernel_configure_variable EXT3_FS_SECURITY y
  29     kernel_configure_variable EXT4_FS_SECURITY y
  30     kernel_configure_variable SECURITY y
  31     kernel_configure_variable SECURITY_SMACK y
  32     kernel_configure_variable TMPFS_XATTR y
  33     kernel_configure_variable DEFAULT_SECURITY "smack"
  34     kernel_configure_variable DEFAULT_SECURITY_SMACK y
  35     kernel_configure_variable FANOTIFY_ACCESS_PERMISSIONS y
  36 }
  37
  38 do_configure_append_netboot() {
  39     # NBD for netboot
  40     kernel_configure_variable BLK_DEV_NBD y
  41     # ramblk for inird
  42     kernel_configure_variable BLK_DEV_RAM y
  43 }
  44
  45 do_configure_append_sota() {
  46     # ramblk for inird
  47     kernel_configure_variable BLK_DEV_RAM y
  48 }
  49
  50 do_configure_append() {
  51
  52     # VC4 Wayland/Weston
  53     kernel_configure_variable I2C_BCM2835 y
  54     kernel_configure_variable DRM y
  55     kernel_configure_variable DRM_PANEL_RASPBERRYPI_TOUCHSCREEN y
  56     kernel_configure_variable DRM_VC4 y
  57     kernel_configure_variable FB_BCM2708 n
  58
  59     # Enable support for TP-Link TL-W722N USB Wifi adapter
  60     kernel_configure_variable CONFIG_ATH_CARDS m
  61     kernel_configure_variable CONFIG_ATH9K_HTC m
  62
  63     # Enable support for RTLSDR
  64     kernel_configure_variable CONFIG_MEDIA_USB_SUPPORT y
  65     kernel_configure_variable CONFIG_MEDIA_DIGITAL_TV_SUPPORT y
  66     kernel_configure_variable CONFIG_DVB_USB_V2 m
  67     kernel_configure_variable CONFIG_DVB_USB_RTL28XXU m
  68
  69     # KEEP until fixed upstream:
  70       # Keep this the last line
  71       # Remove all modified configs and add the rest to .config
  72       sed -e "${CONF_SED_SCRIPT}" < '${WORKDIR}/defconfig' >> '${B}/.config'
  73
  74       yes '' | oe_runmake oldconfig
  75       kernel_do_configure
  76 }
  77
  78 CMDLINE_DEBUG = ""
  79 CMDLINE_append = " usbhid.mousepoll=0"
  80
  81 # Add options to allow CMA to operate
  82 CMDLINE_append = ' ${@base_conditional("ENABLE_CMA", "1", "coherent_pool=6M smsc95xx.turbo_mode=N", "", d)}'
  83
  84 KERNEL_MODULE_AUTOLOAD += "snd-bcm2835"
  85 KERNEL_MODULE_AUTOLOAD += "hid-multitouch"
  86
  87 RDEPENDS_${PN} += "kernel-module-snd-bcm2835"
  88 PACKAGES += "kernel-module-snd-bcm2835"