extra/FindNanopb.cmake

   1 # This is an example script for use with CMake projects for locating and configuring
   2 # the nanopb library.
   3 #
   4 # The following varialbes have to be set:
   5 #
   6 #   NANOPB_SRC_ROOT_FOLDER  - Path to nanopb source folder
   7 #
   8 # The following variables can be set and are optional:
   9 #
  10 #
  11 #   PROTOBUF_SRC_ROOT_FOLDER - When compiling with MSVC, if this cache variable is set
  12 #                              the protobuf-default VS project build locations
  13 #                              (vsprojects/Debug & vsprojects/Release) will be searched
  14 #                              for libraries and binaries.
  15 #
  16 #   NANOPB_IMPORT_DIRS       - List of additional directories to be searched for
  17 #                              imported .proto files.
  18 #
  19 #   NANOPB_GENERATE_CPP_APPEND_PATH - By default -I will be passed to protoc
  20 #                                     for each directory where a proto file is referenced.
  21 #                                     Set to FALSE if you want to disable this behaviour.
  22 #
  23 # Defines the following variables:
  24 #
  25 #   NANOPB_FOUND - Found the nanopb library (source&header files, generator tool, protoc compiler tool)
  26 #   NANOPB_INCLUDE_DIRS - Include directories for Google Protocol Buffers
  27 #
  28 # The following cache variables are also available to set or use:
  29 #   NANOPB_GENERATOR_EXECUTABLE - The nanopb generator
  30 #   PROTOBUF_PROTOC_EXECUTABLE - The protoc compiler
  31 #
  32 #  ====================================================================
  33 #
  34 # NANOPB_GENERATE_CPP (public function)
  35 #   SRCS = Variable to define with autogenerated
  36 #          source files
  37 #   HDRS = Variable to define with autogenerated
  38 #          header files
  39 #   ARGN = proto files
  40 #
  41 #  ====================================================================
  42 #  Example:
  43 #
  44 #   set(NANOPB_SRC_ROOT_FOLDER "/path/to/nanopb")
  45 #   set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${NANOPB_SRC_ROOT_FOLDER}/cmake)
  46 #   find_package( Nanopb REQUIRED )
  47 #   include_directories(${NANOPB_INCLUDE_DIRS})
  48 #
  49 #   NANOPB_GENERATE_CPP(PROTO_SRCS PROTO_HDRS foo.proto)
  50 #
  51 #   include_directories(${CMAKE_CURRENT_BINARY_DIR})
  52 #   add_executable(bar bar.cc ${PROTO_SRCS} ${PROTO_HDRS})
  53 #
  54 #  ====================================================================
  55
  56 #=============================================================================
  57 # Copyright 2009 Kitware, Inc.
  58 # Copyright 2009-2011 Philip Lowman <philip@yhbt.com>
  59 # Copyright 2008 Esben Mose Hansen, Ange Optimization ApS
  60 #
  61 # Redistribution and use in source and binary forms, with or without
  62 # modification, are permitted provided that the following conditions
  63 # are met:
  64 #
  65 # * Redistributions of source code must retain the above copyright
  66 #   notice, this list of conditions and the following disclaimer.
  67 #
  68 # * Redistributions in binary form must reproduce the above copyright
  69 #   notice, this list of conditions and the following disclaimer in the
  70 #   documentation and/or other materials provided with the distribution.
  71 #
  72 # * Neither the names of Kitware, Inc., the Insight Software Consortium,
  73 #   nor the names of their contributors may be used to endorse or promote
  74 #   products derived from this software without specific prior written
  75 #   permission.
  76 #
  77 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  78 # "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  79 # LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  80 # A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  81 # HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  82 # SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  83 # LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  84 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  85 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  86 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  87 # OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  88 #
  89 #=============================================================================
  90 #
  91 # Changes
  92 # 2013.01.31 - Pavlo Ilin - used Modules/FindProtobuf.cmake from cmake 2.8.10 to
  93 #                           write FindNanopb.cmake
  94 #
  95 #=============================================================================
  96
  97
  98 function(NANOPB_GENERATE_CPP SRCS HDRS)
  99   if(NOT ARGN)
 100     return()
 101   endif()
 102
 103   if(NANOPB_GENERATE_CPP_APPEND_PATH)
 104     # Create an include path for each file specified
 105     foreach(FIL ${ARGN})
 106       get_filename_component(ABS_FIL ${FIL} ABSOLUTE)
 107       get_filename_component(ABS_PATH ${ABS_FIL} PATH)
 108
 109       list(FIND _nanobp_include_path ${ABS_PATH} _contains_already)
 110       if(${_contains_already} EQUAL -1)
 111           list(APPEND _nanobp_include_path -I ${ABS_PATH})
 112       endif()
 113     endforeach()
 114   else()
 115     set(_nanobp_include_path -I ${CMAKE_CURRENT_SOURCE_DIR})
 116   endif()
 117
 118   if(DEFINED NANOPB_IMPORT_DIRS)
 119     foreach(DIR ${NANOPB_IMPORT_DIRS})
 120       get_filename_component(ABS_PATH ${DIR} ABSOLUTE)
 121       list(FIND _nanobp_include_path ${ABS_PATH} _contains_already)
 122       if(${_contains_already} EQUAL -1)
 123           list(APPEND _nanobp_include_path -I ${ABS_PATH})
 124       endif()
 125     endforeach()
 126   endif()
 127
 128   set(${SRCS})
 129   set(${HDRS})
 130   get_filename_component(GENERATOR_PATH ${NANOPB_GENERATOR_EXECUTABLE} PATH)
 131   set(GENERATOR_CORE_DIR ${GENERATOR_PATH}/proto)
 132   set(GENERATOR_CORE_SRC
 133       ${GENERATOR_CORE_DIR}/nanopb.proto
 134       ${GENERATOR_CORE_DIR}/plugin.proto)
 135
 136   set(GENERATOR_CORE_PYTHON_SRC)
 137   foreach(FIL ${GENERATOR_CORE_SRC})
 138       get_filename_component(ABS_FIL ${FIL} ABSOLUTE)
 139       get_filename_component(FIL_WE ${FIL} NAME_WE)
 140
 141       set(output "${GENERATOR_CORE_DIR}/${FIL_WE}_pb2.py")
 142       set(GENERATOR_CORE_PYTHON_SRC ${GENERATOR_CORE_PYTHON_SRC} ${output})
 143       add_custom_command(
 144         OUTPUT ${output}
 145         COMMAND ${PROTOBUF_PROTOC_EXECUTABLE}
 146         ARGS -I${GENERATOR_PATH}/proto
 147           --python_out=${GENERATOR_CORE_DIR} ${ABS_FIL}
 148         DEPENDS ${ABS_FIL}
 149         VERBATIM)
 150   endforeach()
 151
 152   foreach(FIL ${ARGN})
 153     get_filename_component(ABS_FIL ${FIL} ABSOLUTE)
 154     get_filename_component(FIL_WE ${FIL} NAME_WE)
 155     get_filename_component(FIL_DIR ${FIL} PATH)
 156     set(NANOPB_OPTIONS_FILE ${FIL_DIR}/${FIL_WE}.options)
 157     set(NANOPB_OPTIONS)
 158     if(EXISTS ${NANOPB_OPTIONS_FILE})
 159         set(NANOPB_OPTIONS -f ${NANOPB_OPTIONS_FILE})
 160     endif()
 161
 162     list(APPEND ${SRCS} "${CMAKE_CURRENT_BINARY_DIR}/${FIL_WE}.pb.c")
 163     list(APPEND ${HDRS} "${CMAKE_CURRENT_BINARY_DIR}/${FIL_WE}.pb.h")
 164
 165     add_custom_command(
 166       OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${FIL_WE}.pb"
 167       COMMAND  ${PROTOBUF_PROTOC_EXECUTABLE}
 168       ARGS -I${GENERATOR_PATH} -I${GENERATOR_CORE_DIR}
 169         -I${CMAKE_CURRENT_BINARY_DIR} ${_nanobp_include_path}
 170         -o${FIL_WE}.pb ${ABS_FIL}
 171       DEPENDS ${ABS_FIL} ${GENERATOR_CORE_PYTHON_SRC}
 172       COMMENT "Running C++ protocol buffer compiler on ${FIL}"
 173       VERBATIM )
 174
 175     add_custom_command(
 176       OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${FIL_WE}.pb.c"
 177              "${CMAKE_CURRENT_BINARY_DIR}/${FIL_WE}.pb.h"
 178       COMMAND ${PYTHON_EXECUTABLE}
 179       ARGS ${NANOPB_GENERATOR_EXECUTABLE} ${FIL_WE}.pb ${NANOPB_OPTIONS}
 180       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${FIL_WE}.pb"
 181       COMMENT "Running nanopb generator on ${FIL_WE}.pb"
 182       VERBATIM )
 183   endforeach()
 184
 185   set_source_files_properties(${${SRCS}} ${${HDRS}} PROPERTIES GENERATED TRUE)
 186   set(${SRCS} ${${SRCS}} ${NANOPB_SRCS} PARENT_SCOPE)
 187   set(${HDRS} ${${HDRS}} ${NANOPB_HDRS} PARENT_SCOPE)
 188
 189 endfunction()
 190
 191
 192
 193 #
 194 # Main.
 195 #
 196
 197 # By default have NANOPB_GENERATE_CPP macro pass -I to protoc
 198 # for each directory where a proto file is referenced.
 199 if(NOT DEFINED NANOPB_GENERATE_CPP_APPEND_PATH)
 200   set(NANOPB_GENERATE_CPP_APPEND_PATH TRUE)
 201 endif()
 202
 203 # Find the include directory
 204 find_path(NANOPB_INCLUDE_DIRS
 205     pb.h
 206     PATHS ${NANOPB_SRC_ROOT_FOLDER}
 207 )
 208 mark_as_advanced(NANOPB_INCLUDE_DIRS)
 209
 210 # Find nanopb source files
 211 set(NANOPB_SRCS)
 212 set(NANOPB_HDRS)
 213 list(APPEND _nanopb_srcs pb_decode.c pb_encode.c pb_common.c)
 214 list(APPEND _nanopb_hdrs pb_decode.h pb_encode.h pb_common.h pb.h)
 215
 216 foreach(FIL ${_nanopb_srcs})
 217   find_file(${FIL}__nano_pb_file NAMES ${FIL} PATHS ${NANOPB_SRC_ROOT_FOLDER} ${NANOPB_INCLUDE_DIRS})
 218   list(APPEND NANOPB_SRCS "${${FIL}__nano_pb_file}")
 219   mark_as_advanced(${FIL}__nano_pb_file)
 220 endforeach()
 221
 222 foreach(FIL ${_nanopb_hdrs})
 223   find_file(${FIL}__nano_pb_file NAMES ${FIL} PATHS ${NANOPB_INCLUDE_DIRS})
 224   mark_as_advanced(${FIL}__nano_pb_file)
 225   list(APPEND NANOPB_HDRS "${${FIL}__nano_pb_file}")
 226 endforeach()
 227
 228 # Find the protoc Executable
 229 find_program(PROTOBUF_PROTOC_EXECUTABLE
 230     NAMES protoc
 231     DOC "The Google Protocol Buffers Compiler"
 232     PATHS
 233     ${PROTOBUF_SRC_ROOT_FOLDER}/vsprojects/Release
 234     ${PROTOBUF_SRC_ROOT_FOLDER}/vsprojects/Debug
 235 )
 236 mark_as_advanced(PROTOBUF_PROTOC_EXECUTABLE)
 237
 238 # Find nanopb generator
 239 find_file(NANOPB_GENERATOR_EXECUTABLE
 240     NAMES nanopb_generator.py
 241     DOC "nanopb generator"
 242     PATHS
 243     ${NANOPB_SRC_ROOT_FOLDER}/generator
 244 )
 245 mark_as_advanced(NANOPB_GENERATOR_EXECUTABLE)
 246
 247 find_package(PythonInterp REQUIRED)
 248
 249 include(FindPackageHandleStandardArgs)
 250 FIND_PACKAGE_HANDLE_STANDARD_ARGS(NANOPB DEFAULT_MSG
 251   NANOPB_INCLUDE_DIRS
 252   NANOPB_SRCS NANOPB_HDRS
 253   NANOPB_GENERATOR_EXECUTABLE
 254   PROTOBUF_PROTOC_EXECUTABLE
 255   )