meta-agl/recipes-graphics/wayland/weston-init.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
   2
   3 inherit agl-graphical
   4
   5 WESTONSTART ??= "/usr/bin/weston ${WESTONARGS}"
   6 WESTONSTART_append = " ${@bb.utils.contains("IMAGE_FEATURES", "debug-tweaks", " --log=${DISPLAY_XDG_RUNTIME_DIR}/weston.log", "",d)}"
   7
   8 SRC_URI += " \
   9     file://weston_tmpfiles.conf \
  10     file://weston.service.add \
  11 "
  12
  13 do_install_append() {
  14     sed -i "/\[Unit\]/aConflicts=getty@tty${WESTONTTY}.service" \
  15            ${D}${systemd_system_unitdir}/weston.service
  16
  17     sed -i "/\[Service\]/r ${S}/weston.service.add" \
  18            ${D}${systemd_system_unitdir}/weston.service
  19
  20     if ! grep -q '^Group=' ${D}${systemd_system_unitdir}/weston.service; then
  21         sed -i "/\[Service\]/aGroup=root" ${D}${systemd_system_unitdir}/weston.service
  22     fi
  23     if ! grep -q '^User=' ${D}${systemd_system_unitdir}/weston.service; then
  24         sed -i "/\[Service\]/aUser=root" ${D}${systemd_system_unitdir}/weston.service
  25     fi
  26
  27     sed -e 's,User=root,User=${WESTONUSER},g' \
  28         -e 's,Group=root,Group=${WESTONGROUP},g' \
  29         -e 's,ExecStart=.*,ExecStart=${WESTONSTART},g' \
  30         -e 's,@WESTONTTY@,${WESTONTTY},g' \
  31         -e 's,@XDG_RUNTIME_DIR@,${DISPLAY_XDG_RUNTIME_DIR},g' \
  32         -i ${D}${systemd_system_unitdir}/weston.service
  33
  34     # Add a rule to ensure the 'display' user has permissions to
  35     # open the graphics device
  36     install -d ${D}${sysconfdir}/init.d
  37     install -d ${D}${sysconfdir}/udev/rules.d
  38     cat >${D}${sysconfdir}/udev/rules.d/zz-dri.rules <<'EOF'
  39 SUBSYSTEM=="drm", MODE="0660", GROUP="${WESTONGROUP}", SECLABEL{smack}="*", TAG+="systemd", ENV{SYSTEMD_WANTS}="weston.service"
  40 EOF
  41
  42     # user 'display' must own /dev/tty${WESTONTTY} for weston to start correctly
  43     cat >${D}${sysconfdir}/udev/rules.d/zz-tty.rules <<'EOF'
  44 SUBSYSTEM=="tty", KERNEL=="tty${WESTONTTY}", OWNER="${WESTONUSER}", SECLABEL{smack}="^", TAG+="systemd", ENV{SYSTEMD_WANTS}="weston.service"
  45 EOF
  46
  47     # user 'display' must also be able to access /dev/input/*
  48     cat >${D}${sysconfdir}/udev/rules.d/zz-input.rules <<'EOF'
  49 SUBSYSTEM=="input", MODE="0660", GROUP="input", SECLABEL{smack}="^", TAG+="systemd", ENV{SYSTEMD_WANTS}="weston.service"
  50 EOF
  51
  52     # user 'display' must also be able to access /dev/media*, etc.
  53     cat >${D}${sysconfdir}/udev/rules.d/zz-remote-display.rules <<'EOF'
  54 SUBSYSTEM=="media", MODE="0660", GROUP="display", SECLABEL{smack}="*", TAG+="systemd", ENV{SYSTEMD_WANTS}="weston.service"
  55 SUBSYSTEM=="video4linux", MODE="0660", GROUP="display", SECLABEL{smack}="*", TAG+="systemd", ENV{SYSTEMD_WANTS}="weston.service"
  56 KERNEL=="uvcs", SUBSYSTEM=="misc", MODE="0660", GROUP="display", SECLABEL{smack}="*"
  57 KERNEL=="rgnmm", SUBSYSTEM=="misc", MODE="0660", GROUP="display", SECLABEL{smack}="*"
  58 EOF
  59
  60     install -d ${D}${sysconfdir}/tmpfiles.d
  61     install -Dm755 ${WORKDIR}/weston_tmpfiles.conf ${D}/${libdir}/tmpfiles.d/weston.conf
  62
  63     sed -e 's,@WESTONUSER@,${WESTONUSER},g' \
  64         -e 's,@WESTONGROUP@,${WESTONGROUP},g' \
  65         -i ${D}/${libdir}/tmpfiles.d/weston.conf
  66 }
  67
  68 do_install_append_imx() {
  69
  70     install -d ${D}${sysconfdir}/udev/rules.d
  71     cat >>${D}${sysconfdir}/udev/rules.d/zz-dri.rules <<'EOF'
  72 SUBSYSTEM=="gpu_class", MODE="0660", GROUP="${WESTONGROUP}", SECLABEL{smack}="*"
  73 EOF
  74
  75 }
  76
  77 FILES_${PN} += "${libdir}/tmpfiles.d/*.conf"
  78
  79