meson.build

   1 project('agl-compositor',
   2   'c','cpp',
   3   version: '0.0.19',
   4   default_options: [
   5     'warning_level=3',
   6     'c_std=gnu99',
   7   ],
   8   meson_version: '>= 0.47',
   9   license: 'MIT/Expat',
  10 )
  11
  12 config_h = configuration_data()
  13 agl_compositor_version = '0.0.19'
  14 libweston_version = 'libweston-9'
  15 pkgconfig = import('pkgconfig')
  16
  17 cc = meson.get_compiler('c')
  18 cxx = meson.get_compiler('cpp')
  19
  20 add_project_arguments(
  21   cc.get_supported_arguments([
  22     '-Wno-missing-field-initializers',
  23     '-Wno-unused-parameter',
  24     '-Wno-pedantic',
  25     '-Wextra',
  26     '-Werror'
  27   ]),
  28   language: 'c'
  29 )
  30
  31 add_project_arguments([
  32     '-DPACKAGE_STRING="agl-compositor @0@"'.format(meson.project_version()),
  33     '-D_GNU_SOURCE',
  34     '-D_ALL_SOURCE',
  35   ],
  36   language: 'c'
  37 )
  38
  39 optional_libc_funcs = [ 'memfd_create', 'strchrnul' ]
  40 foreach func: optional_libc_funcs
  41     if cc.has_function(func)
  42         add_project_arguments('-DHAVE_@0@=1'.format(func.to_upper()), language: 'c')
  43     endif
  44 endforeach
  45
  46 dep_libsystemd = dependency('libsystemd', required: false)
  47 dep_libsmack = dependency('libsmack', required: false)
  48 dep_scanner = dependency('wayland-scanner', native: true)
  49 prog_scanner = find_program(dep_scanner.get_pkgconfig_variable('wayland_scanner'))
  50 dep_wp = dependency('wayland-protocols', version: '>= 1.18')
  51 dir_wp_base = dep_wp.get_pkgconfig_variable('pkgdatadir')
  52
  53 depnames = [
  54   'gstreamer-1.0', 'gstreamer-allocators-1.0',
  55   'gstreamer-app-1.0', 'gstreamer-video-1.0',
  56   'gobject-2.0', 'glib-2.0'
  57 ]
  58
  59 deps_remoting = []
  60 foreach depname : depnames
  61   dep = dependency(depname, required: false)
  62   if not dep.found()
  63     message('Remoting requires @0@ which was not found. '.format(depname))
  64   endif
  65   deps_remoting += dep
  66 endforeach
  67
  68
  69 # the transmitter plug-in requires waltham but we don't have a cflags or libs
  70 # for it so we add waltham depends here. Further more, the output is being
  71 # handled by remoting plug-in
  72 depnames_waltham = [
  73   'waltham'
  74 ]
  75
  76 deps_waltham = []
  77 foreach depname : depnames_waltham
  78   dep = dependency(depname, required: false)
  79   if dep.found()
  80     deps_waltham += dep
  81   else
  82     message('Waltham requires @0@ which was not found. '.format(depname))
  83   endif
  84 endforeach
  85
  86 deps_waltham += deps_remoting
  87
  88 agl_shell_xml = files('protocol/agl-shell.xml')
  89 agl_shell_desktop_xml = files('protocol/agl-shell-desktop.xml')
  90 agl_screenshooter = files('protocol/agl-screenshooter.xml')
  91 xdg_shell_xml = join_paths(dir_wp_base, 'stable', 'xdg-shell', 'xdg-shell.xml')
  92
  93 protocols = [
  94   { 'name': 'agl-shell', 'source': 'internal' },
  95   { 'name': 'weston-test', 'source': 'internal' },
  96   { 'name': 'agl-shell-desktop', 'source': 'internal' },
  97   { 'name': 'agl-screenshooter', 'source': 'internal' },
  98   { 'name': 'xdg-shell', 'source': 'wp-stable' },
  99   { 'name': 'viewporter', 'source': 'wp-stable' },
 100   { 'name': 'xdg-output', 'source': 'unstable', 'version': 'v1' },
 101 ]
 102
 103 foreach proto: protocols
 104     proto_name = proto['name']
 105     if proto['source'] == 'internal'
 106         base_file = proto_name
 107         xml_path = join_paths('protocol', '@0@.xml'.format(base_file))
 108     elif proto['source'] == 'wp-stable'
 109         base_file = proto_name
 110         xml_path = join_paths(dir_wp_base, 'stable', proto_name, '@0@.xml'.format(base_file))
 111     else
 112         base_file = '@0@-unstable-@1@'.format(proto_name, proto['version'])
 113         xml_path = join_paths(dir_wp_base, 'unstable', proto_name, '@0@.xml'.format(base_file))
 114     endif
 115
 116     foreach output_type: [ 'client-header', 'server-header', 'private-code' ]
 117         if output_type == 'client-header'
 118             output_file = '@0@-client-protocol.h'.format(base_file)
 119         elif output_type == 'server-header'
 120             output_file = '@0@-server-protocol.h'.format(base_file)
 121         else
 122             output_file = '@0@-protocol.c'.format(base_file)
 123             if dep_scanner.version().version_compare('< 1.14.91')
 124                 output_type = 'code'
 125             endif
 126         endif
 127
 128         var_name = output_file.underscorify()
 129         target = custom_target(
 130             '@0@ @1@'.format(base_file, output_type),
 131             command: [ prog_scanner, output_type, '@INPUT@', '@OUTPUT@' ],
 132             input: xml_path,
 133             output: output_file,
 134         )
 135
 136         set_variable(var_name, target)
 137     endforeach
 138 endforeach
 139
 140 # libweston-6 pkg-config file already has 'libweston-6' as prefix but
 141 # agl-compositor uses 'libweston-6' also. This makes use of the prefix
 142 # path as to allow building and installing the compositor locally
 143 prefix_path = get_option('prefix')
 144 message('prefix_path ' + prefix_path)
 145 if not prefix_path.contains('/usr')
 146   additional_include_dir = include_directories(prefix_path + '/' + 'include')
 147   local_dep = declare_dependency(include_directories: additional_include_dir)
 148 else
 149   local_dep = []
 150 endif
 151
 152 dir_data = join_paths(prefix_path, get_option('datadir'))
 153 dir_data_agl_compositor = join_paths('agl-compositor', 'protocols')
 154 dir_data_pc = join_paths(dir_data, 'pkgconfig')
 155 libweston_dep = dependency(libweston_version)
 156
 157 deps_libweston = [
 158   dependency('wayland-server'),
 159   libweston_dep,
 160   dependency('libweston-desktop-9'),
 161   local_dep,
 162 ]
 163
 164
 165 srcs_agl_compositor = [
 166         'src/compositor.c',
 167         'src/desktop.c',
 168         'src/layout.c',
 169         'src/policy.c',
 170         'src/shell.c',
 171         'src/screenshooter.c',
 172         'src/input.c',
 173         'shared/option-parser.c',
 174         'shared/os-compatibility.c',
 175         agl_shell_server_protocol_h,
 176         agl_shell_desktop_server_protocol_h,
 177         agl_screenshooter_server_protocol_h,
 178         agl_shell_protocol_c,
 179         agl_shell_desktop_protocol_c,
 180         agl_screenshooter_protocol_c,
 181         xdg_shell_protocol_c,
 182 ]
 183
 184 policy_to_install = get_option('policy-default')
 185 if policy_to_install == 'auto' or policy_to_install == 'allow-all'
 186   srcs_agl_compositor += 'src/policy-default.c'
 187   message('Installing allow all policy')
 188 elif policy_to_install == 'deny-all'
 189   srcs_agl_compositor += 'src/policy-deny.c'
 190   message('Installing deny all policy')
 191 elif policy_to_install == 'rba'
 192   srcs_agl_compositor += ['src/policy-rba.c', 'src/rba_adapter.cpp']
 193   deps_libweston += dependency('librba')
 194   message('Installing rba policy')
 195 endif
 196
 197 # From meson documentation:
 198 # In order to look for headers in a specific directory you can use args :
 199 # '-I/extra/include/dir, but this should only be used in exceptional cases for
 200 # includes that can't be detected via pkg-config and passed via dependencies.
 201 if libweston_dep.found()
 202   if not meson.is_cross_build()
 203     if not prefix_path.contains('/usr')
 204       dir_path_x11_backend = join_paths(prefix_path, 'include', libweston_version, 'libweston', 'backend-x11.h')
 205     else
 206       dir_path_x11_backend = join_paths(libweston_version, 'libweston', 'backend-x11.h')
 207     endif
 208   else
 209     message('Building with cross environment')
 210     dir_path_x11_backend = join_paths(libweston_version, 'libweston', 'backend-x11.h')
 211   endif
 212
 213   # do the test
 214   if cc.has_header(dir_path_x11_backend)
 215     config_h.set('HAVE_BACKEND_X11', 1)
 216   endif
 217 endif
 218
 219 if dep_libsystemd.found()
 220   config_h.set('HAVE_SYSTEMD', 1)
 221
 222   srcs_agl_compositor += 'src/systemd-notify.c'
 223   deps_libweston += dep_libsystemd
 224
 225   message('Found systemd, enabling notify support')
 226 endif
 227
 228 if deps_remoting.length() == depnames.length()
 229   config_h.set('HAVE_REMOTING', 1)
 230   message('Found remoting depends, enabling remoting')
 231 endif
 232
 233 if deps_waltham.length() == depnames_waltham.length() + depnames.length()
 234   config_h.set('HAVE_WALTHAM', 1)
 235   message('Found waltham depends, enabling waltham')
 236 endif
 237
 238 if dep_libsmack.found()
 239   config_h.set('HAVE_SMACK', 1)
 240   deps_libweston += dep_libsmack
 241 endif
 242
 243
 244 libexec_compositor = shared_library(
 245         'exec_compositor',
 246         sources: srcs_agl_compositor,
 247         dependencies: deps_libweston,
 248         install: true,
 249         version: '0.0.0',
 250         soversion: 0
 251 )
 252
 253 dep_libexec_compositor = declare_dependency(
 254         link_with: libexec_compositor,
 255         include_directories: [ include_directories('.') ],
 256         dependencies: deps_libweston,
 257 )
 258
 259 configure_file(output: 'config.h', configuration: config_h)
 260
 261 exe_agl_compositor = executable(
 262         'agl-compositor',
 263         'src/main.c',
 264         dependencies: dep_libexec_compositor,
 265         install: true
 266 )
 267
 268 pkgconfig.generate(
 269         filebase: 'agl-compositor-@0@-protocols'.format(agl_compositor_version),
 270         name: 'agl-compositor private protocols',
 271         version: agl_compositor_version,
 272         description: 'agl-compositor protocol files',
 273         variables: [
 274                 'datarootdir=' + join_paths('${prefix}', get_option('datadir')),
 275                 'pkgdatadir=' + join_paths('${pc_sysrootdir}${datarootdir}', dir_data_agl_compositor)
 276         ],
 277         install_dir: dir_data_pc
 278 )
 279
 280 install_data(
 281         [ agl_shell_xml, agl_shell_desktop_xml ],
 282         install_dir: join_paths(dir_data, dir_data_agl_compositor)
 283 )
 284
 285 common_inc = [ include_directories('src'), include_directories('.') ]
 286 subdir('clients')
 287 subdir('tests')