default/cmake/common.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Get colorized message output non Windows OS. You know bash ? :)
  28 if(NOT WIN32)
  29   string(ASCII 27 Esc)
  30   set(ColourReset "${Esc}[m")
  31   set(ColourBold  "${Esc}[1m")
  32   set(Red         "${Esc}[31m")
  33   set(Green       "${Esc}[32m")
  34   set(Yellow      "${Esc}[33m")
  35   set(Blue        "${Esc}[34m")
  36   set(Magenta     "${Esc}[35m")
  37   set(Cyan        "${Esc}[36m")
  38   set(White       "${Esc}[37m")
  39   set(BoldRed     "${Esc}[1;31m")
  40   set(BoldGreen   "${Esc}[1;32m")
  41   set(BoldYellow  "${Esc}[1;33m")
  42   set(BoldBlue    "${Esc}[1;34m")
  43   set(BoldMagenta "${Esc}[1;35m")
  44   set(BoldCyan    "${Esc}[1;36m")
  45   set(BoldWhite   "${Esc}[1;37m")
  46 endif()
  47
  48 # Generic useful macro
  49 # -----------------------
  50 macro(PROJECT_TARGET_ADD TARGET_NAME)
  51         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  52         set(TARGET_NAME ${TARGET_NAME})
  53 endmacro(PROJECT_TARGET_ADD)
  54
  55 # Check GCC minimal version version
  56 if (gcc_minimal_version)
  57         message (STATUS "${Blue}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  58 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  59         message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  60 endif()
  61 endif(gcc_minimal_version)
  62
  63 macro(defstr name value)
  64         add_definitions(-D${name}=${value})
  65 endmacro(defstr)
  66
  67 # Pre-packaging
  68 macro(project_targets_populate)
  69
  70         # Default Widget default directory
  71         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  72         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  73         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  74         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  75         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  76
  77         add_custom_target(populate)
  78         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  79         foreach(TARGET ${PROJECT_TARGETS})
  80                 get_target_property(T ${TARGET} LABELS)
  81                 if(T)
  82                         # Declaration of a custom command that will populate widget tree with the target
  83                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  84
  85                         get_target_property(P ${TARGET} PREFIX)
  86                         get_target_property(BD ${TARGET} BINARY_DIR)
  87                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  88
  89                         if(P MATCHES "NOTFOUND$")
  90                                 if (${T} STREQUAL "BINDING")
  91                                         set(P "lib")
  92                                 else()
  93                                         set(P "")
  94                                 endif()
  95                         endif()
  96
  97                         if(${T} STREQUAL "BINDING")
  98                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
  99                                         DEPENDS ${TARGET}
 100                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 101                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 102                                 )
 103                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
 104                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 105                         elseif(${T} STREQUAL "EXECUTABLE")
 106                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
 107                                         DEPENDS ${TARGET}
 108                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 109                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 110                                 )
 111                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
 112                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 113                         elseif(${T} STREQUAL "HTDOCS")
 114                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}
 115                                         DEPENDS ${TARGET}
 116                                         COMMAND mkdir -p ${PROJECT_PKG_DIR}/${PACKAGE_HTTPDIR}
 117                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 118                                 )
 119                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR})
 120                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 121                         elseif(${T} STREQUAL "DATA")
 122                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}
 123                                         DEPENDS ${TARGET}
 124                                         COMMAND mkdir -p ${PROJECT_PKG_DIR}/${PACKAGE_DATADIR}
 125                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_DATADIR}
 126                                         )
 127                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR})
 128                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 129                         endif(${T} STREQUAL "BINDING")
 130 #               elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 131 #                                       MESSAGE(WARNING "This target, ${TARGET}, will be not be included in the package.")
 132                 endif()
 133         endforeach()
 134 endmacro(project_targets_populate)
 135
 136 macro(wgt_package_build)
 137         if(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 138                 MESSAGE(SEND_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need config.xml.in and ${PROJECT_ICON} files in ${TEMPLATE_WGT_DIR} folder.${ColourReset}")
 139         else()
 140                 # Build widget spec file from template only once (Fulup good idea or should depend on time ????)
 141                 if(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 142                         configure_file(${TEMPLATE_WGT_DIR}/config.xml.in ${PROJECT_PKG_BUILD_DIR}/config.xml)
 143                         file(COPY ${TEMPLATE_WGT_DIR}/${PROJECT_ICON} DESTINATION ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON})
 144                 endif(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 145
 146                 # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 147                 file(GLOB PROJECT_CONF_FILES "${TEMPLATE_WGT_DIR}/etc/*")
 148                 if(${PROJECT_CONF_FILES})
 149                         file(COPY "${TEMPLATE_WGT_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 150                 endif(${PROJECT_CONF_FILES})
 151
 152                 add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 153                         DEPENDS ${PROJECT_TARGETS}
 154                         COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 155                 )
 156
 157                 add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 158                 add_dependencies(widget populate)
 159                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 160
 161                 if(PACKAGE_MESSAGE)
 162                 add_custom_command(TARGET widget
 163                                 POST_BUILD
 164                                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 165                 endif()
 166         endif()
 167 endmacro(wgt_package_build)
 168
 169 macro(rpm_package_build)
 170         if(NOT EXISTS ${PROJECT_RPM_DIR}/config.spec.in)
 171                         MESSAGE(STATUS "Missing mandatory files: you need config.spec.in in ${PROJECT_RPM_DIR} folder.")
 172         else()
 173                 # extract PROJECT_PKG_DEPS and replace ; by , for RPM spec file
 174                 get_property(PROJECT_PKG_DEPS GLOBAL PROPERTY PROJECT_PKG_DEPS)
 175                 foreach (PKFCONF ${PROJECT_PKG_DEPS})
 176                 set(RPM_PKG_DEPS "${RPM_PKG_DEPS}, pkgconfig(${PKFCONF})")
 177                 endforeach()
 178
 179                 # build rpm spec file from template
 180                 configure_file(${TEMPLATE_RPM_DIR}/config.spec.in ${PROJECT_PKG_BUILD_DIR}/config.spec)
 181
 182                 add_custom_command(OUTPUT ${PROJECT_NAME}.spec
 183                         DEPENDS ${PROJECT_TARGETS}
 184                         COMMAND rpmbuild -ba  ${PROJECT_PKG_BUILD_DIR}/config.spec
 185                 )
 186
 187                 add_custom_target(rpm DEPENDS ${PROJECT_NAME}.spec)
 188                 add_dependencies(rpm populate)
 189                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 190
 191                 if(PACKAGE_MESSAGE)
 192                 add_custom_command(TARGET rpm
 193                                 POST_BUILD
 194                                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 195                 endif()
 196         endif()
 197 endmacro(rpm_package_build)
 198
 199 macro(project_package_build)
 200         if(EXISTS ${TEMPLATE_RPM_DIR})
 201                 rpm_package_build()
 202         endif()
 203
 204         if(EXISTS ${TEMPLATE_WGT_DIR})
 205                 wgt_package_build()
 206         endif()
 207
 208         if(EXISTS ${TEMPLATE_DEB_DIR})
 209                 deb_package_build()
 210         endif()
 211 endmacro(project_package_build)
 212
 213 macro(project_subdirs_add)
 214         if(${ARGV0})
 215                 file(GLOB filelist "${ARGV0}")
 216         else()
 217                 file(GLOB filelist "*")
 218         endif(${ARGV0})
 219
 220         foreach(filename ${filelist})
 221                 if(EXISTS "${filename}/CMakeLists.txt")
 222                         add_subdirectory(${filename})
 223                 endif(EXISTS "${filename}/CMakeLists.txt")
 224         endforeach()
 225 endmacro(project_subdirs_add)
 226
 227 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 228 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 229 set(CMP0048 1)
 230
 231 # Include project configuration
 232 # ------------------------------
 233 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 234 set(PROJECT_LIBDIR "${CMAKE_SOURCE_DIR}/libs" CACHE PATH "Subpath to libraries")
 235 set(PROJECT_RESOURCES "${CMAKE_SOURCE_DIR}/data" CACHE PATH "Subpath to data")
 236
 237 INCLUDE(FindPkgConfig)
 238 INCLUDE(CheckIncludeFiles)
 239 INCLUDE(CheckLibraryExists)
 240 INCLUDE(GNUInstallDirs)
 241
 242 # Default compilation options
 243 ############################################################################
 244 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 245 add_compile_options(-Wall -Wextra -Wconversion)
 246 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 247 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 248 add_compile_options(-Werror=maybe-uninitialized)
 249 add_compile_options(-Werror=implicit-function-declaration)
 250 add_compile_options(-ffunction-sections -fdata-sections)
 251 add_compile_options(-fPIC)
 252 add_compile_options(-g)
 253
 254 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 255 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 256 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 257 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 258
 259 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 260 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 261 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 262 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 263
 264 set(CMAKE_INSTALL_PREFIX      "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 265
 266 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 267 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 268
 269 # Loop on required package and add options
 270 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 271         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 272         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 273
 274         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 275         list (APPEND link_libraries ${${XPREFIX}_LIBRARIES})
 276         add_compile_options (${${XPREFIX}_CFLAGS})
 277 endforeach(PKG_CONFIG)
 278
 279 # Optional LibEfence Malloc debug library
 280 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 281 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 282 IF(HAVE_LIBEFENCE)
 283         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 284         SET(libefence_LIBRARIES "-lefence")
 285         list (APPEND link_libraries ${libefence_LIBRARIES})
 286 ENDIF(HAVE_LIBEFENCE)
 287 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 288
 289 # set default include directories
 290 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 291
 292 # If no install dir try to guess some smart default
 293 if(BINDINGS_INSTALL_PREFIX)
 294         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 295 else()
 296         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 297 endif()
 298
 299 # Define a default package directory
 300 if(PACKAGE_PREFIX)
 301         set(PROJECT_PKG_BUILD_DIR ${PKG_PREFIX}/package CACHE PATH "Where the package will be built.")
 302 else()
 303         set(PROJECT_PKG_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/package CACHE PATH "Where the package will be built")
 304 endif()
 305
 306 set (PKG_TEMPLATE_PREFIX ${CMAKE_SOURCE_DIR}/etc CACHE PATH "Default Package Templates Directory")
 307 set(TEMPLATE_WGT_DIR "${CMAKE_SOURCE_DIR}/conf.d/app-templates/wgt" CACHE PATH "Subpath to a directory where are stored needed files to build widget")
 308 set(TEMPLATE_RPM_DIR "${CMAKE_SOURCE_DIR}/conf.d/app-templates/rpm" CACHE PATH "Subpath to a directory where are stored needed files to build rpm package")
 309 set(TEMPLATE_DEB_DIR "${CMAKE_SOURCE_DIR}/conf.d/app-templates/deb" CACHE PATH "Subpath to a directory where are stored needed files to build deb package")
 310
 311 # Default Linkflag
 312 if(NOT BINDINGS_LINK_FLAG)
 313         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${CMAKE_SOURCE_DIR}/conf.d/app-templates/cmake/export.map")
 314 endif()
 315
 316 # Add a dummy target to enable global dependency order
 317 # -----------------------------------------------------
 318 if(EXTRA_DEPENDENCIES_ORDER)
 319         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 320         add_custom_target(${DEPENDENCIES_TARGET} ALL
 321                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 322         )
 323 endif()
 324
 325 # Print developer helper message when build is done
 326 # -------------------------------------------------------
 327 macro(project_closing_msg)
 328         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 329         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 330         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 331                 add_custom_target(${PROJECT_NAME}_build_done ALL
 332                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 333                 )
 334                  add_dependencies(${PROJECT_NAME}_build_done
 335                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 336         endif()
 337 endmacro()