meta-agl-bsp/meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi_%.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/${BPN}:"
   2
   3 require recipes-kernel/linux/linux-yocto-agl.inc
   4
   5 SRC_URI_append = " \
   6     ${@oe.utils.conditional('USE_FAYTECH_MONITOR', '1', 'file://0002-faytech-fix-rpi.patch', '', d)} \
   7     file://0001-mconf-menuconfig.patch \
   8 "
   9
  10 # Enable support for Pi foundation touchscreen
  11 AGL_KCONFIG_FRAGMENTS += "raspberrypi-panel.cfg"
  12
  13 # Enable bt hci uart
  14 AGL_KCONFIG_FRAGMENTS += "raspberrypi-hciuart.cfg"
  15
  16 # ENABLE NETWORK (built-in)
  17 AGL_KCONFIG_FRAGMENTS += "raspberrypi_network.cfg"
  18
  19 # For Xen
  20 AGL_KCONFIG_FRAGMENTS += " \
  21     ${@bb.utils.contains('AGL_XEN_WANTED','1','xen-be.cfg','',d)} \
  22 "
  23
  24 # Take in account that linux under Xen should use the hvc0 console
  25 SERIAL_OPTION = "${@bb.utils.contains('AGL_XEN_WANTED','1','hvc0','ttyS0,115200',d)}"
  26 SERIAL = "${@oe.utils.conditional("ENABLE_UART", "1", "console=${SERIAL_OPTION}", "", d)}"
  27
  28 CMDLINE_DEBUG = ""
  29
  30 # Xen related option
  31 CMDLINE_append = ' ${@bb.utils.contains('AGL_XEN_WANTED','1','clk_ignore_unused','',d)}'
  32
  33 # Workaround for crash during brcmfmac loading. Disable it at this moment
  34 CMDLINE_append = ' ${@bb.utils.contains('AGL_XEN_WANTED','1','modprobe.blacklist=brcmfmac','',d)}'
  35
  36 CMDLINE_append = " usbhid.mousepoll=0"
  37
  38 # Add options to allow CMA to operate
  39 CMDLINE_append = '${@oe.utils.conditional("ENABLE_CMA", "1", " coherent_pool=6M smsc95xx.turbo_mode=N", "", d)}'
  40
  41 KERNEL_MODULE_AUTOLOAD += "snd-bcm2835"
  42 KERNEL_MODULE_AUTOLOAD += "hid-multitouch"
  43
  44 PACKAGES += "kernel-module-snd-bcm2835"
  45
  46 RDEPENDS_${PN} += "kernel-module-snd-bcm2835"