meta-agl/recipes-connectivity/bluez5/bluez5.inc

   1 SUMMARY = "Linux Bluetooth Stack Userland V5"
   2 DESCRIPTION = "Linux Bluetooth stack V5 userland components.  These include a system configurations, daemons, tools and system libraries."
   3 HOMEPAGE = "http://www.bluez.org"
   4 SECTION = "libs"
   5 LICENSE = "GPLv2+ & LGPLv2.1+"
   6 LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
   7                     file://COPYING.LIB;md5=fb504b67c50331fc78734fed90fb0e09 \
   8                     file://src/main.c;beginline=1;endline=24;md5=9bc54b93cd7e17bf03f52513f39f926e"
   9 DEPENDS = "udev libusb dbus-glib glib-2.0 libcheck readline"
  10 PROVIDES += "bluez-hcidump"
  11 RPROVIDES_${PN} += "bluez-hcidump"
  12
  13 RCONFLICTS_${PN} = "bluez4"
  14
  15 PACKAGECONFIG ??= "obex-profiles"
  16 PACKAGECONFIG[obex-profiles] = "--enable-obex,--disable-obex,libical"
  17 PACKAGECONFIG[experimental] = "--enable-experimental,--disable-experimental,"
  18
  19 SRC_URI = "\
  20     git://git.kernel.org/pub/scm/bluetooth/bluez.git;protocol=https;branch=master \
  21     file://out-of-tree.patch \
  22     file://init \
  23     file://run-ptest \
  24     ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '', 'file://0001-Allow-using-obexd-without-systemd-in-the-user-sessio.patch', d)} \
  25     file://0001-tests-add-a-target-for-building-tests-without-runnin.patch \
  26 "
  27 SRCREV = "c64b4d9e8dc3e36672061f39a9dba19ad0fb1ef1"
  28 S = "${WORKDIR}/git"
  29
  30 inherit autotools pkgconfig systemd update-rc.d distro_features_check ptest
  31
  32 EXTRA_OECONF = "\
  33   --enable-tools \
  34   --disable-cups \
  35   --enable-test \
  36   --enable-datafiles \
  37   ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-systemd', '--disable-systemd', d)} \
  38   --enable-library \
  39 "
  40
  41 # bluez5 builds a large number of useful utilities but does not
  42 # install them.  Specify which ones we want put into ${PN}-noinst-tools.
  43 NOINST_TOOLS_READLINE ??= ""
  44 NOINST_TOOLS_EXPERIMENTAL ??= ""
  45 NOINST_TOOLS = " \
  46     ${NOINST_TOOLS_READLINE} \
  47     ${@bb.utils.contains('PACKAGECONFIG', 'experimental', '${NOINST_TOOLS_EXPERIMENTAL}', '', d)} \
  48 "
  49
  50 do_install_append() {
  51         install -d ${D}${INIT_D_DIR}
  52         install -m 0755 ${WORKDIR}/init ${D}${INIT_D_DIR}/bluetooth
  53
  54         install -d ${D}${sysconfdir}/bluetooth/
  55         if [ -f ${S}/profiles/audio/audio.conf ]; then
  56             install -m 0644 ${S}/profiles/audio/audio.conf ${D}/${sysconfdir}/bluetooth/
  57         fi
  58         if [ -f ${S}/profiles/network/network.conf ]; then
  59             install -m 0644 ${S}/profiles/network/network.conf ${D}/${sysconfdir}/bluetooth/
  60         fi
  61         if [ -f ${S}/profiles/input/input.conf ]; then
  62             install -m 0644 ${S}/profiles/input/input.conf ${D}/${sysconfdir}/bluetooth/
  63         fi
  64
  65   if [ -f ${D}/${sysconfdir}/init.d/bluetooth ]; then
  66     sed -i -e 's#@LIBEXECDIR@#${libexecdir}#g' ${D}/${sysconfdir}/init.d/bluetooth
  67   fi
  68
  69         # Install desired tools that upstream leaves in build area
  70         for f in ${NOINST_TOOLS} ; do
  71             install -m 755 ${B}/$f ${D}/${bindir}
  72         done
  73 }
  74
  75 ALLOW_EMPTY_libasound-module-bluez = "1"
  76 PACKAGES =+ "libasound-module-bluez ${PN}-testtools ${PN}-obex ${PN}-noinst-tools"
  77
  78 FILES_libasound-module-bluez = "${libdir}/alsa-lib/lib*.so ${datadir}/alsa"
  79 FILES_${PN} += "${libdir}/bluetooth/plugins/*.so ${base_libdir}/udev/ ${nonarch_base_libdir}/udev/ ${systemd_unitdir}/ ${datadir}/dbus-1"
  80 FILES_${PN}-dev += "\
  81   ${libdir}/bluetooth/plugins/*.la \
  82   ${libdir}/alsa-lib/*.la \
  83 "
  84
  85 FILES_${PN}-obex = "${libexecdir}/bluetooth/obexd \
  86                     ${exec_prefix}/lib/systemd/user/obex.service \
  87                     ${datadir}/dbus-1/services/org.bluez.obex.service \
  88                    "
  89 SYSTEMD_SERVICE_${PN}-obex = "obex.service"
  90
  91 FILES_${PN}-testtools = "${libdir}/bluez/test/*"
  92
  93 def get_noinst_tools_paths (d, bb, tools):
  94     s = list()
  95     bindir = d.getVar("bindir", True)
  96     for bdp in tools.split():
  97         f = os.path.basename(bdp)
  98         s.append("%s/%s" % (bindir, f))
  99     return "\n".join(s)
 100
 101 FILES_${PN}-noinst-tools = "${@get_noinst_tools_paths(d, bb, d.getVar('NOINST_TOOLS', True))}"
 102
 103 RDEPENDS_${PN}-testtools += "python python-dbus python-pygobject"
 104
 105 SYSTEMD_SERVICE_${PN} = "bluetooth.service"
 106 INITSCRIPT_PACKAGES = "${PN}"
 107 INITSCRIPT_NAME_${PN} = "bluetooth"
 108
 109 EXCLUDE_FROM_WORLD = "1"
 110
 111 do_compile_ptest() {
 112         oe_runmake buildtests
 113 }
 114
 115 do_install_ptest() {
 116         cp -r ${B}/unit/ ${D}${PTEST_PATH}
 117         rm -f ${D}${PTEST_PATH}/unit/*.o
 118 }