meta-agl-bsp/meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi_4.4.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/${BPN}:"
   2
   3 SRC_URI_append = "\
   4         ${@base_conditional('USE_FAYTECH_MONITOR', '1', 'file://0002-faytech-fix-rpi.patch', '', d)} \
   5 "
   6
   7 #-------------------------------------------------------------------------
   8 # smack patches for handling bluetooth
   9
  10 SRC_URI_append_smack = "\
  11        file://0001-Smack-File-receive-for-sockets.patch \
  12        file://0002-smack-fix-cache-of-access-labels.patch \
  13        file://0003-Smack-ignore-null-signal-in-smack_task_kill.patch \
  14        file://0004-Smack-Assign-smack_known_web-label-for-kernel-thread.patch \
  15 "
  16
  17
  18
  19 do_configure_append_smack() {
  20     # SMACK and Co
  21     kernel_configure_variable IP_NF_SECURITY m
  22     kernel_configure_variable IP6_NF_SECURITY m
  23     kernel_configure_variable EXT2_FS_SECURITY y
  24     kernel_configure_variable EXT3_FS_SECURITY y
  25     kernel_configure_variable EXT4_FS_SECURITY y
  26     kernel_configure_variable SECURITY y
  27     kernel_configure_variable SECURITY_SMACK y
  28     kernel_configure_variable TMPFS_XATTR y
  29     kernel_configure_variable DEFAULT_SECURITY "smack"
  30     kernel_configure_variable DEFAULT_SECURITY_SMACK y
  31     kernel_configure_variable FANOTIFY_ACCESS_PERMISSIONS y
  32 }
  33
  34 do_configure_append_netboot() {
  35     # NBD for netboot
  36     kernel_configure_variable BLK_DEV_NBD y
  37     # ramblk for inird
  38     kernel_configure_variable BLK_DEV_RAM y
  39 }
  40
  41 do_configure_append_sota() {
  42     # ramblk for inird
  43     kernel_configure_variable BLK_DEV_RAM y
  44 }
  45
  46 do_configure_append() {
  47
  48     # VC4 Wayland/Weston
  49     kernel_configure_variable I2C_BCM2835 y
  50     kernel_configure_variable DRM y
  51     kernel_configure_variable DRM_PANEL_RASPBERRYPI_TOUCHSCREEN y
  52     kernel_configure_variable DRM_VC4 y
  53     kernel_configure_variable FB_BCM2708 n
  54
  55     # Enable support for TP-Link TL-W722N USB Wifi adapter
  56     kernel_configure_variable CONFIG_ATH_CARDS m
  57     kernel_configure_variable CONFIG_ATH9K_HTC m
  58
  59     # Enable support for RTLSDR
  60     kernel_configure_variable CONFIG_MEDIA_USB_SUPPORT y
  61     kernel_configure_variable CONFIG_MEDIA_DIGITAL_TV_SUPPORT y
  62     kernel_configure_variable CONFIG_DVB_USB_V2 m
  63     kernel_configure_variable CONFIG_DVB_USB_RTL28XXU m
  64
  65     # KEEP until fixed upstream:
  66       # Keep this the last line
  67       # Remove all modified configs and add the rest to .config
  68       sed -e "${CONF_SED_SCRIPT}" < '${WORKDIR}/defconfig' >> '${B}/.config'
  69
  70       yes '' | oe_runmake oldconfig
  71       kernel_do_configure
  72 }
  73
  74 CMDLINE_DEBUG = ""
  75 CMDLINE_append = " usbhid.mousepoll=0"
  76
  77 # Add options to allow CMA to operate
  78 CMDLINE_append = ' ${@base_conditional("ENABLE_CMA", "1", "coherent_pool=6M smsc95xx.turbo_mode=N", "", d)}'
  79
  80 KERNEL_MODULE_AUTOLOAD += "snd-bcm2835"
  81 KERNEL_MODULE_AUTOLOAD += "hid-multitouch"
  82
  83 RDEPENDS_${PN} += "kernel-module-snd-bcm2835"
  84 PACKAGES += "kernel-module-snd-bcm2835"