meta-agl-bsp/meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi_%.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/${BPN}:"
   2
   3 SRC_URI_append = "\
   4         ${@base_conditional('USE_FAYTECH_MONITOR', '1', 'file://0002-faytech-fix-rpi.patch', '', d)} \
   5 "
   6
   7 # Fix CVE-2017-1000364
   8 SRC_URI_append = "\
   9       file://0001-mm-larger-stack-guard-gap-between-vmas.patch \
  10       file://0002-Allow-stack-to-grow-up-to-address-space-limit.patch \
  11       file://0003-mm-fix-new-crash-in-unmapped_area_topdown.patch \
  12 "
  13
  14
  15 do_configure_append_smack() {
  16     # SMACK and Co
  17     kernel_configure_variable IP_NF_SECURITY m
  18     kernel_configure_variable IP6_NF_SECURITY m
  19     kernel_configure_variable EXT2_FS_SECURITY y
  20     kernel_configure_variable EXT3_FS_SECURITY y
  21     kernel_configure_variable EXT4_FS_SECURITY y
  22     kernel_configure_variable SECURITY y
  23     kernel_configure_variable SECURITY_SMACK y
  24     kernel_configure_variable TMPFS_XATTR y
  25     kernel_configure_variable DEFAULT_SECURITY "smack"
  26     kernel_configure_variable DEFAULT_SECURITY_SMACK y
  27     kernel_configure_variable FANOTIFY_ACCESS_PERMISSIONS y
  28 }
  29
  30 do_configure_append_netboot() {
  31     # NBD for netboot
  32     kernel_configure_variable BLK_DEV_NBD y
  33     # ramblk for inird
  34     kernel_configure_variable BLK_DEV_RAM y
  35 }
  36
  37 do_configure_append_sota() {
  38     # ramblk for inird
  39     kernel_configure_variable BLK_DEV_RAM y
  40 }
  41
  42 # can
  43 do_configure_append() {
  44
  45     kernel_configure_variable TASKSTATS y
  46     kernel_configure_variable TASK_DELAY_ACCT y
  47     kernel_configure_variable USER_RETURN_NOTIFIER y
  48     kernel_configure_variable PREEMPT_NOTIFIERS y
  49     kernel_configure_variable CAN m
  50     kernel_configure_variable CAN_RAW m
  51     kernel_configure_variable CAN_BCM m
  52     kernel_configure_variable CAN_GW m
  53     kernel_configure_variable CAN_VCAN m
  54     kernel_configure_variable CAN_SLCAN m
  55     kernel_configure_variable CAN_DEV m
  56     kernel_configure_variable CAN_CALC_BITTIMING y
  57     kernel_configure_variable CAN_MCP251X m
  58     kernel_configure_variable CAN_ESD_USB2 m
  59     kernel_configure_variable CAN_GS_USB m
  60     kernel_configure_variable CAN_KVASER_USB m
  61     kernel_configure_variable CAN_PEAK_USB m
  62     kernel_configure_variable CAN_8DEV_USB m
  63
  64 # not enabled, yet ?
  65 # kernel_configure_variable CAN_LEDS is not set
  66 # kernel_configure_variable CAN_SJA1000 is not set
  67 # kernel_configure_variable CAN_C_CAN is not set
  68 # kernel_configure_variable CAN_M_CAN is not set
  69 # kernel_configure_variable CAN_CC770 is not set
  70 # kernel_configure_variable CAN_EMS_USB is not set
  71 # kernel_configure_variable CAN_SOFTING is not set
  72 # kernel_configure_variable CAN_DEBUG_DEVICES is not set
  73 }
  74
  75 do_configure_append() {
  76
  77     # VC4 Wayland/Weston
  78     kernel_configure_variable I2C_BCM2835 y
  79     kernel_configure_variable DRM y
  80     kernel_configure_variable DRM_PANEL_RASPBERRYPI_TOUCHSCREEN y
  81     kernel_configure_variable DRM_VC4 y
  82     kernel_configure_variable FB_BCM2708 n
  83
  84     # Enable support for TP-Link TL-W722N USB Wifi adapter
  85     kernel_configure_variable ATH_CARDS m
  86     kernel_configure_variable ATH9K_HTC m
  87
  88     # Enable support for RTLSDR
  89     kernel_configure_variable MEDIA_USB_SUPPORT y
  90     kernel_configure_variable MEDIA_DIGITAL_TV_SUPPORT y
  91     kernel_configure_variable DVB_USB_V2 m
  92     kernel_configure_variable DVB_USB_RTL28XXU m
  93
  94     # KEEP until fixed upstream:
  95       # Keep this the last line
  96       # Remove all modified configs and add the rest to .config
  97       sed -e "${CONF_SED_SCRIPT}" < '${WORKDIR}/defconfig' >> '${B}/.config'
  98
  99       yes '' | oe_runmake oldconfig
 100       kernel_do_configure
 101 }
 102
 103 CMDLINE_DEBUG = ""
 104 CMDLINE_append = " usbhid.mousepoll=0"
 105
 106 # Add options to allow CMA to operate
 107 CMDLINE_append = ' ${@base_conditional("ENABLE_CMA", "1", "coherent_pool=6M smsc95xx.turbo_mode=N", "", d)}'
 108
 109 KERNEL_MODULE_AUTOLOAD += "snd-bcm2835"
 110 KERNEL_MODULE_AUTOLOAD += "hid-multitouch"
 111
 112 RDEPENDS_${PN} += "kernel-module-snd-bcm2835"
 113 PACKAGES += "kernel-module-snd-bcm2835"