cmake/macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./etc/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 # Pre-packaging
  41 macro(project_targets_populate)
  42         # Default Widget default directory
  43         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  44         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  45         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  46         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  47         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  48
  49         add_custom_target(populate)
  50                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  51         foreach(TARGET ${PROJECT_TARGETS})
  52                 get_target_property(T ${TARGET} LABELS)
  53                 if(T)
  54                         # Declaration of a custom command that will populate widget tree with the target
  55                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  56
  57                         get_target_property(P ${TARGET} PREFIX)
  58                         get_target_property(BD ${TARGET} BINARY_DIR)
  59                         get_target_property(SD ${TARGET} SOURCE_DIR)
  60                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  61
  62                         if(P MATCHES "NOTFOUND$")
  63                                 if (${T} STREQUAL "BINDING")
  64                                         set(P "lib")
  65                                 else()
  66                                         set(P "")
  67                                 endif()
  68                         endif()
  69
  70                         if(${T} STREQUAL "BINDING")
  71                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
  72                                         DEPENDS ${TARGET}
  73                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
  74                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
  75                                 )
  76                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
  77                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
  78                         elseif(${T} STREQUAL "EXECUTABLE")
  79                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
  80                                         DEPENDS ${TARGET}
  81                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
  82                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
  83                                 )
  84                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
  85                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
  86                         elseif(${T} STREQUAL "HTDOCS")
  87                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
  88                                         DEPENDS ${TARGET}
  89                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
  90                                         COMMAND touch ${PACKAGE_HTTPDIR}
  91                                         COMMAND cp -r ${SD}/* ${PACKAGE_HTTPDIR}
  92                                         COMMAND rm -f ${PACKAGE_HTTPDIR}/CMakeLists.txt
  93                                 )
  94                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
  95                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
  96                         elseif(${T} STREQUAL "DATA")
  97                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
  98                                         DEPENDS ${TARGET}
  99                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 100                                         COMMAND touch ${PACKAGE_DATADIR}
 101                                         COMMAND cp -r ${SD}/* ${PACKAGE_DATADIR}
 102                                         COMMAND rm -f ${PACKAGE_DATADIR}/CMakeLists.txt
 103                                 )
 104                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 105                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 106                         endif(${T} STREQUAL "BINDING")
 107                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 108                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 109                 endif()
 110         endforeach()
 111 endmacro(project_targets_populate)
 112
 113 macro(remote_targets_populate)
 114         if (DEFINED ENV{RSYNC_TARGET})
 115         set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 116         endif()
 117         if (DEFINED ENV{RSYNC_PREFIX})
 118         set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 119         endif()
 120
 121         set(
 122                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 123                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 124         )
 125
 126         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 127                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 128                 add_custom_target(remote-target-populate
 129                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 130                         COMMAND exit -1
 131                 )
 132         else()
 133
 134                 configure_file(${SSH_TEMPLATE_DIR}/start-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh)
 135                 configure_file(${GDB_TEMPLATE_DIR}/gdb-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/gdb-on-${RSYNC_TARGET}.ini)
 136
 137                 add_custom_target(remote-target-populate
 138                         DEPENDS populate
 139                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 140                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 141                         COMMENT "${REMOTE_LAUNCH}"
 142                 )
 143         endif()
 144 endmacro(remote_targets_populate)
 145
 146 macro(wgt_package_build)
 147         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 148                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 149         endif()
 150         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 151                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 152         endif()
 153     if(NOT WIDGET_TYPE)
 154         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 155     endif()
 156
 157         if(NOT WIDGET_ENTRY_POINT)
 158                 set(WIDGET_ENTRY_POINT lib)
 159         endif()
 160
 161         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 162                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 163                 COMMAND cp ${WGT_TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 164
 165         )
 166         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 167
 168         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 169         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 170         if(${PROJECT_CONF_FILES})
 171                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 172         endif(${PROJECT_CONF_FILES})
 173
 174         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 175                 DEPENDS ${PROJECT_TARGETS}
 176                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 177         )
 178
 179         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 180         add_dependencies(widget populate packaging_wgt)
 181         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 182
 183         if(NOT RSYNC_TARGET)
 184                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 185                 add_custom_target(widget-target-install
 186                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 187                         COMMAND exit -1
 188                 )
 189         else()
 190         configure_file(${WGT_TEMPLATE_DIR}/install-wgt-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh)
 191         add_custom_target(widget-target-install
 192             DEPENDS widget
 193             COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 194             COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 195         )
 196     endif()
 197
 198         if(PACKAGE_MESSAGE)
 199         add_custom_command(TARGET widget
 200                 POST_BUILD
 201                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 202         endif()
 203 endmacro(wgt_package_build)
 204
 205 macro(rpm_package_build)
 206         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 207                 DEPENDS ${PROJECT_TARGETS}
 208                                 archive
 209                                 packaging
 210                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 211         )
 212
 213         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 214         add_dependencies(rpm populate packaging)
 215         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 216
 217         if(PACKAGE_MESSAGE)
 218         add_custom_command(TARGET rpm
 219                 POST_BUILD
 220                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 221         endif()
 222 endmacro(rpm_package_build)
 223
 224 macro(deb_package_build)
 225 #TODO
 226 endmacro(deb_package_build)
 227
 228 macro(project_package_build)
 229         if(EXISTS ${RPM_TEMPLATE_DIR})
 230                 rpm_package_build()
 231         endif()
 232
 233         if(EXISTS ${WGT_TEMPLATE_DIR})
 234                 wgt_package_build()
 235         endif()
 236
 237         if(EXISTS ${DEB_TEMPLATE_DIR})
 238                 deb_package_build()
 239         endif()
 240 endmacro(project_package_build)
 241
 242 macro(project_subdirs_add)
 243         set (ARGSLIST ${ARGN})
 244         list(LENGTH ARGSLIST ARGSNUM)
 245         if(${ARGSNUM} GREATER 0)
 246                 file(GLOB filelist "${ARGV0}")
 247         else()
 248         file(GLOB filelist "*")
 249         endif()
 250
 251         foreach(filename ${filelist})
 252                 if(EXISTS "${filename}/CMakeLists.txt")
 253                         add_subdirectory(${filename})
 254                 endif(EXISTS "${filename}/CMakeLists.txt")
 255         endforeach()
 256 endmacro(project_subdirs_add)
 257
 258 # Print developer helper message when build is done
 259 # -------------------------------------------------------
 260 macro(project_closing_msg)
 261         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 262         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 263         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 264                 add_custom_target(${PROJECT_NAME}_build_done ALL
 265                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 266                 )
 267                  add_dependencies(${PROJECT_NAME}_build_done
 268                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 269         endif()
 270 endmacro()