meta-agl-bsp/meta-raspberrypi/recipes-bsp/u-boot/u-boot-tools_2019.07.bb

   1 require u-boot-common.inc
   2
   3 SUMMARY = "U-Boot bootloader tools"
   4 DEPENDS += "openssl"
   5
   6 PROVIDES = "${MLPREFIX}u-boot-mkimage ${MLPREFIX}u-boot-mkenvimage"
   7 PROVIDES_class-native = "u-boot-mkimage-native u-boot-mkenvimage-native"
   8
   9 PACKAGES += "${PN}-mkimage ${PN}-mkenvimage"
  10
  11 # Required for backward compatibility with "u-boot-mkimage-xxx.bb"
  12 RPROVIDES_${PN}-mkimage = "u-boot-mkimage"
  13 RREPLACES_${PN}-mkimage = "u-boot-mkimage"
  14 RCONFLICTS_${PN}-mkimage = "u-boot-mkimage"
  15
  16 EXTRA_OEMAKE_class-target = 'CROSS_COMPILE="${TARGET_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1'
  17 EXTRA_OEMAKE_class-native = 'CC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1'
  18 EXTRA_OEMAKE_class-nativesdk = 'CROSS_COMPILE="${HOST_PREFIX}" CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" STRIP=true V=1'
  19
  20 SED_CONFIG_EFI = '-e "s/CONFIG_EFI_LOADER=.*/# CONFIG_EFI_LOADER is not set/"'
  21 SED_CONFIG_EFI_x86 = ''
  22 SED_CONFIG_EFI_x86-64 = ''
  23 SED_CONFIG_EFI_arm = ''
  24 SED_CONFIG_EFI_armeb = ''
  25 SED_CONFIG_EFI_aarch64 = ''
  26
  27 do_compile () {
  28         oe_runmake sandbox_defconfig
  29
  30         # Disable CONFIG_CMD_LICENSE, license.h is not used by tools and
  31         # generating it requires bin2header tool, which for target build
  32         # is built with target tools and thus cannot be executed on host.
  33         sed -i -e "s/CONFIG_CMD_LICENSE=.*/# CONFIG_CMD_LICENSE is not set/" ${SED_CONFIG_EFI} .config
  34
  35         oe_runmake cross_tools NO_SDL=1
  36 }
  37
  38 do_install () {
  39         install -d ${D}${bindir}
  40
  41         # mkimage
  42         install -m 0755 tools/mkimage ${D}${bindir}/uboot-mkimage
  43         ln -sf uboot-mkimage ${D}${bindir}/mkimage
  44
  45         # mkenvimage
  46         install -m 0755 tools/mkenvimage ${D}${bindir}/uboot-mkenvimage
  47         ln -sf uboot-mkenvimage ${D}${bindir}/mkenvimage
  48
  49         # dumpimage
  50         install -m 0755 tools/dumpimage ${D}${bindir}/uboot-dumpimage
  51         ln -sf uboot-dumpimage ${D}${bindir}/dumpimage
  52
  53         # fit_check_sign
  54         install -m 0755 tools/fit_check_sign ${D}${bindir}/uboot-fit_check_sign
  55         ln -sf uboot-fit_check_sign ${D}${bindir}/fit_check_sign
  56 }
  57
  58 ALLOW_EMPTY_${PN} = "1"
  59 FILES_${PN} = ""
  60 FILES_${PN}-mkimage = "${bindir}/uboot-mkimage ${bindir}/mkimage ${bindir}/uboot-dumpimage ${bindir}/dumpimage ${bindir}/uboot-fit_check_sign ${bindir}/fit_check_sign"
  61 FILES_${PN}-mkenvimage = "${bindir}/uboot-mkenvimage ${bindir}/mkenvimage"
  62
  63 RDEPENDS_${PN}-mkimage += "dtc"
  64 RDEPENDS_${PN} += "${PN}-mkimage ${PN}-mkenvimage"
  65 RDEPENDS_${PN}_class-native = ""
  66
  67 BBCLASSEXTEND = "native nativesdk"