meta-agl-bsp/meta-raspberrypi/recipes-graphics/mesa/mesa.inc

   1 SUMMARY = "A free implementation of the OpenGL API"
   2 DESCRIPTION = "Mesa is an open-source implementation of the OpenGL specification - \
   3 a system for rendering interactive 3D graphics.  \
   4 A variety of device drivers allows Mesa to be used in many different environments \
   5 ranging from software emulation to complete hardware acceleration for modern GPUs. \
   6 Mesa is used as part of the overall Direct Rendering Infrastructure and X.org \
   7 environment."
   8
   9 HOMEPAGE = "http://mesa3d.org"
  10 BUGTRACKER = "https://bugs.freedesktop.org"
  11 SECTION = "x11"
  12 LICENSE = "MIT"
  13 LIC_FILES_CHKSUM = "file://docs/license.html;md5=725f991a1cc322aa7a0cd3a2016621c4"
  14
  15 PE = "2"
  16
  17 DEPENDS = "expat makedepend-native flex-native bison-native libxml2-native zlib chrpath-replacement-native python3-mako-native gettext-native"
  18 EXTRANATIVEPATH += "chrpath-native"
  19 PROVIDES = " \
  20     ${@bb.utils.contains('PACKAGECONFIG', 'opengl', 'virtual/libgl', '', d)} \
  21     ${@bb.utils.contains('PACKAGECONFIG', 'gles', 'virtual/libgles1 virtual/libgles2', '', d)} \
  22     ${@bb.utils.contains('PACKAGECONFIG', 'egl', 'virtual/egl', '', d)} \
  23     ${@bb.utils.contains('PACKAGECONFIG', 'gbm', 'virtual/libgbm', '', d)} \
  24     virtual/mesa \
  25     "
  26
  27 inherit meson pkgconfig python3native gettext distro_features_check
  28
  29 # Unset these to stop python trying to report the target Python setup
  30 _PYTHON_SYSCONFIGDATA_NAME[unexport] = "1"
  31 STAGING_INCDIR[unexport] = "1"
  32 STAGING_LIBDIR[unexport] = "1"
  33
  34 BBCLASSEXTEND = "native nativesdk"
  35
  36 ANY_OF_DISTRO_FEATURES_class-target = "opengl vulkan"
  37
  38 PLATFORMS ??= "${@bb.utils.filter('PACKAGECONFIG', 'x11 wayland', d)} \
  39                ${@bb.utils.contains('PACKAGECONFIG', 'gbm', 'drm', '', d)} \
  40                surfaceless"
  41
  42 export YOCTO_ALTERNATE_EXE_PATH = "${STAGING_LIBDIR}/llvm${MESA_LLVM_RELEASE}/llvm-config"
  43 export YOCTO_ALTERNATE_MULTILIB_NAME = "${base_libdir}"
  44 export LLVM_CONFIG = "${STAGING_BINDIR_NATIVE}/llvm-config${MESA_LLVM_RELEASE}"
  45 export WANT_LLVM_RELEASE = "${MESA_LLVM_RELEASE}"
  46
  47 MESA_LLVM_RELEASE ?= "${LLVMVERSION}"
  48
  49 EXTRA_OEMESON = " \
  50     -Dshared-glapi=true \
  51     -Dgallium-opencl=disabled \
  52     -Dglx-read-only-text=true \
  53     -Dplatforms='${@",".join("${PLATFORMS}".split())}' \
  54 "
  55
  56 PACKAGECONFIG_class-target ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland vulkan', d)} \
  57                    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'opengl egl gles gbm dri gallium', '', d)} \
  58                    ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'x11 dri3', '', d)} \
  59                    ${@bb.utils.contains('DISTRO_FEATURES', 'x11 vulkan', 'dri3', '', d)} \
  60                    glx-tls \
  61                    "
  62 PACKAGECONFIG_class-native ?= "gbm dri egl opengl glx-tls"
  63 PACKAGECONFIG_class-nativesdk ?= "gbm dri egl opengl glx-tls"
  64
  65 PACKAGECONFIG_remove_libc-musl = "glx-tls"
  66
  67 # "gbm" requires "dri", "opengl"
  68 PACKAGECONFIG[gbm] = "-Dgbm=true,-Dgbm=false"
  69
  70 X11_DEPS = "xorgproto virtual/libx11 libxext libxxf86vm libxdamage libxfixes xrandr"
  71 # "x11" requires "opengl"
  72 PACKAGECONFIG[x11] = ",-Dglx=disabled,${X11_DEPS}"
  73 PACKAGECONFIG[glx-tls] = "-Dglx-tls=true, -Dglx-tls=false"
  74 PACKAGECONFIG[xvmc] = "-Dgallium-xvmc=true,-Dgallium-xvmc=false,libxvmc"
  75 PACKAGECONFIG[wayland] = ",,wayland-native wayland libdrm wayland-protocols"
  76
  77 DRIDRIVERS_class-native = "swrast"
  78 DRIDRIVERS_class-nativesdk = "swrast"
  79 DRIDRIVERS_append_x86_class-target = ",r100,r200,nouveau,i965,i915"
  80 DRIDRIVERS_append_x86-64_class-target = ",r100,r200,nouveau,i965,i915"
  81 # "dri" requires "opengl"
  82 PACKAGECONFIG[dri] = "-Ddri=true -Ddri-drivers=${DRIDRIVERS}, -Ddri=false -Ddri-drivers='', xorgproto libdrm"
  83 PACKAGECONFIG[dri3] = "-Ddri3=true, -Ddri3=false, xorgproto libxshmfence"
  84
  85 # Vulkan drivers need dri3 enabled
  86 # radeon could be enabled as well but requires gallium-llvm with llvm >= 3.9
  87 VULKAN_DRIVERS = ""
  88 VULKAN_DRIVERS_append_x86_class-target = ",intel"
  89 VULKAN_DRIVERS_append_x86-64_class-target = ",intel"
  90 PACKAGECONFIG[vulkan] = "-Dvulkan-drivers=${VULKAN_DRIVERS}, -Dvulkan-drivers='',"
  91
  92 PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=false"
  93
  94 # "gles" requires "opengl"
  95 PACKAGECONFIG[gles] = "-Dgles1=true -Dgles2=true, -Dgles1=false -Dgles2=false"
  96
  97 # "egl" requires "dri", "opengl"
  98 PACKAGECONFIG[egl] = "-Degl=true, -Degl=false"
  99
 100 PACKAGECONFIG[etnaviv] = ""
 101 PACKAGECONFIG[kmsro] = ""
 102 PACKAGECONFIG[vc4] = ""
 103 PACKAGECONFIG[v3d] = ""
 104
 105 GALLIUMDRIVERS = "swrast"
 106 # gallium swrast was found to crash Xorg on startup in x32 qemu
 107 GALLIUMDRIVERS_x86-x32 = ""
 108
 109 GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'etnaviv', ',etnaviv', '', d)}"
 110 GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'kmsro', ',kmsro', '', d)}"
 111 GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'vc4', ',vc4', '', d)}"
 112 GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'v3d', ',v3d', '', d)}"
 113
 114 # radeonsi requires LLVM
 115 GALLIUMDRIVERS_LLVM33 = "${@bb.utils.contains('PACKAGECONFIG', 'r600', ',radeonsi', '', d)}"
 116 GALLIUMDRIVERS_LLVM33_ENABLED = "${@oe.utils.version_less_or_equal('MESA_LLVM_RELEASE', '3.2', False, len('${GALLIUMDRIVERS_LLVM33}') > 0, d)}"
 117 GALLIUMDRIVERS_LLVM = "r300,svga,nouveau${@',${GALLIUMDRIVERS_LLVM33}' if ${GALLIUMDRIVERS_LLVM33_ENABLED} else ''}"
 118
 119 PACKAGECONFIG[r600] = ""
 120
 121 GALLIUMDRIVERS_append = "${@bb.utils.contains('PACKAGECONFIG', 'gallium-llvm', ',${GALLIUMDRIVERS_LLVM}', '', d)}"
 122 GALLIUMDRIVERS_append = "${@bb.utils.contains('PACKAGECONFIG', 'r600', ',r600', '', d)}"
 123 GALLIUMDRIVERS_append = ",virgl"
 124
 125 PACKAGECONFIG[gallium] = "-Dgallium-drivers=${GALLIUMDRIVERS}, -Dgallium-drivers=''"
 126 PACKAGECONFIG[gallium-llvm] = "-Dllvm=true -Dshared-llvm=true, -Dllvm=false, llvm${MESA_LLVM_RELEASE} llvm-native \
 127                                ${@'elfutils' if ${GALLIUMDRIVERS_LLVM33_ENABLED} else ''}"
 128 PACKAGECONFIG[xa]  = "-Dgallium-xa=true, -Dgallium-xa=false"
 129
 130 PACKAGECONFIG[lima] = ""
 131 GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'lima', ',lima', '', d)}"
 132
 133 PACKAGECONFIG[panfrost] = ""
 134 GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'panfrost', ',panfrost', '', d)}"
 135
 136 OSMESA = "${@bb.utils.contains('PACKAGECONFIG', 'gallium', 'gallium', 'classic', d)}"
 137 PACKAGECONFIG[osmesa] = "-Dosmesa=${OSMESA},-Dosmesa=none"
 138
 139 PACKAGECONFIG[unwind] = "-Dlibunwind=true,-Dlibunwind=false,libunwind"
 140
 141 # mesa tries to run cross-built gen_matypes on build machine to get struct size information
 142 EXTRA_OEMESON_append = " -Dasm=false"
 143
 144 # llvmpipe is slow if compiled with -fomit-frame-pointer (e.g. -O2)
 145 FULL_OPTIMIZATION_append = " -fno-omit-frame-pointer"
 146
 147 CFLAGS_append_armv5 = " -DMISSING_64BIT_ATOMICS"
 148
 149 # Remove the mesa dependency on mesa-dev, as mesa is empty
 150 RDEPENDS_${PN}-dev = ""
 151
 152 # Add dependency so that GLES3 header don't need to be added manually
 153 RDEPENDS_libgles2-mesa-dev += "libgles3-mesa-dev"
 154
 155 PACKAGES =+ "libegl-mesa libegl-mesa-dev \
 156              libosmesa libosmesa-dev \
 157              libgl-mesa libgl-mesa-dev \
 158              libglapi libglapi-dev \
 159              libgbm libgbm-dev \
 160              libgles1-mesa libgles1-mesa-dev \
 161              libgles2-mesa libgles2-mesa-dev \
 162              libgles3-mesa libgles3-mesa-dev \
 163              libxatracker libxatracker-dev \
 164              mesa-megadriver mesa-vulkan-drivers \
 165             "
 166
 167 do_install_append () {
 168     # Drivers never need libtool .la files
 169     rm -f ${D}${libdir}/dri/*.la
 170     rm -f ${D}${libdir}/egl/*.la
 171     rm -f ${D}${libdir}/gallium-pipe/*.la
 172     rm -f ${D}${libdir}/gbm/*.la
 173
 174     # it was packaged in libdricore9.1.3-1 and preventing upgrades when debian.bbclass was used
 175     chrpath --delete ${D}${libdir}/dri/*_dri.so || true
 176
 177     # libwayland-egl has been moved to wayland 1.15+
 178     rm -f ${D}${libdir}/libwayland-egl*
 179     rm -f ${D}${libdir}/pkgconfig/wayland-egl.pc
 180 }
 181
 182 # For the packages that make up the OpenGL interfaces, inject variables so that
 183 # they don't get Debian-renamed (which would remove the -mesa suffix), and
 184 # RPROVIDEs/RCONFLICTs on the generic libgl name.
 185 python __anonymous() {
 186     pkgconfig = (d.getVar('PACKAGECONFIG') or "").split()
 187     for p in (("egl", "libegl", "libegl1"),
 188               ("dri", "libgl", "libgl1"),
 189               ("gles", "libgles1", "libglesv1-cm1"),
 190               ("gles", "libgles2", "libglesv2-2"),
 191               ("gles", "libgles3",)):
 192         if not p[0] in pkgconfig:
 193             continue
 194         fullp = p[1] + "-mesa"
 195         pkgs = " ".join(p[1:])
 196         d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
 197         d.appendVar("RREPLACES_" + fullp, pkgs)
 198         d.appendVar("RPROVIDES_" + fullp, pkgs)
 199         d.appendVar("RCONFLICTS_" + fullp, pkgs)
 200
 201         d.appendVar("RRECOMMENDS_" + fullp, " mesa-megadriver")
 202
 203         # For -dev, the first element is both the Debian and original name
 204         fullp += "-dev"
 205         pkgs = p[1] + "-dev"
 206         d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
 207         d.appendVar("RREPLACES_" + fullp, pkgs)
 208         d.appendVar("RPROVIDES_" + fullp, pkgs)
 209         d.appendVar("RCONFLICTS_" + fullp, pkgs)
 210 }
 211
 212 python mesa_populate_packages() {
 213     pkgs = ['mesa', 'mesa-dev', 'mesa-dbg']
 214     for pkg in pkgs:
 215         d.setVar("RPROVIDES_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
 216         d.setVar("RCONFLICTS_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
 217         d.setVar("RREPLACES_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
 218
 219     import re
 220     dri_drivers_root = oe.path.join(d.getVar('PKGD'), d.getVar('libdir'), "dri")
 221     if os.path.isdir(dri_drivers_root):
 222         dri_pkgs = os.listdir(dri_drivers_root)
 223         lib_name = d.expand("${MLPREFIX}mesa-megadriver")
 224         for p in dri_pkgs:
 225             m = re.match(r'^(.*)_dri\.so$', p)
 226             if m:
 227                 pkg_name = " ${MLPREFIX}mesa-driver-%s" % legitimize_package_name(m.group(1))
 228                 d.appendVar("RPROVIDES_%s" % lib_name, pkg_name)
 229                 d.appendVar("RCONFLICTS_%s" % lib_name, pkg_name)
 230                 d.appendVar("RREPLACES_%s" % lib_name, pkg_name)
 231
 232     pipe_drivers_root = os.path.join(d.getVar('libdir'), "gallium-pipe")
 233     do_split_packages(d, pipe_drivers_root, r'^pipe_(.*)\.so$', 'mesa-driver-pipe-%s', 'Mesa %s pipe driver', extra_depends='')
 234 }
 235
 236 PACKAGESPLITFUNCS_prepend = "mesa_populate_packages "
 237
 238 PACKAGES_DYNAMIC += "^mesa-driver-.*"
 239
 240 FILES_mesa-megadriver = "${libdir}/dri/* ${datadir}/drirc.d/00-mesa-defaults.conf"
 241 FILES_mesa-vulkan-drivers = "${libdir}/libvulkan_*.so ${datadir}/vulkan"
 242 FILES_libegl-mesa = "${libdir}/libEGL.so.*"
 243 FILES_libgbm = "${libdir}/libgbm.so.*"
 244 FILES_libgles1-mesa = "${libdir}/libGLESv1*.so.*"
 245 FILES_libgles2-mesa = "${libdir}/libGLESv2.so.*"
 246 FILES_libgl-mesa = "${libdir}/libGL.so.*"
 247 FILES_libglapi = "${libdir}/libglapi.so.*"
 248 FILES_libosmesa = "${libdir}/libOSMesa.so.*"
 249 FILES_libxatracker = "${libdir}/libxatracker.so.*"
 250
 251 FILES_${PN}-dev = "${libdir}/pkgconfig/dri.pc ${includedir}/vulkan"
 252 FILES_libegl-mesa-dev = "${libdir}/libEGL.* ${includedir}/EGL ${includedir}/KHR ${libdir}/pkgconfig/egl.pc"
 253 FILES_libgbm-dev = "${libdir}/libgbm.* ${libdir}/pkgconfig/gbm.pc ${includedir}/gbm.h"
 254 FILES_libgl-mesa-dev = "${libdir}/libGL.* ${includedir}/GL ${libdir}/pkgconfig/gl.pc"
 255 FILES_libglapi-dev = "${libdir}/libglapi.*"
 256 FILES_libgles1-mesa-dev = "${libdir}/libGLESv1*.* ${includedir}/GLES ${libdir}/pkgconfig/glesv1*.pc"
 257 FILES_libgles2-mesa-dev = "${libdir}/libGLESv2.* ${includedir}/GLES2 ${libdir}/pkgconfig/glesv2.pc"
 258 FILES_libgles3-mesa-dev = "${includedir}/GLES3"
 259 FILES_libosmesa-dev = "${libdir}/libOSMesa.* ${includedir}/GL/osmesa.h ${libdir}/pkgconfig/osmesa.pc"
 260 FILES_libxatracker-dev = "${libdir}/libxatracker.so ${libdir}/libxatracker.la \
 261                           ${includedir}/xa_tracker.h ${includedir}/xa_composite.h ${includedir}/xa_context.h \
 262                           ${libdir}/pkgconfig/xatracker.pc"
 263
 264 # Fix upgrade path from mesa to mesa-megadriver
 265 RREPLACES_mesa-megadriver = "mesa"
 266 RCONFLICTS_mesa-megadriver = "mesa"
 267 RPROVIDES_mesa-megadriver = "mesa"