cmake/common.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Get colorized message output non Windows OS. You know bash ? :)
  28 if(NOT WIN32)
  29   string(ASCII 27 Esc)
  30   set(ColourReset "${Esc}[m")
  31   set(ColourBold  "${Esc}[1m")
  32   set(Red         "${Esc}[31m")
  33   set(Green       "${Esc}[32m")
  34   set(Yellow      "${Esc}[33m")
  35   set(Blue        "${Esc}[34m")
  36   set(Magenta     "${Esc}[35m")
  37   set(Cyan        "${Esc}[36m")
  38   set(White       "${Esc}[37m")
  39   set(BoldRed     "${Esc}[1;31m")
  40   set(BoldGreen   "${Esc}[1;32m")
  41   set(BoldYellow  "${Esc}[1;33m")
  42   set(BoldBlue    "${Esc}[1;34m")
  43   set(BoldMagenta "${Esc}[1;35m")
  44   set(BoldCyan    "${Esc}[1;36m")
  45   set(BoldWhite   "${Esc}[1;37m")
  46 endif()
  47
  48 # Generic useful macro
  49 # -----------------------
  50 macro(PROJECT_TARGET_ADD TARGET_NAME)
  51         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  52         set(TARGET_NAME ${TARGET_NAME})
  53 endmacro(PROJECT_TARGET_ADD)
  54
  55 # Check GCC minimal version version
  56 if (gcc_minimal_version)
  57         message (STATUS "${Blue}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  58 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  59         message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  60 endif()
  61 endif(gcc_minimal_version)
  62
  63 macro(defstr name value)
  64         add_definitions(-D${name}=${value})
  65 endmacro(defstr)
  66
  67 # Pre-packaging
  68 macro(project_targets_populate)
  69
  70         # Default Widget default directory
  71         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  72         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  73         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  74         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  75         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  76
  77         add_custom_target(populate)
  78         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  79         foreach(TARGET ${PROJECT_TARGETS})
  80                 get_target_property(T ${TARGET} LABELS)
  81                 if(T)
  82                         # Declaration of a custom command that will populate widget tree with the target
  83                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  84
  85                         get_target_property(P ${TARGET} PREFIX)
  86                         get_target_property(BD ${TARGET} BINARY_DIR)
  87                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  88
  89                         if(P MATCHES "NOTFOUND$")
  90                                 if (${T} STREQUAL "BINDING")
  91                                         set(P "lib")
  92                                 else()
  93                                         set(P "")
  94                                 endif()
  95                         endif()
  96
  97                         if(${T} STREQUAL "BINDING")
  98                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
  99                                         DEPENDS ${TARGET}
 100                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 101                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 102                                 )
 103                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
 104                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 105                         elseif(${T} STREQUAL "EXECUTABLE")
 106                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
 107                                         DEPENDS ${TARGET}
 108                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 109                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 110                                 )
 111                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
 112                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 113                         elseif(${T} STREQUAL "HTDOCS")
 114                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}
 115                                         DEPENDS ${TARGET}
 116                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 117                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 118                                 )
 119                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR})
 120                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 121                         elseif(${T} STREQUAL "DATA")
 122                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}
 123                                         DEPENDS ${TARGET}
 124                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 125                                         COMMAND cp -r ${BD}/${P}${OUT} ${PACKAGE_DATADIR}
 126                                 )
 127                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR})
 128                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 129                         endif(${T} STREQUAL "BINDING")
 130                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 131                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 132                 endif()
 133         endforeach()
 134 endmacro(project_targets_populate)
 135
 136 macro(remote_targets_populate)
 137         if (DEFINED ENV{RSYNC_TARGET})
 138         set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 139         endif()
 140         if (DEFINED ENV{RSYNC_PREFIX})
 141         set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 142         endif()
 143
 144         set(
 145                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 146                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 147         )
 148
 149         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 150                 message (".. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated")
 151                 add_custom_target(remote-target-populate
 152                         COMMENT "*** Fatal: RSYNC_TARGET RSYNC_PREFIX required with 'make remote-target-populate'"
 153                         COMMAND exit -1
 154                 )
 155         else()
 156
 157                 configure_file(${SSH_TEMPLATE_DIR}/start-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh)
 158                 configure_file(${GDB_TEMPLATE_DIR}/gdb-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/gdb-on-${RSYNC_TARGET}.ini)
 159
 160                 add_custom_target(remote-target-populate
 161                         DEPENDS populate
 162                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh
 163                         COMMAND rsync --archive --delete ${PROJECT_PKG_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 164                         COMMENT "${REMOTE_LAUNCH}"
 165                 )
 166         endif()
 167 endmacro(remote_targets_populate)
 168
 169 macro(wgt_package_build)
 170         if(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/icon-default.png)
 171                 MESSAGE(SEND_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need config.xml.in and ${PROJECT_ICON} files in ${TEMPLATE_WGT_DIR} folder.${ColourReset}")
 172         else()
 173                 # Build widget spec file from template only once (Fulup good idea or should depend on time ????)
 174                 if(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 175                         configure_file(${TEMPLATE_WGT_DIR}/config.xml.in ${PROJECT_PKG_BUILD_DIR}/config.xml)
 176                         configure_file(${TEMPLATE_WGT_DIR}/config.xml.in ${PROJECT_PKG_ENTRY_POINT}/config.xml)
 177                         file(COPY ${TEMPLATE_WGT_DIR}/icon-default.png DESTINATION ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON})
 178                 endif(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 179
 180                 # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 181                 file(GLOB PROJECT_CONF_FILES "${TEMPLATE_WGT_DIR}/etc/*")
 182                 if(${PROJECT_CONF_FILES})
 183                         file(COPY "${TEMPLATE_WGT_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 184                 endif(${PROJECT_CONF_FILES})
 185
 186                 add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 187                         DEPENDS ${PROJECT_TARGETS}
 188                         COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 189                 )
 190
 191                 add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 192                 add_dependencies(widget populate)
 193                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 194
 195                 if(PACKAGE_MESSAGE)
 196                 add_custom_command(TARGET widget
 197                         POST_BUILD
 198                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 199                 endif()
 200         endif()
 201 endmacro(wgt_package_build)
 202
 203 macro(rpm_package_build)
 204         if(NOT EXISTS ${TEMPLATE_RPM_DIR}/config.spec.in)
 205                         MESSAGE(STATUS "Missing mandatory files: you need config.spec.in in ${TEMPLATE_RPM_DIR} folder.")
 206         else()
 207                 # extract PROJECT_PKG_DEPS and replace ; by , for RPM spec file
 208                 get_property(PROJECT_PKG_DEPS GLOBAL PROPERTY PROJECT_PKG_DEPS)
 209                 foreach (PKFCONF ${PROJECT_PKG_DEPS})
 210                 set(RPM_PKG_DEPS "${RPM_PKG_DEPS}, pkgconfig(${PKFCONF})")
 211                 endforeach()
 212
 213                 # build rpm spec file from template
 214                 configure_file(${TEMPLATE_RPM_DIR}/config.spec.in ${PROJECT_PKG_BUILD_DIR}/config.spec)
 215
 216                 add_custom_command(OUTPUT ${PROJECT_NAME}.spec
 217                         DEPENDS ${PROJECT_TARGETS}
 218                         COMMAND rpmbuild -ba  ${PROJECT_PKG_BUILD_DIR}/config.spec
 219                 )
 220
 221                 add_custom_target(rpm DEPENDS ${PROJECT_NAME}.spec)
 222                 add_dependencies(rpm populate)
 223                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 224
 225                 if(PACKAGE_MESSAGE)
 226                 add_custom_command(TARGET rpm
 227                         POST_BUILD
 228                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 229                 endif()
 230         endif()
 231 endmacro(rpm_package_build)
 232
 233 macro(project_package_build)
 234         if(EXISTS ${TEMPLATE_RPM_DIR})
 235                 rpm_package_build()
 236         endif()
 237
 238         if(EXISTS ${TEMPLATE_WGT_DIR})
 239                 wgt_package_build()
 240         endif()
 241
 242         if(EXISTS ${TEMPLATE_DEB_DIR})
 243                 deb_package_build()
 244         endif()
 245 endmacro(project_package_build)
 246
 247 macro(project_subdirs_add)
 248         if(${ARGV0})
 249                 file(GLOB filelist "${ARGV0}")
 250         else()
 251                 file(GLOB filelist "*")
 252         endif(${ARGV0})
 253
 254         foreach(filename ${filelist})
 255                 if(EXISTS "${filename}/CMakeLists.txt")
 256                         add_subdirectory(${filename})
 257                 endif(EXISTS "${filename}/CMakeLists.txt")
 258         endforeach()
 259 endmacro(project_subdirs_add)
 260
 261 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 262 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 263 set(CMP0048 1)
 264
 265 # Include project configuration
 266 # ------------------------------
 267 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 268 set(PROJECT_LIBDIR "${CMAKE_SOURCE_DIR}/libs" CACHE PATH "Subpath to libraries")
 269 set(PROJECT_RESOURCES "${CMAKE_SOURCE_DIR}/data" CACHE PATH "Subpath to data")
 270
 271 INCLUDE(FindPkgConfig)
 272 INCLUDE(CheckIncludeFiles)
 273 INCLUDE(CheckLibraryExists)
 274 INCLUDE(GNUInstallDirs)
 275
 276 # Default compilation options
 277 ############################################################################
 278 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 279 add_compile_options(-Wall -Wextra -Wconversion)
 280 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 281 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 282 add_compile_options(-Werror=maybe-uninitialized)
 283 add_compile_options(-Werror=implicit-function-declaration)
 284 add_compile_options(-ffunction-sections -fdata-sections)
 285 add_compile_options(-fPIC)
 286 add_compile_options(-g)
 287
 288 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 289 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 290 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 291 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 292
 293 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 294 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 295 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 296 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 297
 298 set(CMAKE_INSTALL_PREFIX      "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 299
 300 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 301 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 302
 303 # Loop on required package and add options
 304 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 305         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 306         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 307
 308         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 309         list (APPEND link_libraries ${${XPREFIX}_LIBRARIES})
 310         add_compile_options (${${XPREFIX}_CFLAGS})
 311 endforeach(PKG_CONFIG)
 312
 313 # Optional LibEfence Malloc debug library
 314 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 315 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 316 IF(HAVE_LIBEFENCE)
 317         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 318         SET(libefence_LIBRARIES "-lefence")
 319         list (APPEND link_libraries ${libefence_LIBRARIES})
 320 ENDIF(HAVE_LIBEFENCE)
 321 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 322
 323 # set default include directories
 324 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 325
 326 # If no install dir try to guess some smart default
 327 if(BINDINGS_INSTALL_PREFIX)
 328         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 329 else()
 330         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 331 endif()
 332
 333 # Define a default package directory
 334 if(PACKAGE_PREFIX)
 335         set(PROJECT_PKG_BUILD_DIR ${PKG_PREFIX}/package CACHE PATH "Where the package will be built.")
 336 else()
 337         set(PROJECT_PKG_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/package CACHE PATH "Where the package will be built")
 338 endif()
 339 set(PROJECT_PKG_ENTRY_POINT ${CMAKE_SOURCE_DIR}/packaging CACHE PATH "Where package build files, like rpm.spec file or config.xml, are write.")
 340
 341 set (PKG_TEMPLATE_PREFIX ${CMAKE_SOURCE_DIR}/etc CACHE PATH "Default Package Templates Directory")
 342 set(TEMPLATE_WGT_DIR "${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/default/wgt" CACHE PATH "Subpath to a directory where are stored needed files to build widget")
 343 set(TEMPLATE_RPM_DIR "${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/default/rpm" CACHE PATH "Subpath to a directory where are stored needed files to build rpm package")
 344 set(TEMPLATE_DEB_DIR "${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/default/deb" CACHE PATH "Subpath to a directory where are stored needed files to build deb package")
 345
 346 # Default Linkflag
 347 if(NOT BINDINGS_LINK_FLAG)
 348         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/default/cmake/export.map")
 349 endif()
 350
 351 # Add a dummy target to enable global dependency order
 352 # -----------------------------------------------------
 353 if(EXTRA_DEPENDENCIES_ORDER)
 354         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 355         add_custom_target(${DEPENDENCIES_TARGET} ALL
 356                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 357         )
 358 endif()
 359
 360 # Print developer helper message when build is done
 361 # -------------------------------------------------------
 362 macro(project_closing_msg)
 363         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 364         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 365         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 366                 add_custom_target(${PROJECT_NAME}_build_done ALL
 367                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 368                 )
 369                  add_dependencies(${PROJECT_NAME}_build_done
 370                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 371         endif()
 372 endmacro()