conf.d/templates/cmake/common.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27
  28 # Generic useful macro
  29 # -----------------------
  30 macro(PROJECT_TARGET_ADD TARGET_NAME)
  31         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  32         set(TARGET_NAME ${TARGET_NAME})
  33 endmacro(PROJECT_TARGET_ADD)
  34
  35 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  36         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  37 endmacro(PROJECT_PKGDEP_ADD)
  38
  39 # Check GCC minimal version version
  40 if (gcc_minimal_version)
  41    message ("-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})")
  42 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  43     message(FATAL_ERROR "**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  44 endif()
  45 endif(gcc_minimal_version)
  46
  47 macro(defstr name value)
  48         add_definitions(-D${name}=${value})
  49 endmacro(defstr)
  50
  51
  52
  53 # Pre-packaging
  54 macro(project_targets_populate)
  55
  56         # Default Widget default directory
  57         set(PACKAGE_BINDIR  ${PROJECT_PKG_DIR}/bin)
  58         set(PACKAGE_ETCDIR  ${PROJECT_PKG_DIR}/etc)
  59         set(PACKAGE_LIBDIR  ${PROJECT_PKG_DIR}/lib)
  60         set(PACKAGE_HTTPDIR ${PROJECT_PKG_DIR}/htdocs)
  61         set(PACKAGE_DATADIR ${PROJECT_PKG_DIR}/data)
  62
  63         add_custom_target(populate)
  64         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  65         foreach(TARGET ${PROJECT_TARGETS})
  66                 get_target_property(T ${TARGET} LABELS)
  67                 if(T)
  68                         # Declaration of a custom command that will populate widget tree with the target
  69                         set(POPULATE_PACKAGE_TARGET "populate_${TARGET}")
  70
  71                         get_target_property(P ${TARGET} PREFIX)
  72                         get_target_property(BD ${TARGET} BINARY_DIR)
  73                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  74
  75                         if(P MATCHES "NOTFOUND$")
  76                                 if (${T} STREQUAL "BINDING")
  77                                         set(P "lib")
  78                                 else()
  79                                         set(P "")
  80                                 endif()
  81                         endif()
  82
  83                         if(${T} STREQUAL "BINDING")
  84                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
  85                                         DEPENDS ${TARGET}
  86                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
  87                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
  88                                 )
  89                                 add_custom_target(${POPULATE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
  90                                 add_dependencies(populate ${POPULATE_PACKAGE_TARGET})
  91                         elseif(${T} STREQUAL "EXECUTABLE")
  92                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
  93                                         DEPENDS ${TARGET}
  94                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
  95                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
  96                                 )
  97                                 add_custom_target(${POPULATE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
  98                                 add_dependencies(populate ${POPULATE_PACKAGE_TARGET})
  99                         elseif(${T} STREQUAL "HTDOCS")
 100                                 add_custom_target(${POPULATE_PACKAGE_TARGET}
 101                                     DEPENDS ${PACKAGE_HTTPDIR}/${TARGET}-xx
 102                                 )
 103                                 add_custom_command(
 104                                     OUTPUT ${PACKAGE_HTTPDIR}/${TARGET}-xx
 105                                     DEPENDS ${TARGET}
 106                                     COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 107                                     COMMAND touch ${PACKAGE_HTTPDIR}
 108                                     COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}/.
 109                                 )
 110                                 add_dependencies(populate ${POPULATE_PACKAGE_TARGET})
 111                         elseif(${T} STREQUAL "DATA")
 112                                 add_custom_target(${POPULATE_PACKAGE_TARGET}
 113                                     DEPENDS ${PACKAGE_DATADIR}/${TARGET}-xx
 114                                     )
 115
 116                                 add_custom_command(
 117                                     OUTPUT ${PACKAGE_DATADIR}/${TARGET}-xx
 118                                     DEPENDS ${TARGET}
 119                                     COMMAND mkdir -p ${PACKAGE_DATADIR}
 120                                     COMMAND touch ${PACKAGE_DATADIR}
 121                                     COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_DATADIR}/.
 122                                     )
 123                                 add_dependencies(populate ${POPULATE_PACKAGE_TARGET})
 124                         endif(${T} STREQUAL "BINDING")
 125                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 126                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 127                 endif()
 128         endforeach()
 129 endmacro(project_targets_populate)
 130
 131 macro(remote_targets_populate)
 132     if (DEFINED ENV{RSYNC_TARGET})
 133        set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 134     endif()
 135     if (DEFINED ENV{RSYNC_PREFIX})
 136        set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 137     endif()
 138
 139     set(
 140        REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 141        CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 142     )
 143
 144     if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 145         message (".. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated")
 146         add_custom_target(remote-target-populate
 147             COMMENT "*** Fatal: RSYNC_TARGET RSYNC_PREFIX required with 'make remote-target-populate'"
 148             COMMAND exit -1
 149         )
 150     else()
 151
 152         configure_file(${SSH_TEMPLATE_DIR}/start-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh)
 153         configure_file(${GDB_TEMPLATE_DIR}/gdb-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/gdb-on-${RSYNC_TARGET}.ini)
 154
 155         add_custom_target(remote-target-populate
 156             DEPENDS populate
 157             COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh
 158             COMMAND rsync --archive --delete ${PROJECT_PKG_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 159             COMMENT "${REMOTE_LAUNCH}"
 160         )
 161     endif()
 162 endmacro(remote_targets_populate)
 163
 164
 165 macro(wgt_package_build)
 166         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/config.xml.in OR NOT EXISTS ${WGT_TEMPLATE_DIR}/${PROJECT_ICON}.in)
 167                 MESSAGE(FATAL_ERROR "Missing mandatory files: you need config.xml.in and ${PROJECT_ICON}.in files in ${WGT_TEMPLATE_DIR} folder.")
 168         endif()
 169
 170         # Build widget spec file from template only once (Fulup good idea or should depend on time ????)
 171         if(NOT EXISTS ${PROJECT_PKG_DIR}/config.xml.in OR NOT EXISTS ${PROJECT_PKG_DIR}/${PROJECT_ICON}.in)
 172                 configure_file(${WGT_TEMPLATE_DIR}/config.xml.in ${PROJECT_PKG_DIR}/config.xml)
 173                 file(COPY ${WGT_TEMPLATE_DIR}/${PROJECT_ICON}.in DESTINATION ${PROJECT_PKG_DIR}/${PROJECT_ICON})
 174         endif(NOT EXISTS ${PROJECT_PKG_DIR}/config.xml.in OR NOT EXISTS ${PROJECT_PKG_DIR}/${PROJECT_ICON}.in)
 175
 176         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 177         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 178         if(${PROJECT_CONF_FILES})
 179                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_DIR}/etc/)
 180         endif(${PROJECT_CONF_FILES})
 181
 182         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 183                 DEPENDS ${PROJECT_TARGETS}
 184                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_DIR}
 185         )
 186
 187         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 188         add_dependencies(widget populate)
 189         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 190
 191         if(PACKAGE_MESSAGE)
 192         add_custom_command(TARGET widget
 193                 POST_BUILD
 194                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 195         endif()
 196 endmacro(wgt_package_build)
 197
 198 macro(rpm_package_build)
 199         if(NOT EXISTS ${RPM_TEMPLATE_DIR}/rpm-config.spec.in)
 200                 MESSAGE(FATAL_ERROR "Missing mandatory files: you needconfig.rpm.in in ${RPM_TEMPLATE_DIR} folder.")
 201         endif()
 202
 203         # extract PROJECT_PKG_DEPS and replace ; by , for RPM spec file
 204         get_property(PROJECT_PKG_DEPS GLOBAL PROPERTY PROJECT_PKG_DEPS)
 205         foreach (PKFCONF ${PROJECT_PKG_DEPS})
 206           set(RPM_PKG_DEPS "${RPM_PKG_DEPS}, pkgconfig(${PKFCONF})")
 207         endforeach()
 208
 209         # build rpm spec file from template
 210         configure_file(${RPM_TEMPLATE_DIR}/rpm-config.spec.in ${SPEC_DIR}/${PROJECT_NAME}.spec)
 211
 212         add_custom_command(OUTPUT ${PROJECT_NAME}.rpm
 213                 DEPENDS ${PROJECT_TARGETS}
 214                 COMMAND git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git  archive --format=tar.gz --prefix=${PROJECT_NAME}-${PROJECT_VERSION}/ HEAD -o ${SPEC_DIR}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz
 215                 COMMAND rpmbuild --define=\"%_sourcedir ${SPEC_DIR}\" -ba ${SPEC_DIR}/${PROJECT_NAME}.spec
 216         )
 217
 218         add_custom_target(rpm DEPENDS ${PROJECT_NAME}.rpm)
 219         add_dependencies(rpm populate)
 220         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.rpm")
 221
 222         if(PACKAGE_MESSAGE)
 223         add_custom_command(TARGET rpm
 224                 POST_BUILD
 225                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 226         endif()
 227 endmacro(rpm_package_build)
 228
 229 macro(project_package_build)
 230
 231     if(EXISTS ${RPM_TEMPLATE_DIR})
 232         rpm_package_build()
 233     endif()
 234
 235     if(EXISTS ${WGT_TEMPLATE_DIR})
 236         wgt_package_build()
 237     endif()
 238
 239     if(EXISTS ${DEB_TEMPLATE_DIR})
 240         deb_package_build()
 241     endif()
 242
 243 endmacro(project_package_build)
 244
 245
 246 macro(project_subdirs_add)
 247     set (ARGSLIST ${ARGN}) # ${ARGN} is special and should be copied
 248     list(LENGTH ARGSLIST ARGSNUM)
 249     if(${ARGSNUM} GREATER 0)
 250         file(GLOB filelist "${ARGV0}")
 251     else()
 252         file(GLOB filelist "*")
 253     endif()
 254
 255     foreach(filename ${filelist})
 256         if(EXISTS "${filename}/CMakeLists.txt")
 257                 add_subdirectory(${filename})
 258         endif(EXISTS "${filename}/CMakeLists.txt")
 259     endforeach()
 260 endmacro(project_subdirs_add)
 261
 262 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 263 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 264 set(CMP0048 1)
 265
 266 # Include project configuration
 267 # ------------------------------
 268 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 269 set(PROJECT_PKG_DIR    "pkgout" CACHE PATH "Subpath to packages")
 270 set(PROJECT_LIB_DIR    "libs" CACHE PATH "Subpath to libraries")
 271 set(PROJECT_RESOURCES  "data"  CACHE PATH "Subpath to data")
 272
 273 set(AFB_TOKEN   ""      CACHE PATH "Default AFB_TOKEN")
 274 set(AFB_REMPORT "1234"  CACHE PATH "Default AFB_TOKEN")
 275
 276 INCLUDE(FindPkgConfig)
 277 INCLUDE(CheckIncludeFiles)
 278 INCLUDE(CheckLibraryExists)
 279 INCLUDE(GNUInstallDirs)
 280
 281 # Default compilation options
 282 ############################################################################
 283 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 284 add_compile_options(-Wall -Wextra -Wconversion)
 285 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 286 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 287 add_compile_options(-Werror=maybe-uninitialized)
 288 add_compile_options(-Werror=implicit-function-declaration)
 289 add_compile_options(-ffunction-sections -fdata-sections)
 290 add_compile_options(-fPIC)
 291 add_compile_options(-g)
 292
 293 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 294 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 295 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 296 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 297
 298 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 299 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 300 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 301 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 302
 303 # Env variable overload default
 304 if(DEFINED ENV{INSTALL_PREFIX})
 305     set (INSTALL_PREFIX $ENV{INSTALL_PREFIX})
 306 else()
 307     set(INSTALL_PREFIX "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 308 endif()
 309 set(CMAKE_INSTALL_PREFIX ${INSTALL_PREFIX} CACHE STRING "Installation Prefix" FORCE)
 310
 311 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 312 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 313
 314 # Loop on required package and add options
 315 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 316         PKG_CHECK_MODULES(${PKG_CONFIG} REQUIRED ${PKG_CONFIG})
 317
 318         INCLUDE_DIRECTORIES(${${PKG_CONFIG}_INCLUDE_DIRS})
 319         list (APPEND link_libraries ${${PKG_CONFIG}_LIBRARIES})
 320         add_compile_options (${${PKG_CONFIG}_CFLAGS})
 321
 322         PROJECT_PKGDEP_ADD(${PKG_CONFIG})
 323 endforeach(PKG_CONFIG)
 324
 325 # Optional LibEfence Malloc debug library
 326 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 327 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 328 IF(HAVE_LIBEFENCE)
 329         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 330         SET(libefence_LIBRARIES "-lefence")
 331         list (APPEND link_libraries ${libefence_LIBRARIES})
 332 ENDIF(HAVE_LIBEFENCE)
 333 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 334
 335 # set default include directories
 336 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 337
 338 # If no install dir try to guess some smart default
 339 if(BINDINGS_INSTALL_PREFIX)
 340         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME})
 341 else()
 342         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME})
 343 endif()
 344
 345 # Define a default widget directory
 346 set (PKG_TEMPLATE_PREFIX ${CMAKE_SOURCE_DIR}/conf.d/templates CACHE PATH "Default Package Templates Directory")
 347 set(SSH_TEMPLATE_DIR ${PKG_TEMPLATE_PREFIX}/ssh)
 348 set(GDB_TEMPLATE_DIR ${PKG_TEMPLATE_PREFIX}/gdb)
 349 set(WGT_TEMPLATE_DIR ${PKG_TEMPLATE_PREFIX}/wgt)
 350 set(RPM_TEMPLATE_DIR ${PKG_TEMPLATE_PREFIX}/rpm)
 351 set(DEB_TEMPLATE_DIR ${PKG_TEMPLATE_PREFIX}/deb)
 352 set(SPEC_DIR ${CMAKE_SOURCE_DIR}/conf.d/packaging)
 353
 354
 355 # Default Linkflag
 356 if(NOT BINDINGS_LINK_FLAG)
 357         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${PKG_TEMPLATE_PREFIX}/cmake/export.map")
 358 endif()
 359
 360 # Add a dummy target to enable global dependency order
 361 # -----------------------------------------------------
 362 if(EXTRA_DEPENDENCIES_ORDER)
 363         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 364         add_custom_target(${DEPENDENCIES_TARGET} ALL
 365                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 366         )
 367 endif()
 368
 369 # Print developer helper message when build is done
 370 # -------------------------------------------------------
 371 macro(project_closing_msg)
 372         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 373         if(CLOSING_MESSAGE AND PROJECT_TARGETS)
 374                 add_custom_target(${PROJECT_NAME}_build_done ALL
 375                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 376                 )
 377                  add_dependencies(${PROJECT_NAME}_build_done
 378                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 379         endif()
 380 endmacro()
 381
 382 # Add RSYSTARGET
 383 remote_targets_populate()