meta-agl-bsp/classes/sdcard_image-rpi.bbclass

   1 inherit image_types
   2 inherit linux-raspberrypi-base
   3
   4 #
   5 # Create an image that can by written onto a SD card using dd.
   6 #
   7 # The disk layout used is:
   8 #
   9 #    0                      -> IMAGE_ROOTFS_ALIGNMENT         - reserved for other data
  10 #    IMAGE_ROOTFS_ALIGNMENT -> BOOT_SPACE                     - bootloader and kernel
  11 #    BOOT_SPACE             -> SDIMG_SIZE                     - rootfs
  12 #
  13
  14 #                                                     Default Free space = 1.3x
  15 #                                                     Use IMAGE_OVERHEAD_FACTOR to add more space
  16 #                                                     <--------->
  17 #            4MiB              40MiB           SDIMG_ROOTFS
  18 # <-----------------------> <----------> <---------------------->
  19 #  ------------------------ ------------ ------------------------
  20 # | IMAGE_ROOTFS_ALIGNMENT | BOOT_SPACE | ROOTFS_SIZE            |
  21 #  ------------------------ ------------ ------------------------
  22 # ^                        ^            ^                        ^
  23 # |                        |            |                        |
  24 # 0                      4MiB     4MiB + 40MiB       4MiB + 40Mib + SDIMG_ROOTFS
  25
  26 # This image depends on the rootfs image
  27 IMAGE_TYPEDEP_rpi-sdimg = "${SDIMG_ROOTFS_TYPE}"
  28
  29 # Set kernel and boot loader
  30 IMAGE_BOOTLOADER ?= "bcm2835-bootfiles"
  31
  32 # Set initramfs extension
  33 KERNEL_INITRAMFS ?= ""
  34
  35 # Kernel image name
  36 SDIMG_KERNELIMAGE_raspberrypi  ?= "kernel.img"
  37 SDIMG_KERNELIMAGE_raspberrypi2 ?= "kernel7.img"
  38 SDIMG_KERNELIMAGE_raspberrypi3-64 ?= "kernel8.img"
  39
  40 # Boot partition volume id
  41 BOOTDD_VOLUME_ID ?= "${MACHINE}"
  42
  43 # Boot partition size [in KiB] (will be rounded up to IMAGE_ROOTFS_ALIGNMENT)
  44 BOOT_SPACE ?= "40960"
  45
  46 # Set alignment to 4MB [in KiB]
  47 IMAGE_ROOTFS_ALIGNMENT = "4096"
  48
  49 # Use an uncompressed ext3 by default as rootfs
  50 SDIMG_ROOTFS_TYPE ?= "ext3"
  51 SDIMG_ROOTFS = "${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.${SDIMG_ROOTFS_TYPE}"
  52
  53 IMAGE_DEPENDS_rpi-sdimg = " \
  54                         parted-native \
  55                         mtools-native \
  56                         dosfstools-native \
  57                         virtual/kernel:do_deploy \
  58                         ${IMAGE_BOOTLOADER} \
  59                         ${@bb.utils.contains('KERNEL_IMAGETYPE', 'uImage', 'u-boot', '',d)} \
  60                         "
  61
  62 # SD card image name
  63 SDIMG = "${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.rpi-sdimg"
  64
  65 # Compression method to apply to SDIMG after it has been created. Supported
  66 # compression formats are "gzip", "bzip2" or "xz". The original .rpi-sdimg file
  67 # is kept and a new compressed file is created if one of these compression
  68 # formats is chosen. If SDIMG_COMPRESSION is set to any other value it is
  69 # silently ignored.
  70 #SDIMG_COMPRESSION ?= ""
  71
  72 # Additional files and/or directories to be copied into the vfat partition from the IMAGE_ROOTFS.
  73 FATPAYLOAD ?= ""
  74
  75 IMAGE_CMD_rpi-sdimg () {
  76
  77         # Align partitions
  78         BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
  79         BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE_ALIGNED} - ${BOOT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
  80         SDIMG_SIZE=$(expr ${IMAGE_ROOTFS_ALIGNMENT} + ${BOOT_SPACE_ALIGNED} + $ROOTFS_SIZE)
  81
  82         echo "Creating filesystem with Boot partition ${BOOT_SPACE_ALIGNED} KiB and RootFS $ROOTFS_SIZE KiB"
  83
  84         # Check if we are building with device tree support
  85         DTS="${@get_dts(d)}"
  86
  87         # Initialize sdcard image file
  88         dd if=/dev/zero of=${SDIMG} bs=1024 count=0 seek=${SDIMG_SIZE}
  89
  90         # Create partition table
  91         parted -s ${SDIMG} mklabel msdos
  92         # Create boot partition and mark it as bootable
  93         parted -s ${SDIMG} unit KiB mkpart primary fat32 ${IMAGE_ROOTFS_ALIGNMENT} $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT})
  94         parted -s ${SDIMG} set 1 boot on
  95         # Create rootfs partition to the end of disk
  96         parted -s ${SDIMG} -- unit KiB mkpart primary ext2 $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT}) -1s
  97         parted ${SDIMG} print
  98
  99         # Create a vfat image with boot files
 100         BOOT_BLOCKS=$(LC_ALL=C parted -s ${SDIMG} unit b print | awk '/ 1 / { print substr($4, 1, length($4 -1)) / 512 /2 }')
 101         rm -f ${WORKDIR}/boot.img
 102         mkfs.vfat -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/boot.img $BOOT_BLOCKS
 103         mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/bcm2835-bootfiles/* ::/
 104         if test -n "${DTS}"; then
 105                 # Device Tree Overlays are assumed to be suffixed by '-overlay.dtb' (4.1.x) or by '.dtbo' (4.4.9+) string and will be put in a dedicated folder
 106                 DT_OVERLAYS="${@split_overlays(d, 0)}"
 107                 DT_ROOT="${@split_overlays(d, 1)}"
 108
 109                 # Copy board device trees to root folder
 110                 for DTB in ${DT_ROOT}; do
 111                         DTB_BASE_NAME=`basename ${DTB} .dtb`
 112
 113                         mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTB_BASE_NAME}.dtb ::${DTB_BASE_NAME}.dtb
 114                 done
 115
 116                 # Copy device tree overlays to dedicated folder
 117                 mmd -i ${WORKDIR}/boot.img overlays
 118                 for DTB in ${DT_OVERLAYS}; do
 119                                 DTB_EXT=${DTB##*.}
 120                                 DTB_BASE_NAME=`basename ${DTB} ."${DTB_EXT}"`
 121
 122                         mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${DTB_BASE_NAME}.${DTB_EXT} ::overlays/${DTB_BASE_NAME}.${DTB_EXT}
 123                 done
 124         fi
 125         case "${KERNEL_IMAGETYPE}" in
 126         "uImage")
 127                 mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/u-boot.bin ::${SDIMG_KERNELIMAGE}
 128                 mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}${KERNEL_INITRAMFS}-${MACHINE}.bin ::uImage
 129                 mcopy -o -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/boot.scr ::boot.scr
 130                 ;;
 131         *)
 132                 mcopy -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}${KERNEL_INITRAMFS}-${MACHINE}.bin ::${SDIMG_KERNELIMAGE}
 133                 ;;
 134         esac
 135
 136         if [ -n ${FATPAYLOAD} ] ; then
 137                 echo "Copying payload into VFAT"
 138                 for entry in ${FATPAYLOAD} ; do
 139                                 # add the || true to stop aborting on vfat issues like not supporting .~lock files
 140                                 mcopy -i ${WORKDIR}/boot.img -s -v ${IMAGE_ROOTFS}$entry :: || true
 141                 done
 142         fi
 143
 144         # Add stamp file
 145         echo "${IMAGE_NAME}" > ${WORKDIR}/image-version-info
 146         mcopy -i ${WORKDIR}/boot.img -v ${WORKDIR}/image-version-info ::
 147
 148         # Burn Partitions
 149         dd if=${WORKDIR}/boot.img of=${SDIMG} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 150         # If SDIMG_ROOTFS_TYPE is a .xz file use xzcat
 151         if echo "${SDIMG_ROOTFS_TYPE}" | egrep -q "*\.xz"
 152         then
 153                 xzcat ${SDIMG_ROOTFS} | dd of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 154         else
 155                 dd if=${SDIMG_ROOTFS} of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024) && sync && sync
 156         fi
 157
 158         # Optionally apply compression
 159         case "${SDIMG_COMPRESSION}" in
 160         "gzip")
 161                 gzip -k9 "${SDIMG}"
 162                 ;;
 163         "bzip2")
 164                 bzip2 -k9 "${SDIMG}"
 165                 ;;
 166         "xz")
 167                 xz -k "${SDIMG}"
 168                 ;;
 169         esac
 170 }
 171
 172 ROOTFS_POSTPROCESS_COMMAND += " rpi_generate_sysctl_config ; "
 173
 174 rpi_generate_sysctl_config() {
 175         # systemd sysctl config
 176         test -d ${IMAGE_ROOTFS}${sysconfdir}/sysctl.d && \
 177                 echo "vm.min_free_kbytes = 8192" > ${IMAGE_ROOTFS}${sysconfdir}/sysctl.d/rpi-vm.conf
 178
 179         # sysv sysctl config
 180         IMAGE_SYSCTL_CONF="${IMAGE_ROOTFS}${sysconfdir}/sysctl.conf"
 181         test -e ${IMAGE_ROOTFS}${sysconfdir}/sysctl.conf && \
 182                 sed -e "/vm.min_free_kbytes/d" -i ${IMAGE_SYSCTL_CONF}
 183         echo "" >> ${IMAGE_SYSCTL_CONF} && echo "vm.min_free_kbytes = 8192" >> ${IMAGE_SYSCTL_CONF}
 184 }