cmake/common.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Get colorized message output non Windows OS. You know bash ? :)
  28 if(NOT WIN32)
  29   string(ASCII 27 Esc)
  30   set(ColourReset "${Esc}[m")
  31   set(ColourBold  "${Esc}[1m")
  32   set(Red         "${Esc}[31m")
  33   set(Green       "${Esc}[32m")
  34   set(Yellow      "${Esc}[33m")
  35   set(Blue        "${Esc}[34m")
  36   set(Magenta     "${Esc}[35m")
  37   set(Cyan        "${Esc}[36m")
  38   set(White       "${Esc}[37m")
  39   set(BoldRed     "${Esc}[1;31m")
  40   set(BoldGreen   "${Esc}[1;32m")
  41   set(BoldYellow  "${Esc}[1;33m")
  42   set(BoldBlue    "${Esc}[1;34m")
  43   set(BoldMagenta "${Esc}[1;35m")
  44   set(BoldCyan    "${Esc}[1;36m")
  45   set(BoldWhite   "${Esc}[1;37m")
  46 endif()
  47
  48 # Generic useful macro
  49 # -----------------------
  50 macro(PROJECT_TARGET_ADD TARGET_NAME)
  51         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  52         set(TARGET_NAME ${TARGET_NAME})
  53 endmacro(PROJECT_TARGET_ADD)
  54
  55 # Check GCC minimal version
  56 if (gcc_minimal_version)
  57         message (STATUS "${Blue}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  58 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  59         message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  60 endif()
  61 endif(gcc_minimal_version)
  62
  63 # Check Kernel minimal version
  64 if (kernel_minimal_version)
  65         message (STATUS "${Blue}-- Check kernel_minimal_version (found kernel version ${CMAKE_SYSTEM_VERSION})${ColourReset}")
  66         if (CMAKE_SYSTEM_VERSION VERSION_LESS ${kernel_minimal_version})
  67         message(FATAL_ERROR "${Red}**** FATAL: Require at least ${kernel_minimal_version} please use a recent kernel.")
  68 endif()
  69 endif(kernel_minimal_version)
  70
  71 macro(defstr name value)
  72         add_definitions(-D${name}=${value})
  73 endmacro(defstr)
  74
  75 # Pre-packaging
  76 macro(project_targets_populate)
  77
  78         # Default Widget default directory
  79         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  80         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  81         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  82         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  83         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  84
  85         add_custom_target(populate)
  86         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  87         foreach(TARGET ${PROJECT_TARGETS})
  88                 get_target_property(T ${TARGET} LABELS)
  89                 if(T)
  90                         # Declaration of a custom command that will populate widget tree with the target
  91                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  92
  93                         get_target_property(P ${TARGET} PREFIX)
  94                         get_target_property(BD ${TARGET} BINARY_DIR)
  95                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  96
  97                         if(P MATCHES "NOTFOUND$")
  98                                 if (${T} STREQUAL "BINDING")
  99                                         set(P "lib")
 100                                 else()
 101                                         set(P "")
 102                                 endif()
 103                         endif()
 104
 105                         if(${T} STREQUAL "BINDING")
 106                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
 107                                         DEPENDS ${TARGET}
 108                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 109                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 110                                 )
 111                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
 112                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 113                         elseif(${T} STREQUAL "EXECUTABLE")
 114                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
 115                                         DEPENDS ${TARGET}
 116                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 117                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 118                                 )
 119                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
 120                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 121                         elseif(${T} STREQUAL "HTDOCS")
 122                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}
 123                                         DEPENDS ${TARGET}
 124                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 125                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 126                                 )
 127                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR})
 128                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 129                         elseif(${T} STREQUAL "DATA")
 130                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}
 131                                         DEPENDS ${TARGET}
 132                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 133                                         COMMAND cp -r ${BD}/${P}${OUT} ${PACKAGE_DATADIR}
 134                                 )
 135                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR})
 136                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 137                         endif(${T} STREQUAL "BINDING")
 138                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 139                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 140                 endif()
 141         endforeach()
 142 endmacro(project_targets_populate)
 143
 144 macro(remote_targets_populate)
 145         if (DEFINED ENV{RSYNC_TARGET})
 146         set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 147         endif()
 148         if (DEFINED ENV{RSYNC_PREFIX})
 149         set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 150         endif()
 151
 152         set(
 153                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 154                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 155         )
 156
 157         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 158                 message (".. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated")
 159                 add_custom_target(remote-target-populate
 160                         COMMENT "*** Fatal: RSYNC_TARGET RSYNC_PREFIX required with 'make remote-target-populate'"
 161                         COMMAND exit -1
 162                 )
 163         else()
 164
 165                 configure_file(${SSH_TEMPLATE_DIR}/start-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh)
 166                 configure_file(${GDB_TEMPLATE_DIR}/gdb-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/gdb-on-${RSYNC_TARGET}.ini)
 167
 168                 add_custom_target(remote-target-populate
 169                         DEPENDS populate
 170                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh
 171                         COMMAND rsync --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 172                         COMMENT "${REMOTE_LAUNCH}"
 173                 )
 174         endif()
 175 endmacro(remote_targets_populate)
 176
 177 macro(wgt_package_build)
 178         if(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/icon-default.png)
 179                 MESSAGE(SEND_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need config.xml.in and ${PROJECT_ICON} files in ${TEMPLATE_WGT_DIR} folder.${ColourReset}")
 180         else()
 181                 # Build widget spec file from template only once (Fulup good idea or should depend on time ????)
 182                 if(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 183                         configure_file(${TEMPLATE_WGT_DIR}/config.xml.in ${PROJECT_PKG_BUILD_DIR}/config.xml)
 184                         configure_file(${TEMPLATE_WGT_DIR}/config.xml.in ${PROJECT_PKG_ENTRY_POINT}/config.xml)
 185                         file(COPY ${TEMPLATE_WGT_DIR}/icon-default.png DESTINATION ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON})
 186                 endif(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 187
 188                 # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 189                 file(GLOB PROJECT_CONF_FILES "${TEMPLATE_WGT_DIR}/etc/*")
 190                 if(${PROJECT_CONF_FILES})
 191                         file(COPY "${TEMPLATE_WGT_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 192                 endif(${PROJECT_CONF_FILES})
 193
 194                 add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 195                         DEPENDS ${PROJECT_TARGETS}
 196                         COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 197                 )
 198
 199                 add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 200                 add_dependencies(widget populate)
 201                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 202
 203                 if(PACKAGE_MESSAGE)
 204                 add_custom_command(TARGET widget
 205                         POST_BUILD
 206                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 207                 endif()
 208         endif()
 209 endmacro(wgt_package_build)
 210
 211 macro(rpm_package_build)
 212         if(NOT EXISTS ${TEMPLATE_RPM_DIR}/config.spec.in)
 213                         MESSAGE(STATUS "Missing mandatory files: you need config.spec.in in ${TEMPLATE_RPM_DIR} folder.")
 214         else()
 215                 # extract PROJECT_PKG_DEPS and replace ; by , for RPM spec file
 216                 get_property(PROJECT_PKG_DEPS GLOBAL PROPERTY PROJECT_PKG_DEPS)
 217                 foreach (PKFCONF ${PROJECT_PKG_DEPS})
 218                 set(RPM_PKG_DEPS "${RPM_PKG_DEPS}, pkgconfig(${PKFCONF})")
 219                 endforeach()
 220
 221                 # build rpm spec file from template
 222                 configure_file(${TEMPLATE_RPM_DIR}/config.spec.in ${PROJECT_PKG_BUILD_DIR}/config.spec)
 223
 224                 add_custom_command(OUTPUT ${PROJECT_NAME}.spec
 225                         DEPENDS ${PROJECT_TARGETS}
 226                         COMMAND rpmbuild -ba  ${PROJECT_PKG_BUILD_DIR}/config.spec
 227                 )
 228
 229                 add_custom_target(rpm DEPENDS ${PROJECT_NAME}.spec)
 230                 add_dependencies(rpm populate)
 231                 set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 232
 233                 if(PACKAGE_MESSAGE)
 234                 add_custom_command(TARGET rpm
 235                         POST_BUILD
 236                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 237                 endif()
 238         endif()
 239 endmacro(rpm_package_build)
 240
 241 macro(project_package_build)
 242         if(EXISTS ${TEMPLATE_RPM_DIR})
 243                 rpm_package_build()
 244         endif()
 245
 246         if(EXISTS ${TEMPLATE_WGT_DIR})
 247                 wgt_package_build()
 248         endif()
 249
 250         if(EXISTS ${TEMPLATE_DEB_DIR})
 251                 deb_package_build()
 252         endif()
 253 endmacro(project_package_build)
 254
 255 macro(project_subdirs_add)
 256         set (ARGSLIST ${ARGN})
 257         list(LENGTH ARGSLIST ARGSNUM)
 258         if(${ARGSNUM} GREATER 0)
 259                 file(GLOB filelist "${ARGV0}")
 260         else()
 261         file(GLOB filelist "*")
 262         endif()
 263
 264         foreach(filename ${filelist})
 265                 if(EXISTS "${filename}/CMakeLists.txt")
 266                         add_subdirectory(${filename})
 267                 endif(EXISTS "${filename}/CMakeLists.txt")
 268         endforeach()
 269 endmacro(project_subdirs_add)
 270
 271 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 272 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 273 set(CMP0048 1)
 274
 275 # Include project configuration
 276 # ------------------------------
 277 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 278 set(PROJECT_LIBDIR "${CMAKE_SOURCE_DIR}/libs" CACHE PATH "Subpath to libraries")
 279 set(PROJECT_RESOURCES "${CMAKE_SOURCE_DIR}/data" CACHE PATH "Subpath to data")
 280
 281 INCLUDE(FindPkgConfig)
 282 INCLUDE(CheckIncludeFiles)
 283 INCLUDE(CheckLibraryExists)
 284 INCLUDE(GNUInstallDirs)
 285
 286 # Default compilation options
 287 ############################################################################
 288 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 289 add_compile_options(-Wall -Wextra -Wconversion)
 290 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 291 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 292 add_compile_options(-Werror=maybe-uninitialized)
 293 add_compile_options(-Werror=implicit-function-declaration)
 294 add_compile_options(-ffunction-sections -fdata-sections)
 295 add_compile_options(-fPIC)
 296 add_compile_options(-g)
 297
 298 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 299 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 300 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 301 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 302
 303 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 304 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 305 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 306 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 307
 308 set(CMAKE_INSTALL_PREFIX      "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 309
 310 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 311 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 312
 313 # Loop on required package and add options
 314 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 315         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 316         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 317
 318         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 319         list (APPEND link_libraries ${${XPREFIX}_LIBRARIES})
 320         add_compile_options (${${XPREFIX}_CFLAGS})
 321 endforeach(PKG_CONFIG)
 322
 323 # Optional LibEfence Malloc debug library
 324 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 325 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 326 IF(HAVE_LIBEFENCE)
 327         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 328         SET(libefence_LIBRARIES "-lefence")
 329         list (APPEND link_libraries ${libefence_LIBRARIES})
 330 ENDIF(HAVE_LIBEFENCE)
 331 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 332
 333 # set default include directories
 334 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 335
 336 # If no install dir try to guess some smart default
 337 if(BINDINGS_INSTALL_PREFIX)
 338         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 339 else()
 340         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 341 endif()
 342
 343 # Define a default package directory
 344 if(PACKAGE_PREFIX)
 345         set(PROJECT_PKG_BUILD_DIR ${PKG_PREFIX}/package CACHE PATH "Where the package will be built.")
 346 else()
 347         set(PROJECT_PKG_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/package CACHE PATH "Where the package will be built")
 348 endif()
 349 set(PROJECT_PKG_ENTRY_POINT ${CMAKE_SOURCE_DIR}/packaging CACHE PATH "Where package build files, like rpm.spec file or config.xml, are write.")
 350
 351 set (PKG_TEMPLATE_PREFIX ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR} CACHE PATH "Default Package Templates Directory")
 352 set(SSH_TEMPLATE_DIR ${PKG_TEMPLATE_PREFIX}/ssh)
 353 set(GDB_TEMPLATE_DIR ${PKG_TEMPLATE_PREFIX}/gdb)
 354 set(TEMPLATE_WGT_DIR "${PKG_TEMPLATE_PREFIX}/wgt" CACHE PATH "Subpath to a directory where are stored needed files to build widget")
 355 set(TEMPLATE_RPM_DIR "${PKG_TEMPLATE_PREFIX}/rpm" CACHE PATH "Subpath to a directory where are stored needed files to build rpm package")
 356 set(TEMPLATE_DEB_DIR "${PKG_TEMPLATE_PREFIX}/deb" CACHE PATH "Subpath to a directory where are stored needed files to build deb package")
 357
 358 # Default Linkflag
 359 if(NOT BINDINGS_LINK_FLAG)
 360         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/export.map")
 361 endif()
 362
 363 # Add a dummy target to enable global dependency order
 364 # -----------------------------------------------------
 365 if(EXTRA_DEPENDENCIES_ORDER)
 366         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 367         add_custom_target(${DEPENDENCIES_TARGET} ALL
 368                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 369         )
 370 endif()
 371
 372 # Print developer helper message when build is done
 373 # -------------------------------------------------------
 374 macro(project_closing_msg)
 375         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 376         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 377         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 378                 add_custom_target(${PROJECT_NAME}_build_done ALL
 379                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 380                 )
 381                  add_dependencies(${PROJECT_NAME}_build_done
 382                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 383         endif()
 384 endmacro()
 385
 386 # Add RSYSTARGET
 387 remote_targets_populate()