meson.build

   1 project('agl-compositor',
   2   'c','cpp',
   3   version: '0.0.19',
   4   default_options: [
   5     'warning_level=3',
   6     'c_std=gnu99',
   7   ],
   8   meson_version: '>= 0.47',
   9   license: 'MIT/Expat',
  10 )
  11
  12 config_h = configuration_data()
  13 agl_compositor_version = '0.0.19'
  14 libweston_version = 'libweston-8'
  15 pkgconfig = import('pkgconfig')
  16
  17 cc = meson.get_compiler('c')
  18 cxx = meson.get_compiler('cpp')
  19
  20 add_project_arguments(
  21   cc.get_supported_arguments([
  22     '-Wno-unused-parameter',
  23     '-Wno-pedantic',
  24     '-Wextra',
  25     '-Werror'
  26   ]),
  27   language: 'c'
  28 )
  29
  30 add_project_arguments([
  31     '-DPACKAGE_STRING="agl-compositor @0@"'.format(meson.project_version()),
  32     '-D_GNU_SOURCE',
  33     '-D_ALL_SOURCE',
  34   ],
  35   language: 'c'
  36 )
  37
  38 optional_libc_funcs = [ 'memfd_create', 'strchrnul' ]
  39 foreach func: optional_libc_funcs
  40     if cc.has_function(func)
  41         add_project_arguments('-DHAVE_@0@=1'.format(func.to_upper()), language: 'c')
  42     endif
  43 endforeach
  44
  45 dep_libsystemd = dependency('libsystemd', required: false)
  46 dep_libsmack = dependency('libsmack', required: false)
  47 dep_scanner = dependency('wayland-scanner', native: true)
  48 prog_scanner = find_program(dep_scanner.get_pkgconfig_variable('wayland_scanner'))
  49 dep_wp = dependency('wayland-protocols', version: '>= 1.18')
  50 dir_wp_base = dep_wp.get_pkgconfig_variable('pkgdatadir')
  51
  52 depnames = [
  53   'gstreamer-1.0', 'gstreamer-allocators-1.0',
  54   'gstreamer-app-1.0', 'gstreamer-video-1.0',
  55   'gobject-2.0', 'glib-2.0'
  56 ]
  57
  58 deps_remoting = []
  59 foreach depname : depnames
  60   dep = dependency(depname, required: false)
  61   if not dep.found()
  62     message('Remoting requires @0@ which was not found. '.format(depname))
  63   endif
  64   deps_remoting += dep
  65 endforeach
  66
  67
  68 # the transmitter plug-in requires waltham but we don't have a cflags or libs
  69 # for it so we add waltham depends here. Further more, the output is being
  70 # handled by remoting plug-in
  71 depnames_waltham = [
  72   'waltham'
  73 ]
  74
  75 deps_waltham = []
  76 foreach depname : depnames_waltham
  77   dep = dependency(depname, required: false)
  78   if dep.found()
  79     deps_waltham += dep
  80   else
  81     message('Waltham requires @0@ which was not found. '.format(depname))
  82   endif
  83 endforeach
  84
  85 deps_waltham += deps_remoting
  86
  87 agl_shell_xml = files('protocol/agl-shell.xml')
  88 agl_shell_desktop_xml = files('protocol/agl-shell-desktop.xml')
  89 agl_screenshooter = files('protocol/agl-screenshooter.xml')
  90 xdg_shell_xml = join_paths(dir_wp_base, 'stable', 'xdg-shell', 'xdg-shell.xml')
  91
  92 protocols = [
  93   { 'name': 'agl-shell', 'source': 'internal' },
  94   { 'name': 'agl-shell-desktop', 'source': 'internal' },
  95   { 'name': 'agl-screenshooter', 'source': 'internal' },
  96   { 'name': 'xdg-shell', 'source': 'wp-stable' },
  97   { 'name': 'xdg-output', 'source': 'unstable', 'version': 'v1' },
  98 ]
  99
 100 foreach proto: protocols
 101     proto_name = proto['name']
 102     if proto['source'] == 'internal'
 103         base_file = proto_name
 104         xml_path = join_paths('protocol', '@0@.xml'.format(base_file))
 105     elif proto['source'] == 'wp-stable'
 106         base_file = proto_name
 107         xml_path = join_paths(dir_wp_base, 'stable', proto_name, '@0@.xml'.format(base_file))
 108     else
 109         base_file = '@0@-unstable-@1@'.format(proto_name, proto['version'])
 110         xml_path = join_paths(dir_wp_base, 'unstable', proto_name, '@0@.xml'.format(base_file))
 111     endif
 112
 113     foreach output_type: [ 'client-header', 'server-header', 'private-code' ]
 114         if output_type == 'client-header'
 115             output_file = '@0@-client-protocol.h'.format(base_file)
 116         elif output_type == 'server-header'
 117             output_file = '@0@-server-protocol.h'.format(base_file)
 118         else
 119             output_file = '@0@-protocol.c'.format(base_file)
 120             if dep_scanner.version().version_compare('< 1.14.91')
 121                 output_type = 'code'
 122             endif
 123         endif
 124
 125         var_name = output_file.underscorify()
 126         target = custom_target(
 127             '@0@ @1@'.format(base_file, output_type),
 128             command: [ prog_scanner, output_type, '@INPUT@', '@OUTPUT@' ],
 129             input: xml_path,
 130             output: output_file,
 131         )
 132
 133         set_variable(var_name, target)
 134     endforeach
 135 endforeach
 136
 137 # libweston-6 pkg-config file already has 'libweston-6' as prefix but
 138 # agl-compositor uses 'libweston-6' also. This makes use of the prefix
 139 # path as to allow building and installing the compositor locally
 140 prefix_path = get_option('prefix')
 141 message('prefix_path ' + prefix_path)
 142 if not prefix_path.contains('/usr')
 143   additional_include_dir = include_directories(prefix_path + '/' + 'include')
 144   local_dep = declare_dependency(include_directories: additional_include_dir)
 145 else
 146   local_dep = []
 147 endif
 148
 149 dir_data = join_paths(prefix_path, get_option('datadir'))
 150 dir_data_agl_compositor = join_paths('agl-compositor', 'protocols')
 151 dir_data_pc = join_paths(dir_data, 'pkgconfig')
 152 libweston_dep = dependency(libweston_version)
 153
 154 deps_libweston = [
 155   dependency('wayland-server'),
 156   libweston_dep,
 157   dependency('libweston-desktop-8'),
 158   local_dep,
 159 ]
 160
 161 srcs_agl_compositor = [
 162         'src/main.c',
 163         'src/desktop.c',
 164         'src/layout.c',
 165         'src/policy.c',
 166         'src/shell.c',
 167         'src/screenshooter.c',
 168         'src/input.c',
 169         'shared/option-parser.c',
 170         'shared/os-compatibility.c',
 171         agl_shell_server_protocol_h,
 172         agl_shell_desktop_server_protocol_h,
 173         agl_screenshooter_server_protocol_h,
 174         agl_shell_protocol_c,
 175         agl_shell_desktop_protocol_c,
 176         agl_screenshooter_protocol_c,
 177         xdg_shell_protocol_c,
 178 ]
 179
 180 policy_to_install = get_option('policy-default')
 181 if policy_to_install == 'auto' or policy_to_install == 'allow-all'
 182   srcs_agl_compositor += 'src/policy-default.c'
 183   message('Installing allow all policy')
 184 elif policy_to_install == 'deny-all'
 185   srcs_agl_compositor += 'src/policy-deny.c'
 186   message('Installing deny all policy')
 187 elif policy_to_install == 'rba'
 188   srcs_agl_compositor += ['src/policy-rba.c', 'src/rba_adapter.cpp']
 189   deps_libweston += dependency('librba')
 190   message('Installing rba policy')
 191 endif
 192
 193
 194 # From meson documentation:
 195 # In order to look for headers in a specific directory you can use args :
 196 # '-I/extra/include/dir, but this should only be used in exceptional cases for
 197 # includes that can't be detected via pkg-config and passed via dependencies.
 198 if libweston_dep.found()
 199   if not meson.is_cross_build()
 200     if not prefix_path.contains('/usr')
 201       dir_path_x11_backend = join_paths(prefix_path, 'include', libweston_version, 'libweston', 'backend-x11.h')
 202     else
 203       dir_path_x11_backend = join_paths(libweston_version, 'libweston', 'backend-x11.h')
 204     endif
 205   else
 206     message('Building with cross environment')
 207     dir_path_x11_backend = join_paths(libweston_version, 'libweston', 'backend-x11.h')
 208   endif
 209
 210   # do the test
 211   if cc.has_header(dir_path_x11_backend)
 212     config_h.set('HAVE_BACKEND_X11', 1)
 213   endif
 214 endif
 215
 216 if dep_libsystemd.found()
 217   config_h.set('HAVE_SYSTEMD', 1)
 218
 219   srcs_agl_compositor += 'src/systemd-notify.c'
 220   deps_libweston += dep_libsystemd
 221
 222   message('Found systemd, enabling notify support')
 223 endif
 224
 225 if deps_remoting.length() == depnames.length()
 226   config_h.set('HAVE_REMOTING', 1)
 227   message('Found remoting depends, enabling remoting')
 228 endif
 229
 230 if deps_waltham.length() == depnames_waltham.length() + depnames.length()
 231   config_h.set('HAVE_WALTHAM', 1)
 232   message('Found waltham depends, enabling waltham')
 233 endif
 234
 235 if dep_libsmack.found()
 236   config_h.set('HAVE_SMACK', 1)
 237   deps_libweston += dep_libsmack
 238 endif
 239
 240 configure_file(output: 'config.h', configuration: config_h)
 241
 242 exe_agl_compositor = executable(
 243         'agl-compositor',
 244         srcs_agl_compositor,
 245         dependencies: deps_libweston,
 246         install: true
 247 )
 248
 249 pkgconfig.generate(
 250         filebase: 'agl-compositor-@0@-protocols'.format(agl_compositor_version),
 251         name: 'agl-compositor private protocols',
 252         version: agl_compositor_version,
 253         description: 'agl-compositor protocol files',
 254         variables: [
 255                 'datarootdir=' + join_paths('${prefix}', get_option('datadir')),
 256                 'pkgdatadir=' + join_paths('${pc_sysrootdir}${datarootdir}', dir_data_agl_compositor)
 257         ],
 258         install_dir: dir_data_pc
 259 )
 260
 261 install_data(
 262         [ agl_shell_xml, agl_shell_desktop_xml ],
 263         install_dir: join_paths(dir_data, dir_data_agl_compositor)
 264 )
 265
 266 common_inc = [ include_directories('src'), include_directories('.') ]
 267 subdir('clients')