meta-agl-bsp/classes/sdcard_image-socfpga.bbclass

   1 inherit image_types
   2
   3 # Create an sdcard image suitable for the atlas board
   4 # This is copied from the raspberrypi and freescale sdcard classes
   5
   6 # Disk layout
   7 #    0                      -> 8*1024                           - reserverd
   8 #    8*1024                 -> 32*1024                          -
   9 #    32*1024                -> 1024*1024                        -
  10 #    1024*1024              -> BOOT_SPACE                       - bootloader and kernel in Part 3
  11 #    BOOT_SPACE*1024        -> FAT_SPACE
  12
  13
  14
  15 # This image depends on the rootfs image
  16 IMAGE_TYPEDEP_socfpga-sdimg = "${SDIMG_ROOTFS_TYPE}"
  17
  18 # Boot partition volume id
  19 BOOTDD_VOLUME_ID ?= "${MACHINE}"
  20
  21 # Boot partition size [in KiB] -> size 2M for A10
  22 BOOT_SPACE ?= "2048"
  23
  24 # Fat partition size
  25 FAT_SPACE ?= "102400"
  26
  27 # uBoot ENV offset
  28 SDIMG_UBOOT_ENV_OFFSET ?= "512"
  29 ENV_BASE_NAME ??= "${UBOOT_CONFIG}"
  30
  31 # Boot partition begin at sector 1024
  32 # This is required as for c5/a5 mainline uboot hard codes the location
  33 # of the uboot image in the sdcard to 0xa00 sector
  34 IMAGE_ROOTFS_ALIGNMENT = "1024"
  35
  36 # ROOTFS_SIZE_MOD ?= "524288"
  37 ROOTFS_SIZE_MOD ?= "16384"
  38
  39 # Use an uncompressed ext3 by default as rootfs
  40 SDIMG_ROOTFS_TYPE = "ext3"
  41 SDIMG_ROOTFS = "${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.${SDIMG_ROOTFS_TYPE}"
  42
  43
  44 do_image_socfpga_sdimg[depends] += " \
  45                         coreutils-native:do_populate_sysroot \
  46                         parted-native:do_populate_sysroot \
  47                         mtools-native:do_populate_sysroot \
  48                         dosfstools-native:do_populate_sysroot \
  49                         virtual/kernel:do_deploy \
  50                         virtual/bootloader:do_deploy \
  51                         "
  52
  53 rootfs[depends] += "virtual/kernel:do_deploy"
  54
  55 # SD card image name
  56 SDIMG = "${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.socfpga-sdimg"
  57
  58 IMAGEDATESTAMP = "${@time.strftime('%Y.%m.%d',time.gmtime())}"
  59
  60 # After uboot v2016.05 the boot partition number was changed from 3 to 1 so as a
  61 # result we need 2 different functions for creating the boot partitions just to
  62 # change the partition creation order
  63
  64 SOCFPGA_SDIMG_PARTITION_COMMAND ?= "generate_sdcard_partitions"
  65
  66 generate_sdcard_partitions () {
  67
  68         # Create partition table
  69         parted -s ${SDIMG} mklabel msdos
  70         # P1: Fat partition
  71         parted -s ${SDIMG} unit KiB mkpart primary fat32 $(expr  ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ ${FAT_SPACE_ALIGNED})
  72         # set fat partition as bootable for distroboot
  73         parted -s ${SDIMG} set 1 boot on
  74         # P2: Linux FS partition
  75         parted -s ${SDIMG} unit KiB mkpart primary $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ ${FAT_SPACE_ALIGNED}) $(expr ${IMAGE_ROOTFS_ALIGNMENT} \+ ${BOOT_SPACE_ALIGNED} \+ ${FAT_SPACE_ALIGNED} \+ ${ROOTFS_SIZE_ALIGNED})
  76         # P3: A2 partition for bootloader
  77         parted -s ${SDIMG} unit KiB mkpart primary ${IMAGE_ROOTFS_ALIGNMENT} $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT})
  78
  79         # set part 3 to type a2 for spl / uboot image
  80         # 446 to partition table, 16 bytes per entry, 4 byte offset to partition type
  81         echo -ne "\xa2" | dd of=${SDIMG} bs=1 count=1 seek=$(expr 446 + 16 + 16 + 4) conv=notrunc && sync && sync
  82
  83         # Create a vfat image with boot files
  84         FAT_BLOCKS=$(LC_ALL=C parted -s ${SDIMG} unit b print | awk '/ 1 / { print substr($4, 1, length($4 -1)) / 512 /2 }')
  85         rm -f ${WORKDIR}/fat.img
  86         mkfs.vfat -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/fat.img $FAT_BLOCKS
  87
  88 }
  89
  90 IMAGE_CMD_socfpga-sdimg () {
  91
  92         # Align partitions
  93         BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
  94         BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE_ALIGNED} - ${BOOT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
  95         FAT_SPACE_ALIGNED=$(expr ${FAT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
  96         FAT_SPACE_ALIGNED=$(expr ${FAT_SPACE_ALIGNED} - ${FAT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
  97
  98         ROOTFS_SIZE_ALIGNED=$(expr ${ROOTFS_SIZE} \+ ${ROOTFS_SIZE_MOD})
  99         ROOTFS_SIZE_ALIGNED=$(expr ${ROOTFS_SIZE_ALIGNED} \- ${ROOTFS_SIZE_ALIGNED} \% ${ROOTFS_SIZE_MOD})
 100
 101         SDIMG_SIZE=$(expr ${IMAGE_ROOTFS_ALIGNMENT} + ${BOOT_SPACE_ALIGNED} + ${FAT_SPACE_ALIGNED} + ${ROOTFS_SIZE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT})
 102
 103         # Initialize sdcard image file
 104         dd if=/dev/zero of=${SDIMG} bs=1 count=0 seek=$(expr 1024 \* ${SDIMG_SIZE}) && sync && sync
 105
 106         # Create partition table
 107         ${SOCFPGA_SDIMG_PARTITION_COMMAND}
 108
 109         # Copy kernel image
 110         mcopy -i ${WORKDIR}/fat.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin ::/${KERNEL_IMAGETYPE}
 111
 112         # Copy boot scripts
 113         if [ -e "${DEPLOY_DIR_IMAGE}/${MACHINE}.scr" ]
 114         then
 115                 mcopy -i ${WORKDIR}/fat.img -s ${DEPLOY_DIR_IMAGE}/${MACHINE}.scr ::/u-boot.scr
 116         fi
 117
 118         # Copy device tree file
 119         if test -n "${KERNEL_DEVICETREE}"; then
 120                 for DTS_FILE in ${KERNEL_DEVICETREE}; do
 121                         DTS_BASE_NAME=`basename ${DTS_FILE} | awk -F "." '{print $1}'`
 122                         if [ -e "${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb" ]; then
 123                                 kernel_bin="`readlink ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${MACHINE}.bin`"
 124                                 kernel_bin_for_dtb="`readlink ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb | sed "s,$DTS_BASE_NAME,${MACHINE},g;s,\.dtb$,.bin,g"`"
 125                                 if [ $kernel_bin = $kernel_bin_for_dtb ]; then
 126                                         mcopy -i ${WORKDIR}/fat.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTS_BASE_NAME}.dtb ::/${DTS_BASE_NAME}.dtb
 127                                 fi
 128                         fi
 129                 done
 130         fi
 131
 132         # copy extlinux stuff
 133         if [ "${UBOOT_EXTLINUX}" = "1" ]
 134         then
 135                 if [ -e "${DEPLOY_DIR_IMAGE}/extlinux.conf" ]
 136                 then
 137                         rm -Rf ${WORKDIR}/extlinux
 138                         mkdir ${WORKDIR}/extlinux
 139                         cp ${DEPLOY_DIR_IMAGE}/extlinux.conf ${WORKDIR}/extlinux/
 140                         mcopy -i ${WORKDIR}/fat.img -s ${WORKDIR}/extlinux ::/
 141                 fi
 142
 143         fi
 144
 145         # copy any files listed as extra files
 146         if test -n "${SOCFPGA_SDIMG_EXTRA_FILES}"; then
 147                 for EXTRA_FILE in ${SOCFPGA_SDIMG_EXTRA_FILES}; do
 148                         if [ -e "${DEPLOY_DIR_IMAGE}/${EXTRA_FILE}" ]; then
 149                                 mcopy -i ${WORKDIR}/fat.img -s ${DEPLOY_DIR_IMAGE}/${EXTRA_FILE} ::/${EXTRA_FILE}
 150                         fi
 151                 done
 152         fi
 153
 154         # Add stamp file
 155         echo "${IMAGE_NAME}-${IMAGEDATESTAMP}" > ${WORKDIR}/image-version-info
 156         mcopy -i ${WORKDIR}/fat.img -v ${WORKDIR}//image-version-info ::
 157
 158         # Burn Partitions
 159         dd if=${WORKDIR}/fat.img of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 160         # If SDIMG_ROOTFS_TYPE is a .xz file use xzcat
 161         if echo "${SDIMG_ROOTFS_TYPE}" | egrep -q "*\.xz"
 162         then
 163                 xzcat ${SDIMG_ROOTFS} | dd of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + 1024 \* ${FAT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 164         else
 165                 dd if=${SDIMG_ROOTFS} of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + 1024 \* ${FAT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 166         fi
 167
 168         if [ -e "${DEPLOY_DIR_IMAGE}/${SPL_BINARY}-${UBOOT_CONFIG}" ]
 169         then
 170             dd if=${DEPLOY_DIR_IMAGE}/${SPL_BINARY}-${UBOOT_CONFIG} of=${SDIMG} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 171         elif [ -e "${DEPLOY_DIR_IMAGE}/${SPL_BINARY}" ]
 172         then
 173             dd if=${DEPLOY_DIR_IMAGE}/${SPL_BINARY} of=${SDIMG} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 174         else
 175             bbfatal "${SPL_BINARY} does not exist."
 176         fi
 177
 178         if [ -e "${DEPLOY_DIR_IMAGE}/u-boot-env-${ENV_BASE_NAME}.bin" ]; then
 179                 dd if=${DEPLOY_DIR_IMAGE}/u-boot-env-${ENV_BASE_NAME}.bin of=${SDIMG} conv=notrunc bs=1 seek=${SDIMG_UBOOT_ENV_OFFSET} && sync && sync
 180         fi
 181
 182 }