e4880ffedd2c2b86f39d70e8faffd4f2cc7f53ac
[AGL/meta-agl.git] / meta-agl-bsp / meta-raspberrypi / recipes-graphics / mesa / mesa.inc
1 SUMMARY = "A free implementation of the OpenGL API"
2 DESCRIPTION = "Mesa is an open-source implementation of the OpenGL specification - \
3 a system for rendering interactive 3D graphics.  \
4 A variety of device drivers allows Mesa to be used in many different environments \
5 ranging from software emulation to complete hardware acceleration for modern GPUs. \
6 Mesa is used as part of the overall Direct Rendering Infrastructure and X.org \
7 environment."
8
9 HOMEPAGE = "http://mesa3d.org"
10 BUGTRACKER = "https://bugs.freedesktop.org"
11 SECTION = "x11"
12 LICENSE = "MIT"
13 LIC_FILES_CHKSUM = "file://docs/license.html;md5=899fbe7e42d494c7c8c159c7001693d5"
14
15 PE = "2"
16
17 DEPENDS = "expat makedepend-native flex-native bison-native libxml2-native udev"
18
19 PROVIDES = "virtual/libgl virtual/libgles1 virtual/libgles2 virtual/egl virtual/mesa"
20
21 inherit autotools pkgconfig pythonnative gettext distro_features_check
22
23 REQUIRED_DISTRO_FEATURES = "opengl"
24
25 EXTRA_OECONF = "--enable-shared-glapi"
26
27 PACKAGECONFIG ??= "gbm egl gles dri ${MESA_CRYPTO} \
28                 ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}\
29                 ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland', '', d)}\
30                 "
31
32 PACKAGECONFIG[gbm] = "--enable-gbm,--disable-gbm"
33
34 X11_DEPS = "xf86driproto glproto virtual/libx11 libxext libxxf86vm libxdamage libxfixes"
35 PACKAGECONFIG[x11] = "--enable-glx-tls,--disable-glx,${X11_DEPS}"
36 PACKAGECONFIG[xvmc] = "--enable-xvmc,--disable-xvmc,libxvmc"
37 PACKAGECONFIG[wayland] = ",,wayland-native wayland"
38
39 DRIDRIVERS = "swrast"
40 DRIDRIVERS_append_x86 = ",radeon,r200,nouveau,i965,i915"
41 DRIDRIVERS_append_x86-64 = ",radeon,r200,nouveau,i965,i915"
42 PACKAGECONFIG[dri] = "--enable-dri --with-dri-drivers=${DRIDRIVERS}, --disable-dri, dri2proto libdrm"
43 PACKAGECONFIG[dri3] = "--enable-dri3, --disable-dri3, dri3proto presentproto libxshmfence"
44
45 PACKAGECONFIG[gles] = "--enable-gles1 --enable-gles2, --disable-gles1 --disable-gles2"
46
47 EGL_PLATFORMS  = "drm"
48 EGL_PLATFORMS .="${@bb.utils.contains('PACKAGECONFIG', 'x11', ',x11', '', d)}"
49 EGL_PLATFORMS .="${@bb.utils.contains('PACKAGECONFIG', 'wayland', ',wayland', '', d)}"
50 PACKAGECONFIG[egl] = "--enable-egl --with-egl-platforms=${EGL_PLATFORMS}, --disable-egl"
51
52 GALLIUMDRIVERS = "swrast"
53 GALLIUMDRIVERS_LLVM33 = "${@bb.utils.contains('PACKAGECONFIG', 'r600', 'radeonsi,r600', '', d)}"
54 PACKAGECONFIG[r600] = ""
55 GALLIUMDRIVERS_LLVM33_ENABLED = "${@base_version_less_or_equal('MESA_LLVM_RELEASE', '3.2', False, len('${GALLIUMDRIVERS_LLVM33}') > 0, d)}"
56 GALLIUMDRIVERS_LLVM = "r300,svga,nouveau${@',${GALLIUMDRIVERS_LLVM33}' if ${GALLIUMDRIVERS_LLVM33_ENABLED} else ''}"
57 GALLIUMDRIVERS_append_x86 = "${@bb.utils.contains('PACKAGECONFIG', 'gallium-llvm', ',${GALLIUMDRIVERS_LLVM}', '', d)}"
58 GALLIUMDRIVERS_append_x86-64 = "${@bb.utils.contains('PACKAGECONFIG', 'gallium-llvm', ',${GALLIUMDRIVERS_LLVM}', '', d)}"
59 # keep --with-gallium-drivers separate, because when only one of gallium versions is enabled, other 2 were adding --without-gallium-drivers
60 PACKAGECONFIG[gallium]      = "--with-gallium-drivers=${GALLIUMDRIVERS}, --without-gallium-drivers"
61 MESA_LLVM_RELEASE ?= "3.3"
62 PACKAGECONFIG[gallium-llvm] = "--enable-gallium-llvm --enable-llvm-shared-libs, --disable-gallium-llvm, llvm${MESA_LLVM_RELEASE} \
63                                ${@'elfutils' if ${GALLIUMDRIVERS_LLVM33_ENABLED} else ''}"
64 export WANT_LLVM_RELEASE = "${MESA_LLVM_RELEASE}"
65 PACKAGECONFIG[xa]  = "--enable-xa, --disable-xa"
66
67 # Mesa requires one of the following crypto implementation, pick one of them
68 MESA_CRYPTO ??= "openssl"
69 PACKAGECONFIG[openssl] = "--with-sha1=libcrypto,,openssl"
70 PACKAGECONFIG[nettle] = "--with-sha1=libnettle,,nettle"
71 PACKAGECONFIG[gcrypt] = "--with-sha1=libgcrypt,,libgcrypt"
72
73 # llvmpipe is slow if compiled with -fomit-frame-pointer (e.g. -O2)
74 FULL_OPTIMIZATION_append = " -fno-omit-frame-pointer"
75
76 # Multiple virtual/gl providers being built breaks staging
77 EXCLUDE_FROM_WORLD = "1"
78
79 # Remove the mesa dependency on mesa-dev, as mesa is empty
80 RDEPENDS_${PN}-dev = ""
81
82 PACKAGES =+ "libegl-mesa libegl-mesa-dev \
83              libosmesa libosmesa-dev \
84              libgl-mesa libgl-mesa-dev \
85              libglapi libglapi-dev \
86              libgbm libgbm-dev \
87              libgles1-mesa libgles1-mesa-dev \
88              libgles2-mesa libgles2-mesa-dev \
89              libgles3-mesa libgles3-mesa-dev \
90              libwayland-egl libwayland-egl-dev \
91              libxvmcsoftpipe libxvmcsoftpipe-dev \
92              libxatracker libxatracker-dev \
93              mesa-megadriver \
94             "
95
96 do_install_append () {
97     # Drivers never need libtool .la files
98     rm -f ${D}${libdir}/dri/*.la
99     rm -f ${D}${libdir}/egl/*.la
100     rm -f ${D}${libdir}/gallium-pipe/*.la
101     rm -f ${D}${libdir}/gbm/*.la
102     
103     # it was packaged in libdricore9.1.3-1 and preventing upgrades when debian.bbclass was used 
104     rm -f ${D}${sysconfdir}/drirc
105 }
106
107 # For the packages that make up the OpenGL interfaces, inject variables so that
108 # they don't get Debian-renamed (which would remove the -mesa suffix), and
109 # RPROVIDEs/RCONFLICTs on the generic libgl name.
110 python __anonymous() {
111     pkgconfig = (d.getVar('PACKAGECONFIG', True) or "").split()
112     for p in (("egl", "libegl", "libegl1"),
113               ("dri", "libgl", "libgl1"),
114               ("gles", "libgles1", "libglesv1-cm1"),
115               ("gles", "libgles2", "libglesv2-2"),
116               ("gles", "libgles3",)):
117         if not p[0] in pkgconfig:
118             continue
119         fullp = p[1] + "-mesa"
120         pkgs = " ".join(p[1:])
121         d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
122         d.appendVar("RREPLACES_" + fullp, pkgs)
123         d.appendVar("RPROVIDES_" + fullp, pkgs)
124         d.appendVar("RCONFLICTS_" + fullp, pkgs)
125
126         d.appendVar("RRECOMMENDS_" + fullp, " mesa-megadriver")
127
128         # For -dev, the first element is both the Debian and original name
129         fullp += "-dev"
130         pkgs = p[1] + "-dev"
131         d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
132         d.appendVar("RREPLACES_" + fullp, pkgs)
133         d.appendVar("RPROVIDES_" + fullp, pkgs)
134         d.appendVar("RCONFLICTS_" + fullp, pkgs)
135 }
136
137 python mesa_populate_packages() {
138     pkgs = ['mesa', 'mesa-dev', 'mesa-dbg']
139     for pkg in pkgs:
140         d.setVar("RPROVIDES_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
141         d.setVar("RCONFLICTS_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
142         d.setVar("RREPLACES_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
143
144     import re
145     dri_drivers_root = oe.path.join(d.getVar('PKGD', True), d.getVar('libdir', True), "dri")
146     if os.path.isdir(dri_drivers_root):
147         dri_pkgs = os.listdir(dri_drivers_root)
148         lib_name = d.expand("${MLPREFIX}mesa-megadriver")
149         for p in dri_pkgs:
150             m = re.match('^(.*)_dri\.so$', p)
151             if m:
152                 pkg_name = " ${MLPREFIX}mesa-driver-%s" % legitimize_package_name(m.group(1))
153                 d.appendVar("RPROVIDES_%s" % lib_name, pkg_name)
154                 d.appendVar("RCONFLICTS_%s" % lib_name, pkg_name)
155                 d.appendVar("RREPLACES_%s" % lib_name, pkg_name)
156
157     pipe_drivers_root = os.path.join(d.getVar('libdir', True), "gallium-pipe")
158     do_split_packages(d, pipe_drivers_root, '^pipe_(.*)\.so$', 'mesa-driver-pipe-%s', 'Mesa %s pipe driver', extra_depends='')
159 }
160
161 PACKAGESPLITFUNCS_prepend = "mesa_populate_packages "
162
163 PACKAGES_DYNAMIC += "^mesa-driver-.*"
164
165 FILES_${PN} += "${sysconfdir}/drirc"
166 FILES_mesa-megadriver = "${libdir}/dri/*"
167 FILES_libegl-mesa = "${libdir}/libEGL.so.*"
168 FILES_libgbm = "${libdir}/libgbm.so.*"
169 FILES_libgles1-mesa = "${libdir}/libGLESv1*.so.*"
170 FILES_libgles2-mesa = "${libdir}/libGLESv2.so.*"
171 FILES_libgl-mesa = "${libdir}/libGL.so.*"
172 FILES_libglapi = "${libdir}/libglapi.so.*"
173 FILES_libosmesa = "${libdir}/libOSMesa.so.*"
174 FILES_libwayland-egl = "${libdir}/libwayland-egl.so.*"
175 FILES_libxvmcsoftpipe = "${libdir}/libXvMCsoftpipe.so.*"
176 FILES_libxatracker = "${libdir}/libxatracker.so.*"
177
178 FILES_${PN}-dev = "${libdir}/pkgconfig/dri.pc"
179 FILES_libegl-mesa-dev = "${libdir}/libEGL.* ${includedir}/EGL ${includedir}/KHR ${libdir}/pkgconfig/egl.pc"
180 FILES_libgbm-dev = "${libdir}/libgbm.* ${libdir}/pkgconfig/gbm.pc ${includedir}/gbm.h"
181 FILES_libgl-mesa-dev = "${libdir}/libGL.* ${includedir}/GL ${libdir}/pkgconfig/gl.pc"
182 FILES_libglapi-dev = "${libdir}/libglapi.*"
183 FILES_libgles1-mesa-dev = "${libdir}/libGLESv1*.* ${includedir}/GLES ${libdir}/pkgconfig/glesv1*.pc"
184 FILES_libgles2-mesa-dev = "${libdir}/libGLESv2.* ${includedir}/GLES2 ${libdir}/pkgconfig/glesv2.pc"
185 FILES_libgles3-mesa-dev = "${includedir}/GLES3"
186 FILES_libosmesa-dev = "${libdir}/libOSMesa.* ${includedir}/osmesa.h ${libdir}/pkgconfig/osmesa.pc"
187 FILES_libwayland-egl-dev = "${libdir}/pkgconfig/wayland-egl.pc ${libdir}/libwayland-egl.*"
188 FILES_libxvmcsoftpipe-dev = "${libdir}/libXvMCsoftpipe.so ${libdir}/libXvMCsoftpipe.la"
189 FILES_libxatracker-dev = "${libdir}/libxatracker.so ${libdir}/libxatracker.la \
190                           ${includedir}/xa_tracker.h ${includedir}/xa_composite.h ${includedir}/xa_context.h \
191                           ${libdir}/pkgconfig/xatracker.pc"