meta-agl/recipes-multimedia/lightmediascanner/lightmediascanner_%.bbappend

   1 # Disable everything but the roygalty-free formats
   2 PACKAGECONFIG = "ogg flac wave m3u pls jpeg png"
   3
   4 FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
   5
   6 SRC_URI += "file://lightmediascanner.service \
   7             file://plugin-ogg-fix-chucksize-issue.patch \
   8             file://dbus-lightmediascanner.conf \
   9             file://90-lightmediascanner.rules \
  10             file://lightmediascanner.sh \
  11            "
  12
  13 CFLAGS_append = " -D_FILE_OFFSET_BITS=64"
  14
  15 inherit systemd
  16
  17 do_install_append() {
  18        # Install LMS systemd service
  19        if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
  20               install -m 644 -p -D ${WORKDIR}/lightmediascanner.service ${D}${systemd_user_unitdir}/lightmediascanner.service
  21
  22               # Execute these manually on behalf of systemctl script (from systemd-systemctl-native.bb)
  23               # because it does not support systemd's user mode.
  24               mkdir -p ${D}/etc/systemd/user/default.target.wants/
  25               ln -sf ${systemd_user_unitdir}/lightmediascanner.service ${D}/etc/systemd/user/dbus-org.lightmediascanner.service
  26               ln -sf ${systemd_user_unitdir}/lightmediascanner.service ${D}/etc/systemd/user/default.target.wants/lightmediascanner.service
  27        fi
  28
  29        if ${@bb.utils.contains('DISTRO_FEATURES', 'automount', 'true', 'false', d)}; then
  30               install -m 644 -p -D ${WORKDIR}/90-lightmediascanner.rules ${D}/etc/udev/rules.d/90-lightmediascanner.rules
  31               install -m 755 -p -D ${WORKDIR}/lightmediascanner.sh ${D}/etc/udev/scripts/lightmediascanner.sh
  32        fi
  33
  34        install -d ${D}/etc/dbus-1/session.d
  35        install -m 0644 ${WORKDIR}/dbus-lightmediascanner.conf ${D}/etc/dbus-1/session.d/lightmediascanner.conf
  36 }
  37
  38 FILES_${PN} += " \
  39     ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_user_unitdir}/lightmediascanner.service', '', d)} \
  40     "