meta-agl-bsp/meta-raspberrypi/recipes-kernel/linux/linux-raspberrypi_%.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/${BPN}:"
   2
   3 require recipes-kernel/linux/linux-agl.inc
   4
   5 SRC_URI_append = "\
   6     ${@oe.utils.conditional('USE_FAYTECH_MONITOR', '1', 'file://0002-faytech-fix-rpi.patch', '', d)} \
   7     file://0001-mconf-menuconfig.patch \
   8 "
   9
  10 # For Xen
  11 SRC_URI_append = "\
  12     ${@bb.utils.contains('AGL_XEN_WANTED','1','file://xen-be.cfg','',d)} \
  13 "
  14
  15 #take in account that linux under xen should use the hvc0 console
  16 SERIAL_OPTION = "${@bb.utils.contains('AGL_XEN_WANTED','1','hvc0','ttyS0,115200',d)}"
  17 SERIAL = "${@oe.utils.conditional("ENABLE_UART", "1", "console=${SERIAL_OPTION}", "", d)}"
  18
  19 CMDLINE_DEBUG = ""
  20
  21 # XEN related option
  22 CMDLINE_append = ' ${@bb.utils.contains('AGL_XEN_WANTED','1','clk_ignore_unused','',d)}'
  23
  24 # Workaround for crash during brcmfmac loading. Disable it at this moment
  25 CMDLINE_append = ' ${@bb.utils.contains('AGL_XEN_WANTED','1','modprobe.blacklist=brcmfmac','',d)}'
  26
  27 CMDLINE_append = " usbhid.mousepoll=0"
  28
  29 # Add options to allow CMA to operate
  30 CMDLINE_append = '${@oe.utils.conditional("ENABLE_CMA", "1", " coherent_pool=6M smsc95xx.turbo_mode=N", "", d)}'
  31
  32 KERNEL_MODULE_AUTOLOAD += "snd-bcm2835"
  33 KERNEL_MODULE_AUTOLOAD += "hid-multitouch"
  34
  35 RDEPENDS_${PN} += "kernel-module-snd-bcm2835"
  36 PACKAGES += "kernel-module-snd-bcm2835"
  37
  38 # Enable support for usb video class for usb camera devices
  39 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/uvc.cfg"
  40
  41 # Enable support for joystick devices
  42 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/joystick.cfg"
  43
  44 # Enable support for Pi foundation touchscreen
  45 SRC_URI_append = " file://raspberrypi-panel.cfg"
  46 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/raspberrypi-panel.cfg"
  47
  48 # Enable bt hci uart
  49 SRC_URI_append = " file://raspberrypi-hciuart.cfg"
  50 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/raspberrypi-hciuart.cfg"
  51
  52 # ENABLE NETWORK (built-in)
  53 SRC_URI_append = " file://raspberrypi_network.cfg"
  54 KERNEL_CONFIG_FRAGMENTS_append = " ${WORKDIR}/raspberrypi_network.cfg"