meta-agl-bsp/meta-freescale-layer/recipes-graphics/wayland/weston_2.0.0.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/weston-2.0.0:"
   2
   3 SRC_URI_append_imxgpu3d = " \
   4     file://0001-libweston-Restore-EGL-support-for-the-fbdev-backend.patch     \
   5     file://0002-MGS-2352-ccc-Add-GPU-VIV-support-for-weston-2.0.patch     \
   6     file://0006-Link-compositor-to-egl.patch                               \
   7 "
   8
   9 # The 'egl' configuration of weston requires gles support, and consideration
  10 # must be taken for the different SoC capabilities:
  11 # - For SoCs with 3d support, imx-gpu-viv provides hardware-accelerated
  12 #   egl and gles, so weston egl configuration is enabled.
  13 # - For SoCs with VG2D, like i.MX 6SoloLite, imx-gpu-viv provides
  14 #   hardware-accelerated egl but does not provide a compatible software
  15 #   version of gles, so weston egl configuration is disabled.
  16 # - For SoCs with no GPU, mesa provides software implementations of egl
  17 #   and gles, so weston egl configuration is enabled.
  18 PACKAGECONFIG_IMX_TO_APPEND = ""
  19 PACKAGECONFIG_IMX_TO_APPEND_imxgpu3d = "cairo-glesv2"
  20 PACKAGECONFIG_IMX_TO_REMOVE = ""
  21 PACKAGECONFIG_IMX_TO_REMOVE_imxgpu2d = "egl"
  22 PACKAGECONFIG_IMX_TO_REMOVE_imxgpu3d = ""
  23
  24 PACKAGECONFIG_append = " ${PACKAGECONFIG_IMX_TO_APPEND}"
  25 PACKAGECONFIG_remove = " ${PACKAGECONFIG_IMX_TO_REMOVE}"
  26
  27 EXTRA_OECONF_IMX_COMMON = " \
  28     --disable-libunwind \
  29     --disable-xwayland-test \
  30     WESTON_NATIVE_BACKEND=fbdev-backend.so \
  31 "
  32 EXTRA_OECONF_IMX          = ""
  33 EXTRA_OECONF_IMX_imxpxp   = "${EXTRA_OECONF_IMX_COMMON}"
  34 EXTRA_OECONF_IMX_imxgpu2d = "${EXTRA_OECONF_IMX_COMMON}"
  35
  36 EXTRA_OECONF_append = " ${EXTRA_OECONF_IMX}"
  37
  38 PACKAGE_ARCH = "${MACHINE_SOCARCH}"