meta-agl-bsp/classes/image-vm.bbclass

   1 # image-vm.bbclass
   2 # (loosly based off image-live.bbclass Copyright (C) 2004, Advanced Micro Devices, Inc.)
   3 #
   4 # Create an image which can be placed directly onto a harddisk using dd and then
   5 # booted.
   6 #
   7 # This uses syslinux. extlinux would have been nice but required the ext2/3
   8 # partition to be mounted. grub requires to run itself as part of the install
   9 # process.
  10 #
  11 # The end result is a 512 boot sector populated with an MBR and partition table
  12 # followed by an msdos fat16 partition containing syslinux and a linux kernel
  13 # completed by the ext2/3 rootfs.
  14 #
  15 # We have to push the msdos parition table size > 16MB so fat 16 is used as parted
  16 # won't touch fat12 partitions.
  17
  18 inherit live-vm-common
  19
  20 do_bootdirectdisk[depends] += "dosfstools-native:do_populate_sysroot \
  21                                virtual/kernel:do_deploy \
  22                                syslinux:do_populate_sysroot \
  23                                syslinux-native:do_populate_sysroot \
  24                                parted-native:do_populate_sysroot \
  25                                mtools-native:do_populate_sysroot \
  26                                ${PN}:do_image_${VM_ROOTFS_TYPE} \
  27                                "
  28
  29 IMAGE_TYPEDEP_vmdk = "${VM_ROOTFS_TYPE}"
  30 IMAGE_TYPEDEP_vmdk.xz = "${VM_ROOTFS_TYPE}"
  31 IMAGE_TYPEDEP_vdi = "${VM_ROOTFS_TYPE}"
  32 IMAGE_TYPEDEP_qcow2 = "${VM_ROOTFS_TYPE}"
  33 IMAGE_TYPEDEP_hdddirect = "${VM_ROOTFS_TYPE}"
  34 IMAGE_TYPES_MASKED += "vmdk vmdk.xz vdi qcow2 hdddirect"
  35
  36 VM_ROOTFS_TYPE ?= "ext4"
  37 ROOTFS ?= "${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.${VM_ROOTFS_TYPE}"
  38
  39 # Used by bootloader
  40 LABELS_VM ?= "boot"
  41 ROOT_VM ?= "root=/dev/sda2"
  42 # Using an initramfs is optional. Enable it by setting INITRD_IMAGE_VM.
  43 INITRD_IMAGE_VM ?= ""
  44 INITRD_VM ?= "${@'${IMGDEPLOYDIR}/${INITRD_IMAGE_VM}-${MACHINE}.cpio.gz' if '${INITRD_IMAGE_VM}' else ''}"
  45 do_bootdirectdisk[depends] += "${@'${INITRD_IMAGE_VM}:do_image_complete' if '${INITRD_IMAGE_VM}' else ''}"
  46
  47 BOOTDD_VOLUME_ID   ?= "boot"
  48 BOOTDD_EXTRA_SPACE ?= "16384"
  49
  50 DISK_SIGNATURE ?= "${DISK_SIGNATURE_GENERATED}"
  51 DISK_SIGNATURE[vardepsexclude] = "DISK_SIGNATURE_GENERATED"
  52
  53 build_boot_dd() {
  54         HDDDIR="${S}/hdd/boot"
  55         HDDIMG="${S}/hdd.image"
  56         IMAGE=${IMGDEPLOYDIR}/${IMAGE_NAME}.hdddirect
  57
  58         populate_kernel $HDDDIR
  59
  60         if [ "${PCBIOS}" = "1" ]; then
  61                 syslinux_hddimg_populate $HDDDIR
  62         fi
  63         if [ "${EFI}" = "1" ]; then
  64                 efi_hddimg_populate $HDDDIR
  65         fi
  66
  67         BLOCKS=`du -bks $HDDDIR | cut -f 1`
  68         BLOCKS=`expr $BLOCKS + ${BOOTDD_EXTRA_SPACE}`
  69
  70         # Remove it since mkdosfs would fail when it exists
  71         rm -f $HDDIMG
  72         mkdosfs -n ${BOOTDD_VOLUME_ID} -S 512 -C $HDDIMG $BLOCKS
  73         mcopy -i $HDDIMG -s $HDDDIR/* ::/
  74
  75         if [ "${PCBIOS}" = "1" ]; then
  76                 syslinux_hdddirect_install $HDDIMG
  77         fi
  78         chmod 644 $HDDIMG
  79
  80         ROOTFSBLOCKS=`du -Lbks ${ROOTFS} | cut -f 1`
  81         TOTALSIZE=`expr $BLOCKS + $ROOTFSBLOCKS`
  82         END1=`expr $BLOCKS \* 1024`
  83         END2=`expr $END1 + 512`
  84         END3=`expr \( $ROOTFSBLOCKS \* 1024 \) + $END1`
  85
  86         echo $ROOTFSBLOCKS $TOTALSIZE $END1 $END2 $END3
  87         rm -rf $IMAGE
  88         dd if=/dev/zero of=$IMAGE bs=1024 seek=$TOTALSIZE count=1
  89
  90         parted $IMAGE mklabel msdos
  91         parted $IMAGE mkpart primary fat16 0 ${END1}B
  92         parted $IMAGE unit B mkpart primary ext2 ${END2}B ${END3}B
  93         parted $IMAGE set 1 boot on
  94
  95         parted $IMAGE print
  96
  97         awk "BEGIN { printf \"$(echo ${DISK_SIGNATURE} | fold -w 2 | tac | paste -sd '' | sed 's/\(..\)/\\x&/g')\" }" | \
  98                 dd of=$IMAGE bs=1 seek=440 conv=notrunc
  99
 100         OFFSET=`expr $END2 / 512`
 101         if [ "${PCBIOS}" = "1" ]; then
 102                 dd if=${STAGING_DATADIR}/syslinux/mbr.bin of=$IMAGE conv=notrunc
 103         fi
 104
 105         dd if=$HDDIMG of=$IMAGE conv=notrunc seek=1 bs=512
 106         dd if=${ROOTFS} of=$IMAGE conv=notrunc seek=$OFFSET bs=512
 107
 108         cd ${IMGDEPLOYDIR}
 109
 110         ln -sf ${IMAGE_NAME}.hdddirect ${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.hdddirect
 111 }
 112
 113 python do_bootdirectdisk() {
 114     validate_disk_signature(d)
 115     set_live_vm_vars(d, 'VM')
 116     if d.getVar("PCBIOS", True) == "1":
 117         bb.build.exec_func('build_syslinux_cfg', d)
 118     if d.getVar("EFI", True) == "1":
 119         bb.build.exec_func('build_efi_cfg', d)
 120     bb.build.exec_func('build_boot_dd', d)
 121 }
 122
 123 def generate_disk_signature():
 124     import uuid
 125
 126     signature = str(uuid.uuid4())[:8]
 127
 128     if signature != '00000000':
 129         return signature
 130     else:
 131         return 'ffffffff'
 132
 133 def validate_disk_signature(d):
 134     import re
 135
 136     disk_signature = d.getVar("DISK_SIGNATURE", True)
 137
 138     if not re.match(r'^[0-9a-fA-F]{8}$', disk_signature):
 139         bb.fatal("DISK_SIGNATURE '%s' must be an 8 digit hex string" % disk_signature)
 140
 141 DISK_SIGNATURE_GENERATED := "${@generate_disk_signature()}"
 142
 143 run_qemu_img (){
 144     type="$1"
 145     qemu-img convert -O $type ${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.hdddirect ${IMGDEPLOYDIR}/${IMAGE_NAME}.$type
 146
 147     ln -sf ${IMAGE_NAME}.$type ${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.$type
 148 }
 149 create_vmdk_image () {
 150     run_qemu_img vmdk
 151 }
 152
 153 create_vmdkxz_image () {
 154     run_qemu_img vmdk
 155     xz -f ${XZ_COMPRESSION_LEVEL} ${XZ_THREADS} --check=${XZ_INTEGRITY_CHECK} ${IMGDEPLOYDIR}/${IMAGE_NAME}.vmdk
 156     ln -sf ${IMAGE_NAME}.vmdk.xz ${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.vmdk.xz
 157     rm -f ${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.vmdk
 158 }
 159
 160 create_vdi_image () {
 161     run_qemu_img vdi
 162 }
 163
 164 create_qcow2_image () {
 165     run_qemu_img qcow2
 166 }
 167
 168 python do_vmimg() {
 169     if bb.utils.contains('IMAGE_FSTYPES', 'vmdk.xz', True, False, d):
 170         bb.build.exec_func('create_vmdkxz_image', d)
 171     if bb.utils.contains('IMAGE_FSTYPES', 'vmdk', True, False, d):
 172         bb.build.exec_func('create_vmdk_image', d)
 173     if 'vdi' in d.getVar('IMAGE_FSTYPES', True):
 174         bb.build.exec_func('create_vdi_image', d)
 175     if 'qcow2' in d.getVar('IMAGE_FSTYPES', True):
 176         bb.build.exec_func('create_qcow2_image', d)
 177 }
 178
 179 addtask bootdirectdisk before do_vmimg
 180 addtask vmimg after do_bootdirectdisk before do_image_complete
 181 do_vmimg[depends] += "qemu-native:do_populate_sysroot"