docs/dev_guide/3_advanced_usage.md

   1 # Build a widget
   2
   3 ## config.xml.in file
   4
   5 To build a widget you need a _config.xml_ file describing what is your apps and
   6 how Application Framework would launch it. This repo provide a simple default
   7 file _config.xml.in_ that should work for simple application without
   8 interactions with others bindings.
   9
  10 It is recommanded that you use the sample one which is more complete. You can
  11 find it at the same location under the name _config.xml.in.sample_ (stunning
  12 isn't it). Just copy the sample file to your _conf.d/wgt_ directory and name it
  13 _config.xml.in_, then edit it to fit your needs.
  14
  15 > ***CAUTION*** : The default file is only meant to be use for a
  16 > simple widget app, more complicated ones which needed to export
  17 > their api, or ship several app in one widget need to use the provided
  18 > _config.xml.in.sample_ which had all new Application Framework
  19 > features explained and examples.
  20
  21 ## Using cmake template macros
  22
  23 To leverage all cmake templates features, you have to specify ***properties***
  24 on your targets. Some macros will not works without specifying which is the
  25 target type.
  26
  27 As the type is not always specified for some custom targets, like an ***HTML5***
  28 application, macros make the difference using ***LABELS*** property.
  29
  30 Choose between:
  31
  32 - **BINDING**: Shared library that be loaded by the AGL Application Framework
  33 - **BINDINGV2**: Shared library that be loaded by the AGL Application Framework
  34  This has to be accompagnied with a JSON file named like the
  35  *${OUTPUT_NAME}-apidef* of the target that describe the API with OpenAPI
  36  syntax (e.g: *mybinding-apidef*).
  37  Or Alternatively, you can choose the name, without the extension, using macro
  38  **set_openapi_filename**. If you use C++, you have to set
  39  **PROJECT_LANGUAGES** with *CXX*.
  40 - **PLUGIN**: Shared library meant to be used as a binding plugin. Binding
  41  would load it as a plugin to extend its functionnalities. It should be named
  42  with a special extension that you choose with SUFFIX cmake target property or
  43  it'd be **.ctlso** by default.
  44 - **HTDOCS**: Root directory of a web app. This target has to build its
  45  directory and puts its files in the ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  46 - **DATA**: Resources used by your application. This target has to build its
  47  directory and puts its files in the ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  48 - **EXECUTABLE**: Entry point of your application executed by the AGL
  49  Application Framework
  50 - **LIBRARY**: An external 3rd party library bundled with the binding for its
  51  own purpose because platform doesn't provide it.
  52
  53 > **TIP** you should use the prefix _afb-_ with your **BINDING* targets which
  54 > stand for **Application Framework Binding**.
  55
  56 Example:
  57
  58 ```cmake
  59 SET_TARGET_PROPERTIES(${TARGET_NAME} PROPERTIES
  60                 LABELS "HTDOCS"
  61                 OUTPUT_NAME dist.prod
  62         )
  63 ```
  64
  65 > **NOTE**: You doesn't need to specify an **INSTALL** command for these
  66 > targets. This is already handle by template and will be installed in the
  67 > following path : **${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME}**
  68
  69 > **NOTE**: if you want to set and use `rpath` with your target you should use
  70 > and set the target property `INSTALL_RPATH`.
  71
  72 ## Add external 3rd party library
  73
  74 ### Build, link and ship external library with the project
  75
  76 You could need to include an external library that isn't shipped in the
  77 platform. Then you have to bundle the required library in the `lib` widget
  78 directory.
  79
  80 Templates includes some facilities to help you to do so. Classic way to do so
  81 is to declare as many CMake ExternalProject as library you need.
  82
  83 An ExternalProject is a special CMake module that let you define how to:
  84 download, update, patch, configure, build and install an external project. It
  85 doesn't have to be a CMake project and custom step could be added for special
  86 needs using ExternalProject step. More informations on CMake [ExternalProject
  87 documentation site](https://cmake.org/cmake/help/v3.5/module/ExternalProject.html?highlight=externalproject).
  88
  89 Example to include `mxml` library for [unicens2-binding](https://github.com/iotbzh/unicens2-binding)
  90 project:
  91
  92 ```cmake
  93 set(MXML external-mxml)
  94 set(MXML_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/mxml)
  95 ExternalProject_Add(${MXML}
  96     GIT_REPOSITORY https://github.com/michaelrsweet/mxml.git
  97     GIT_TAG release-2.10
  98     SOURCE_DIR ${MXML_SOURCE_DIR}
  99     CONFIGURE_COMMAND ./configure --build x86_64 --host aarch64
 100     BUILD_COMMAND make libmxml.so.1.5
 101     BUILD_IN_SOURCE 1
 102     INSTALL_COMMAND ""
 103 )
 104
 105 PROJECT_TARGET_ADD(mxml)
 106
 107 add_library(${TARGET_NAME} SHARED IMPORTED GLOBAL)
 108
 109 SET_TARGET_PROPERTIES(${TARGET_NAME} PROPERTIES
 110     LABELS LIBRARY
 111     IMPORTED_LOCATION ${MXML_SOURCE_DIR}/libmxml.so.1
 112     INTERFACE_INCLUDE_DIRECTORIES ${MXML_SOURCE_DIR}
 113 )
 114
 115 add_dependencies(${TARGET_NAME} ${MXML})
 116 ```
 117
 118 Here we define an external project that drive the build of the library then we
 119 define new CMake target of type **IMPORTED**. Meaning that this target hasn't
 120 been built using CMake but is available at the location defined in the target
 121 property *IMPORTED_LOCATION*.
 122
 123 You could want to build the library as *SHARED* or *STATIC* depending on your needs
 124 and goals. Then you only have to modify the external project configure step and change
 125 filename used by **IMPORTED** library target defined after external project.
 126
 127 Then target *LABELS* property is set to **LIBRARY** to ship it in the widget.
 128
 129 Unicens project also need some header from this library, so we use the target
 130 property *INTERFACE_INCLUDE_DIRECTORIES*. Setting that when another target link
 131 to that imported target, it can access to the include directories.
 132
 133 We bound the target to the external project using a CMake dependency at last.
 134
 135 Then this target could be use like any other CMake target and be linked etc.
 136
 137 ### Only link and ship external library with the project
 138
 139 If you already have a binary version of the library that you want to use and you
 140 can't or don't want to build the library then you only have to add an **IMPORTED**
 141 library target.
 142
 143 So, taking the above example, `mxml` library inclusion would be:
 144
 145 ```cmake
 146 PROJECT_TARGET_ADD(mxml)
 147
 148 add_library(${TARGET_NAME} SHARED IMPORTED GLOBAL)
 149
 150 SET_TARGET_PROPERTIES(${TARGET_NAME} PROPERTIES
 151     LABELS LIBRARY
 152     IMPORTED_LOCATION /path/to/library/libmxml.so.1
 153     INTERFACE_INCLUDE_DIRECTORIES /path/to/mxml/include/dir
 154 )
 155 ```
 156
 157 Finally, you can link any other lib or executable target with this imported
 158 library like any other target.
 159
 160 ## Macro reference
 161
 162 ### PROJECT_TARGET_ADD
 163
 164 Typical usage would be to add the target to your project using macro
 165 `PROJECT_TARGET_ADD` with the name of your target as parameter.
 166
 167 Example:
 168
 169 ```cmake
 170 PROJECT_TARGET_ADD(low-can-demo)
 171 ```
 172
 173 > ***NOTE***: This will make available the variable `${TARGET_NAME}`
 174 > set with the specificied name. This variable will change at the next call
 175 > to this macros.
 176
 177 ### project_subdirs_add
 178
 179 This macro will search in all subfolder any `CMakeLists.txt` file. If found then
 180 it will be added to your project. This could be use in an hybrid application by
 181 example where the binding lay in a sub directory.
 182
 183 Usage :
 184
 185 ```cmake
 186 project_subdirs_add()
 187 ```
 188
 189 You also can specify a globbing pattern as argument to filter which folders
 190 will be looked for.
 191
 192 To filter all directories that begin with a number followed by a dash the
 193 anything:
 194
 195 ```cmake
 196 project_subdirs_add("[0-9]-*")
 197 ```
 198
 199 ### set_openapi_filename
 200
 201 Used with a target labelized **BINDINGV2** to define the file name, and
 202 possibly a relative path with the current *CMakeLists.txt*.
 203
 204 If you don't use that macro to specify the name of your definition file
 205 then the default one will be used, *${OUTPUT_NAME}-apidef* with
 206 **OUTPUT_NAME** as the [target property].
 207
 208 > **CAUTION** you must only specify the name **WITHOUT** the extension.
 209
 210 ```cmake
 211 set_openapi_filename('binding/mybinding_definition')
 212 ```
 213
 214 [target property]: https://cmake.org/cmake/help/v3.6/prop_tgt/OUTPUT_NAME.html "OUTPUT_NAME property documentation"
 215
 216 ### add_input_files
 217
 218 Create custom target dedicated for HTML5 and data resource files. This macro
 219 provides syntax and schema verification for differents languages which are
 220 about now: LUA, JSON and XML.
 221
 222 You could change the tools used to check files with the following variables:
 223
 224 - XML_CHECKER: set to use **xmllint** provided with major linux distribution.
 225 - LUA_CHECKER: set to use **luac** provided with major linux distribution.
 226 - JSON_CHECKER: no tools found at the moment.
 227
 228 ```cmake
 229 add_input_file("${MY_FILES_LIST}")
 230 ```
 231
 232 > **NOTE**: an issue at the check step on a file will stop at the build step.