meta-agl-bsp/classes/sdcard_image-socfpga.bbclass

   1 inherit image_types
   2
   3 # Create an sdcard image suitable for the atlas board
   4 # This is copied from the raspberrypi and freescale sdcard classes
   5
   6 # Disk layout
   7 #    0                      -> 8*1024                           - reserverd
   8 #    8*1024                 -> 32*1024                          -
   9 #    32*1024                -> 1024*1024                        -
  10 #    1024*1024              -> BOOT_SPACE                       - bootloader and kernel in Part 3
  11 #    BOOT_SPACE*1024        -> FAT_SPACE
  12
  13
  14
  15 # This image depends on the rootfs image
  16 IMAGE_TYPEDEP_socfpga-sdimg = "${SDIMG_ROOTFS_TYPE}"
  17
  18 # Boot partition volume id
  19 BOOTDD_VOLUME_ID ?= "${MACHINE}"
  20
  21 # Boot partition size [in KiB] -> size 2M for A10
  22 BOOT_SPACE ?= "2048"
  23
  24 # Fat partition size
  25 FAT_SPACE ?= "102400"
  26
  27 # uBoot ENV offset
  28 SDIMG_UBOOT_ENV_OFFSET ?= "512"
  29 ENV_BASE_NAME ??= "${UBOOT_CONFIG}"
  30
  31 # Boot partition begin at sector 1024
  32 # This is required as for c5/a5 mainline uboot hard codes the location
  33 # of the uboot image in the sdcard to 0xa00 sector
  34 IMAGE_ROOTFS_ALIGNMENT = "1024"
  35
  36 # ROOTFS_SIZE_MOD ?= "524288"
  37 ROOTFS_SIZE_MOD ?= "16384"
  38
  39 # Use an uncompressed ext3 by default as rootfs
  40 SDIMG_ROOTFS_TYPE = "ext3"
  41 SDIMG_ROOTFS = "${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.${SDIMG_ROOTFS_TYPE}"
  42
  43
  44 do_image_socfpga-sdimg[depends] += " \
  45                         parted-native:do_populate_sysroot \
  46                         mtools-native:do_populate_sysroot \
  47                         dosfstools-native:do_populate_sysroot \
  48                         virtual/kernel:do_deploy \
  49                         virtual/bootloader:do_deploy \
  50                         "
  51
  52 rootfs[depends] += "virtual/kernel:do_deploy"
  53
  54 # SD card image name
  55 SDIMG = "${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.socfpga-sdimg"
  56
  57 IMAGEDATESTAMP = "${@time.strftime('%Y.%m.%d',time.gmtime())}"
  58
  59 # After uboot v2016.05 the boot partition number was changed from 3 to 1 so as a
  60 # result we need 2 different functions for creating the boot partitions just to
  61 # change the partition creation order
  62
  63 SOCFPGA_SDIMG_PARTITION_COMMAND ?= "generate_sdcard_partitions"
  64
  65 generate_sdcard_partitions () {
  66
  67         # Create partition table
  68         parted -s ${SDIMG} mklabel msdos
  69         # P1: Fat partition
  70         parted -s ${SDIMG} unit KiB mkpart primary fat32 $(expr  ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ ${FAT_SPACE_ALIGNED})
  71         # set fat partition as bootable for distroboot
  72         parted -s ${SDIMG} set 1 boot on
  73         # P2: Linux FS partition
  74         parted -s ${SDIMG} unit KiB mkpart primary $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ ${FAT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ ${FAT_SPACE_ALIGNED} \+ ${ROOTFS_SIZE_ALIGNED})
  75         # P3: A2 partition for bootloader
  76         parted -s ${SDIMG} unit KiB mkpart primary ${IMAGE_ROOTFS_ALIGNMENT} $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT})
  77
  78         # set part 3 to type a2 for spl / uboot image
  79         # 446 to partition table, 16 bytes per entry, 4 byte offset to partition type
  80         echo -ne "\xa2" | dd of=${SDIMG} bs=1 count=1 seek=$(expr 446 + 16 + 16 + 4) conv=notrunc && sync && sync
  81
  82         # Create a vfat image with boot files
  83         FAT_BLOCKS=$(LC_ALL=C parted -s ${SDIMG} unit b print | awk '/ 1 / { print substr($4, 1, length($4 -1)) / 512 /2 }')
  84         rm -f ${WORKDIR}/fat.img
  85         mkfs.vfat -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/fat.img $FAT_BLOCKS
  86
  87 }
  88
  89 IMAGE_CMD_socfpga-sdimg () {
  90
  91         # Align partitions
  92         BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
  93         BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE_ALIGNED} - ${BOOT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
  94         FAT_SPACE_ALIGNED=$(expr ${FAT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
  95         FAT_SPACE_ALIGNED=$(expr ${FAT_SPACE_ALIGNED} - ${FAT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
  96
  97         ROOTFS_SIZE_ALIGNED=$(expr ${ROOTFS_SIZE} \+ ${ROOTFS_SIZE_MOD})
  98         ROOTFS_SIZE_ALIGNED=$(expr ${ROOTFS_SIZE_ALIGNED} \- ${ROOTFS_SIZE_ALIGNED} \% ${ROOTFS_SIZE_MOD})
  99
 100         SDIMG_SIZE=$(expr ${IMAGE_ROOTFS_ALIGNMENT} + ${BOOT_SPACE_ALIGNED} + ${FAT_SPACE_ALIGNED} + ${ROOTFS_SIZE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT})
 101
 102         # Initialize sdcard image file
 103         dd if=/dev/zero of=${SDIMG} bs=1 count=0 seek=$(expr 1024 \* ${SDIMG_SIZE}) && sync && sync
 104
 105         # Create partition table
 106         ${SOCFPGA_SDIMG_PARTITION_COMMAND}
 107
 108         # Copy kernel image
 109         mcopy -i ${WORKDIR}/fat.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin ::/${KERNEL_IMAGETYPE}
 110
 111         # Copy boot scripts
 112         if [ -e "${DEPLOY_DIR_IMAGE}/${MACHINE}.scr" ]
 113         then
 114                 mcopy -i ${WORKDIR}/fat.img -s ${DEPLOY_DIR_IMAGE}/${MACHINE}.scr ::/u-boot.scr
 115         fi
 116
 117         # Copy device tree file
 118         if test -n "${KERNEL_DEVICETREE}"; then
 119                 for DTS_FILE in ${KERNEL_DEVICETREE}; do
 120                         DTS_BASE_NAME=`basename ${DTS_FILE} | awk -F "." '{print $1}'`
 121                         if [ -e "${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb" ]; then
 122                                 kernel_bin="`readlink ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin`"
 123                                 kernel_bin_for_dtb="`readlink ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb | sed "s,$DTS_BASE_NAME,${MACHINE},g;s,\.dtb$,.bin,g"`"
 124                                 if [ $kernel_bin = $kernel_bin_for_dtb ]; then
 125                                         mcopy -i ${WORKDIR}/fat.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb ::/${DTS_BASE_NAME}.dtb
 126                                 fi
 127                         fi
 128                 done
 129         fi
 130
 131         # copy extlinux stuff
 132         if [ "${UBOOT_EXTLINUX}" = "1" ]
 133         then
 134                 if [ -e "${DEPLOY_DIR_IMAGE}/extlinux.conf" ]
 135                 then
 136                         rm -Rf ${WORKDIR}/extlinux
 137                         mkdir ${WORKDIR}/extlinux
 138                         cp ${DEPLOY_DIR_IMAGE}/extlinux.conf ${WORKDIR}/extlinux/
 139                         mcopy -i ${WORKDIR}/fat.img -s ${WORKDIR}/extlinux ::/
 140                 fi
 141
 142         fi
 143
 144         # copy any files listed as extra files
 145         if test -n "${SOCFPGA_SDIMG_EXTRA_FILES}"; then
 146                 for EXTRA_FILE in ${SOCFPGA_SDIMG_EXTRA_FILES}; do
 147                         if [ -e "${DEPLOY_DIR_IMAGE}/${EXTRA_FILE}" ]; then
 148                                 mcopy -i ${WORKDIR}/fat.img -s ${DEPLOY_DIR_IMAGE}/${EXTRA_FILE} ::/${EXTRA_FILE}
 149                         fi
 150                 done
 151         fi
 152
 153         # Add stamp file
 154         echo "${IMAGE_NAME}-${IMAGEDATESTAMP}" > ${WORKDIR}/image-version-info
 155         mcopy -i ${WORKDIR}/fat.img -v ${WORKDIR}//image-version-info ::
 156
 157         # Burn Partitions
 158         dd if=${WORKDIR}/fat.img of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 159         # If SDIMG_ROOTFS_TYPE is a .xz file use xzcat
 160         if echo "${SDIMG_ROOTFS_TYPE}" | egrep -q "*\.xz"
 161         then
 162                 xzcat ${SDIMG_ROOTFS} | dd of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + 1024 \* ${FAT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 163         else
 164                 dd if=${SDIMG_ROOTFS} of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + 1024 \* ${FAT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 165         fi
 166
 167         if [ -e "${DEPLOY_DIR_IMAGE}/${SPL_BINARY}-${UBOOT_CONFIG}" ]
 168         then
 169             dd if=${DEPLOY_DIR_IMAGE}/${SPL_BINARY}-${UBOOT_CONFIG} of=${SDIMG} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 170         elif [ -e "${DEPLOY_DIR_IMAGE}/${SPL_BINARY}" ]
 171         then
 172             dd if=${DEPLOY_DIR_IMAGE}/${SPL_BINARY} of=${SDIMG} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 173         else
 174             bbfatal "${SPL_BINARY} does not exist."
 175         fi
 176
 177         if [ -e "${DEPLOY_DIR_IMAGE}/u-boot-env-${ENV_BASE_NAME}.bin" ]; then
 178                 dd if=${DEPLOY_DIR_IMAGE}/u-boot-env-${ENV_BASE_NAME}.bin of=${SDIMG} conv=notrunc bs=1 seek=${SDIMG_UBOOT_ENV_OFFSET} && sync && sync
 179         fi
 180
 181 }