cmake/common.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Get colorized message output non Windows OS. You know bash ? :)
  28 if(NOT WIN32)
  29   string(ASCII 27 Esc)
  30   set(ColourReset "${Esc}[m")
  31   set(ColourBold  "${Esc}[1m")
  32   set(Red         "${Esc}[31m")
  33   set(Green       "${Esc}[32m")
  34   set(Yellow      "${Esc}[33m")
  35   set(Blue        "${Esc}[34m")
  36   set(Magenta     "${Esc}[35m")
  37   set(Cyan        "${Esc}[36m")
  38   set(White       "${Esc}[37m")
  39   set(BoldRed     "${Esc}[1;31m")
  40   set(BoldGreen   "${Esc}[1;32m")
  41   set(BoldYellow  "${Esc}[1;33m")
  42   set(BoldBlue    "${Esc}[1;34m")
  43   set(BoldMagenta "${Esc}[1;35m")
  44   set(BoldCyan    "${Esc}[1;36m")
  45   set(BoldWhite   "${Esc}[1;37m")
  46 endif()
  47
  48 # Generic useful macro
  49 # -----------------------
  50 macro(PROJECT_TARGET_ADD TARGET_NAME)
  51         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  52         set(TARGET_NAME ${TARGET_NAME})
  53 endmacro(PROJECT_TARGET_ADD)
  54
  55 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  56         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  57 endmacro(PROJECT_PKGDEP_ADD)
  58
  59 # Check GCC minimal version
  60 if (gcc_minimal_version)
  61         message (STATUS "${Blue}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  62 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  63         message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  64 endif()
  65 endif(gcc_minimal_version)
  66
  67 # Check Kernel minimal version
  68 if (kernel_minimal_version)
  69         message (STATUS "${Blue}-- Check kernel_minimal_version (found kernel version ${CMAKE_SYSTEM_VERSION})${ColourReset}")
  70         if (CMAKE_SYSTEM_VERSION VERSION_LESS ${kernel_minimal_version})
  71         message(FATAL_ERROR "${Red}**** FATAL: Require at least ${kernel_minimal_version} please use a recent kernel.")
  72 endif()
  73 endif(kernel_minimal_version)
  74
  75 macro(defstr name value)
  76         add_definitions(-D${name}=${value})
  77 endmacro(defstr)
  78
  79 # Pre-packaging
  80 macro(project_targets_populate)
  81
  82         # Default Widget default directory
  83         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  84         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  85         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  86         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  87         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  88
  89         add_custom_target(populate)
  90                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  91         foreach(TARGET ${PROJECT_TARGETS})
  92                 get_target_property(T ${TARGET} LABELS)
  93                 if(T)
  94                         # Declaration of a custom command that will populate widget tree with the target
  95                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  96
  97                         get_target_property(P ${TARGET} PREFIX)
  98                         get_target_property(BD ${TARGET} BINARY_DIR)
  99                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 100
 101                         if(P MATCHES "NOTFOUND$")
 102                                 if (${T} STREQUAL "BINDING")
 103                                         set(P "lib")
 104                                 else()
 105                                         set(P "")
 106                                 endif()
 107                         endif()
 108
 109                         if(${T} STREQUAL "BINDING")
 110                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
 111                                         DEPENDS ${TARGET}
 112                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 113                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 114                                 )
 115                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
 116                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 117                         elseif(${T} STREQUAL "EXECUTABLE")
 118                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
 119                                         DEPENDS ${TARGET}
 120                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 121                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 122                                 )
 123                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
 124                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 125                         elseif(${T} STREQUAL "HTDOCS")
 126                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 127                                         DEPENDS ${TARGET}
 128                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 129                                         COMMAND touch ${PACKAGE_HTTPDIR}
 130                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 131                                 )
 132                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 133                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 134                         elseif(${T} STREQUAL "DATA")
 135                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 136                                         DEPENDS ${TARGET}
 137                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 138                                         COMMAND touch ${PACKAGE_DATADIR}
 139                                         COMMAND cp -r ${BD}/${P}${OUT} ${PACKAGE_DATADIR}
 140                                 )
 141                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 142                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 143                         endif(${T} STREQUAL "BINDING")
 144                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 145                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 146                 endif()
 147         endforeach()
 148 endmacro(project_targets_populate)
 149
 150 macro(remote_targets_populate)
 151         if (DEFINED ENV{RSYNC_TARGET})
 152         set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 153         endif()
 154         if (DEFINED ENV{RSYNC_PREFIX})
 155         set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 156         endif()
 157
 158         set(
 159                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 160                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 161         )
 162
 163         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 164                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 165                 add_custom_target(remote-target-populate
 166                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 167                         COMMAND exit -1
 168                 )
 169         else()
 170
 171                 configure_file(${SSH_TEMPLATE_DIR}/start-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh)
 172                 configure_file(${GDB_TEMPLATE_DIR}/gdb-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/gdb-on-${RSYNC_TARGET}.ini)
 173
 174                 add_custom_target(remote-target-populate
 175                         DEPENDS populate
 176                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh
 177                         COMMAND rsync --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 178                         COMMENT "${REMOTE_LAUNCH}"
 179                 )
 180         endif()
 181 endmacro(remote_targets_populate)
 182
 183 macro(wgt_package_build)
 184         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 185                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 186         endif()
 187         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 188                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 189         endif()
 190     if(NOT WIDGET_TYPE)
 191         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 192     endif()
 193
 194     set(WIDGET_ENTRY_POINT lib CACHE STRING "the widget entry point file")
 195
 196         configure_file(${WIDGET_CONFIG_TEMPLATE} ${PROJECT_PKG_BUILD_DIR}/config.xml)
 197         configure_file(${WIDGET_CONFIG_TEMPLATE} ${PROJECT_PKG_ENTRY_POINT}/config.xml)
 198         file(COPY ${WGT_TEMPLATE_DIR}/icon-default.png DESTINATION ${PROJECT_PKG_BUILD_DIR})
 199         file(RENAME ${PROJECT_PKG_BUILD_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON})
 200
 201         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 202         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 203         if(${PROJECT_CONF_FILES})
 204                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 205         endif(${PROJECT_CONF_FILES})
 206
 207         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 208                 DEPENDS ${PROJECT_TARGETS}
 209                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 210         )
 211
 212         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 213         add_dependencies(widget populate)
 214         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 215
 216         if(PACKAGE_MESSAGE)
 217         add_custom_command(TARGET widget
 218                 POST_BUILD
 219                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 220         endif()
 221 endmacro(wgt_package_build)
 222
 223 macro(rpm_package_build)
 224         if(NOT EXISTS ${RPM_TEMPLATE_DIR}/rpm-config.spec.in)
 225                 MESSAGE(FATAL_ERROR "${Red}Missing mandatory files: you need rpm-config.spec.in in ${RPM_TEMPLATE_DIR} folder.${ColourReset}")
 226         endif()
 227
 228         # extract PROJECT_PKG_DEPS and replace ; by , for RPM spec file
 229         get_property(PROJECT_PKG_DEPS GLOBAL PROPERTY PROJECT_PKG_DEPS)
 230         foreach (PKFCONF ${PROJECT_PKG_DEPS})
 231                 set(RPM_PKG_DEPS "${RPM_PKG_DEPS}, pkgconfig(${PKFCONF})")
 232         endforeach()
 233
 234         # build rpm spec file from template
 235         configure_file(${RPM_TEMPLATE_DIR}/rpm-config.spec.in ${PROJECT_NAME}.spec)
 236         configure_file(${RPM_TEMPLATE_DIR}/rpm-config.spec.in ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}.spec)
 237
 238         add_custom_command(OUTPUT ${PROJECT_NAME}.spec
 239                 DEPENDS ${PROJECT_TARGETS}
 240                 COMMAND git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git  archive --format=tar.gz --prefix=${PROJECT_NAME}-${PROJECT_VERSION}/ HEAD -o ${PROJECT_PKG_BUILD_DIR}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz
 241                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_BUILD_DIR}\" -ba  ${PROJECT_PKG_BUILD_DIR}/${PROJECT_NAME}.spec
 242         )
 243
 244         add_custom_target(rpm DEPENDS ${PROJECT_NAME}.spec)
 245         add_dependencies(rpm populate)
 246         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 247
 248         if(PACKAGE_MESSAGE)
 249         add_custom_command(TARGET rpm
 250                 POST_BUILD
 251                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 252         endif()
 253 endmacro(rpm_package_build)
 254
 255 macro(project_package_build)
 256         if(EXISTS ${RPM_TEMPLATE_DIR})
 257                 rpm_package_build()
 258         endif()
 259
 260         if(EXISTS ${WGT_TEMPLATE_DIR})
 261                 wgt_package_build()
 262         endif()
 263
 264         if(EXISTS ${DEB_TEMPLATE_DIR})
 265                 deb_package_build()
 266         endif()
 267 endmacro(project_package_build)
 268
 269 macro(project_subdirs_add)
 270         set (ARGSLIST ${ARGN})
 271         list(LENGTH ARGSLIST ARGSNUM)
 272         if(${ARGSNUM} GREATER 0)
 273                 file(GLOB filelist "${ARGV0}")
 274         else()
 275         file(GLOB filelist "*")
 276         endif()
 277
 278         foreach(filename ${filelist})
 279                 if(EXISTS "${filename}/CMakeLists.txt")
 280                         add_subdirectory(${filename})
 281                 endif(EXISTS "${filename}/CMakeLists.txt")
 282         endforeach()
 283 endmacro(project_subdirs_add)
 284
 285 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 286 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 287 set(CMP0048 1)
 288
 289 # Include project configuration
 290 # ------------------------------
 291 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 292 set(PROJECT_LIBDIR "${CMAKE_SOURCE_DIR}/libs" CACHE PATH "Subpath to libraries")
 293 set(PROJECT_RESOURCES "${CMAKE_SOURCE_DIR}/data" CACHE PATH "Subpath to data")
 294
 295 set(AFB_TOKEN   ""      CACHE PATH "Default AFB_TOKEN")
 296 set(AFB_REMPORT "1234" CACHE PATH "Default AFB_TOKEN")
 297
 298 INCLUDE(FindPkgConfig)
 299 INCLUDE(CheckIncludeFiles)
 300 INCLUDE(CheckLibraryExists)
 301 INCLUDE(GNUInstallDirs)
 302
 303 # Default compilation options
 304 ############################################################################
 305 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 306 add_compile_options(-Wall -Wextra -Wconversion)
 307 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 308 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 309 add_compile_options(-Werror=maybe-uninitialized)
 310 add_compile_options(-Werror=implicit-function-declaration)
 311 add_compile_options(-ffunction-sections -fdata-sections)
 312 add_compile_options(-fPIC)
 313 add_compile_options(-g)
 314
 315 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 316 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 317 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 318 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 319
 320 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 321 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 322 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 323 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 324
 325 # Env variable overload default
 326 if(DEFINED ENV{INSTALL_PREFIX})
 327         set (INSTALL_PREFIX $ENV{INSTALL_PREFIX})
 328 else()
 329         set(INSTALL_PREFIX "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 330 endif()
 331 set(CMAKE_INSTALL_PREFIX ${INSTALL_PREFIX} CACHE STRING "Installation Prefix")
 332
 333 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 334 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 335
 336 # Loop on required package and add options
 337 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 338         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 339         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 340
 341         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 342         list (APPEND link_libraries ${${XPREFIX}_LIBRARIES})
 343         add_compile_options (${${XPREFIX}_CFLAGS})
 344 endforeach(PKG_CONFIG)
 345
 346 # Optional LibEfence Malloc debug library
 347 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 348 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 349 IF(HAVE_LIBEFENCE)
 350         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 351         SET(libefence_LIBRARIES "-lefence")
 352         list (APPEND link_libraries ${libefence_LIBRARIES})
 353 ENDIF(HAVE_LIBEFENCE)
 354 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 355
 356 # set default include directories
 357 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 358
 359 # If no install dir try to guess some smart default
 360 if(BINDINGS_INSTALL_PREFIX)
 361         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 362 else()
 363         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 364 endif()
 365
 366 # Define a default package directory
 367 if(PACKAGE_PREFIX)
 368         set(PROJECT_PKG_BUILD_DIR ${PKG_PREFIX}/package CACHE PATH "Application contents to be packaged")
 369 else()
 370         set(PROJECT_PKG_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/package CACHE PATH "Application contents to be packaged")
 371 endif()
 372
 373 set (PROJECT_APP_TEMPLATES_DIR "conf.d/templates" CACHE PATH "Default Templates directory")
 374
 375 set (PKG_TEMPLATE_PREFIX ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR} CACHE PATH "Default Package Templates Directory")
 376 set(SSH_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/ssh" CACHE PATH "Subpath to a directory where are stored needed files to launch on remote target to debuging purposes")
 377 set(GDB_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/gdb" CACHE PATH "Subpath to a directory where are stored needed files to launch debuging server on a remote target. Use gdbserver.")
 378 set(WGT_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/wgt" CACHE PATH "Subpath to a directory where are stored needed files to build widget")
 379 if(NOT WIDGET_CONFIG_TEMPLATE)
 380         set(WIDGET_CONFIG_TEMPLATE ${WGT_TEMPLATE_DIR}/config.xml.in CACHE PATH "Path to widget config file template (config.xml.in)")
 381 endif()
 382 set(RPM_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/rpm" CACHE PATH "Subpath to a directory where are stored needed files to build rpm package")
 383 set(DEB_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/deb" CACHE PATH "Subpath to a directory where are stored needed files to build deb package")
 384
 385 string(REGEX REPLACE "^(.*)/.*$" "\\1" ENTRY_POINT "${PKG_TEMPLATE_PREFIX}")
 386 set(PROJECT_PKG_ENTRY_POINT ${ENTRY_POINT}/packaging CACHE PATH "Where package build files, like rpm.spec file or config.xml, are write.")
 387
 388 # Default Linkflag
 389 if(NOT BINDINGS_LINK_FLAG)
 390         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${PKG_TEMPLATE_PREFIX}/cmake/export.map")
 391 endif()
 392
 393 # Add a dummy target to enable global dependency order
 394 # -----------------------------------------------------
 395 if(EXTRA_DEPENDENCIES_ORDER)
 396         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 397         add_custom_target(${DEPENDENCIES_TARGET} ALL
 398                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 399         )
 400 endif()
 401
 402 # Print developer helper message when build is done
 403 # -------------------------------------------------------
 404 macro(project_closing_msg)
 405         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 406         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 407         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 408                 add_custom_target(${PROJECT_NAME}_build_done ALL
 409                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 410                 )
 411                  add_dependencies(${PROJECT_NAME}_build_done
 412                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 413         endif()
 414 endmacro()
 415
 416 # Add RSYNCTARGET
 417 remote_targets_populate()
 418
 419 add_custom_command(OUTPUT ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz
 420 DEPENDS ${PROJECT_TARGETS}
 421  COMMAND git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git archive --format=tar.gz --prefix=${PROJECT_NAME}-${PROJECT_VERSION}/ HEAD -o ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz
 422 )
 423
 424 add_custom_target(archive DEPENDS ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz)