meta-agl-bsp/conf/machine/include/rpi4-base.inc

   1 include conf/machine/include/rpi-default-settings.inc
   2 include conf/machine/include/rpi-default-versions.inc
   3 include conf/machine/include/rpi-default-providers.inc
   4
   5 SOC_FAMILY = "rpi"
   6 include conf/machine/include/soc-family.inc
   7
   8 IMAGE_FSTYPES ?= "tar.bz2 ext3 rpi-sdimg"
   9 WKS_FILE ?= "sdimage-raspberrypi.wks"
  10
  11 XSERVER = " \
  12     xserver-xorg \
  13     ${@bb.utils.contains("MACHINE_FEATURES", "vc4graphics", "xserver-xorg-extension-glx", "", d)} \
  14     ${@bb.utils.contains("MACHINE_FEATURES", "vc4graphics", "xf86-video-modesetting", "xf86-video-fbdev", d)} \
  15     "
  16
  17 RPI_KERNEL_DEVICETREE_OVERLAYS ?= " \
  18     overlays/at86rf233.dtbo \
  19     overlays/dwc2.dtbo \
  20     overlays/gpio-key.dtbo \
  21     overlays/hifiberry-amp.dtbo \
  22     overlays/hifiberry-dac.dtbo \
  23     overlays/hifiberry-dacplus.dtbo \
  24     overlays/hifiberry-digi.dtbo \
  25     overlays/i2c-rtc.dtbo \
  26     overlays/iqaudio-dac.dtbo \
  27     overlays/iqaudio-dacplus.dtbo \
  28     overlays/mcp2515-can0.dtbo \
  29     overlays/pi3-disable-bt.dtbo \
  30     overlays/pi3-miniuart-bt.dtbo \
  31     overlays/pitft22.dtbo \
  32     overlays/pitft28-resistive.dtbo \
  33     overlays/pitft35-resistive.dtbo \
  34     overlays/pps-gpio.dtbo \
  35     overlays/rpi-ft5406.dtbo \
  36     overlays/rpi-poe.dtbo \
  37     overlays/vc4-kms-v3d.dtbo \
  38     overlays/vc4-fkms-v3d.dtbo \
  39     overlays/w1-gpio-pullup.dtbo \
  40     overlays/w1-gpio.dtbo \
  41     "
  42
  43 RPI_KERNEL_DEVICETREE ?= " \
  44     bcm2708-rpi-zero-w.dtb \
  45     bcm2708-rpi-b.dtb \
  46     bcm2708-rpi-b-plus.dtb \
  47     bcm2709-rpi-2-b.dtb \
  48     bcm2710-rpi-3-b.dtb \
  49     bcm2710-rpi-3-b-plus.dtb \
  50     bcm2711-rpi-4-b.dtb \
  51     bcm2708-rpi-cm.dtb \
  52     bcm2710-rpi-cm3.dtb \
  53     "
  54
  55 KERNEL_DEVICETREE ?= " \
  56     ${RPI_KERNEL_DEVICETREE} \
  57     ${RPI_KERNEL_DEVICETREE_OVERLAYS} \
  58     "
  59
  60 # By default:
  61 #
  62 # * When u-boot is disabled use the "Image" format which can be directly loaded
  63 #   by the rpi firmware.
  64 #
  65 # * When u-boot is enabled use the "uImage" format and the "bootm" command
  66 #   within u-boot to load the kernel.
  67 KERNEL_BOOTCMD ??= "bootm"
  68 KERNEL_IMAGETYPE_UBOOT ??= "uImage"
  69 KERNEL_IMAGETYPE_DIRECT ??= "zImage"
  70 KERNEL_IMAGETYPE ?= "${@bb.utils.contains('RPI_USE_U_BOOT', '1', \
  71         '${KERNEL_IMAGETYPE_UBOOT}', '${KERNEL_IMAGETYPE_DIRECT}', d)}"
  72
  73 MACHINE_FEATURES += "apm usbhost keyboard vfat ext2 screen touchscreen alsa bluetooth wifi sdio ${@bb.utils.contains('DISABLE_VC4GRAPHICS', '1', '', 'vc4graphics', d)}"
  74
  75 # Raspberry Pi has no hardware clock
  76 MACHINE_FEATURES_BACKFILL_CONSIDERED = "rtc"
  77
  78 MACHINE_EXTRA_RRECOMMENDS += " kernel-modules udev-rules-rpi"
  79
  80 # Set Raspberrypi splash image
  81 SPLASH = "psplash-raspberrypi"
  82
  83 def make_dtb_boot_files(d):
  84     # Generate IMAGE_BOOT_FILES entries for device tree files listed in
  85     # KERNEL_DEVICETREE.
  86     alldtbs = d.getVar('KERNEL_DEVICETREE')
  87     imgtyp = d.getVar('KERNEL_IMAGETYPE')
  88
  89     def transform(dtb):
  90         base = os.path.basename(dtb)
  91         if dtb.endswith('dtb'):
  92             # eg: whatever/bcm2708-rpi-b.dtb has:
  93             #     DEPLOYDIR file: bcm2708-rpi-b.dtb
  94             #     destination: bcm2708-rpi-b.dtb
  95             return base
  96         elif dtb.endswith('dtbo'):
  97             # overlay dtb:
  98             # eg: overlays/hifiberry-amp.dtbo has:
  99             #     DEPLOYDIR file: hifiberry-amp.dtbo
 100             #     destination: overlays/hifiberry-amp.dtbo
 101             return '{};{}'.format(base, dtb)
 102
 103     return ' '.join([transform(dtb) for dtb in alldtbs.split(' ') if dtb])
 104
 105
 106 IMAGE_BOOT_FILES ?= "bcm2835-bootfiles/* \
 107                  ${@make_dtb_boot_files(d)} \
 108                  ${@bb.utils.contains('RPI_USE_U_BOOT', '1', \
 109                     '${KERNEL_IMAGETYPE} u-boot.bin;${SDIMG_KERNELIMAGE} boot.scr', \
 110                     '${KERNEL_IMAGETYPE};${SDIMG_KERNELIMAGE}', d)} \
 111                  "
 112 do_image_wic[depends] += " \
 113     bcm2835-bootfiles:do_deploy \
 114     ${@bb.utils.contains('RPI_USE_U_BOOT', '1', 'u-boot:do_deploy', '',d)} \
 115     "
 116
 117 do_image_wic[recrdeps] = "do_build"
 118
 119 # The kernel image is installed into the FAT32 boot partition and does not need
 120 # to also be installed into the rootfs.
 121 RDEPENDS_${KERNEL_PACKAGE_NAME}-base = ""