cmake/common.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Get colorized message output non Windows OS. You know bash ? :)
  28 if(NOT WIN32)
  29   string(ASCII 27 Esc)
  30   set(ColourReset "${Esc}[m")
  31   set(ColourBold  "${Esc}[1m")
  32   set(Red         "${Esc}[31m")
  33   set(Green       "${Esc}[32m")
  34   set(Yellow      "${Esc}[33m")
  35   set(Blue        "${Esc}[34m")
  36   set(Magenta     "${Esc}[35m")
  37   set(Cyan        "${Esc}[36m")
  38   set(White       "${Esc}[37m")
  39   set(BoldRed     "${Esc}[1;31m")
  40   set(BoldGreen   "${Esc}[1;32m")
  41   set(BoldYellow  "${Esc}[1;33m")
  42   set(BoldBlue    "${Esc}[1;34m")
  43   set(BoldMagenta "${Esc}[1;35m")
  44   set(BoldCyan    "${Esc}[1;36m")
  45   set(BoldWhite   "${Esc}[1;37m")
  46 endif()
  47
  48 # Generic useful macro
  49 # -----------------------
  50 macro(PROJECT_TARGET_ADD TARGET_NAME)
  51         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  52         set(TARGET_NAME ${TARGET_NAME})
  53 endmacro(PROJECT_TARGET_ADD)
  54
  55 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  56         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  57 endmacro(PROJECT_PKGDEP_ADD)
  58
  59 # Check GCC minimal version
  60 if (gcc_minimal_version)
  61         message (STATUS "${Blue}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  62 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  63         message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  64 endif()
  65 endif(gcc_minimal_version)
  66
  67 # Check Kernel minimal version
  68 if (kernel_minimal_version)
  69         message (STATUS "${Blue}-- Check kernel_minimal_version (found kernel version ${CMAKE_SYSTEM_VERSION})${ColourReset}")
  70         if (CMAKE_SYSTEM_VERSION VERSION_LESS ${kernel_minimal_version})
  71         message(FATAL_ERROR "${Red}**** FATAL: Require at least ${kernel_minimal_version} please use a recent kernel.")
  72 endif()
  73 endif(kernel_minimal_version)
  74
  75 macro(defstr name value)
  76         add_definitions(-D${name}=${value})
  77 endmacro(defstr)
  78
  79 # Pre-packaging
  80 macro(project_targets_populate)
  81
  82         # Default Widget default directory
  83         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  84         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  85         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  86         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  87         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  88
  89         add_custom_target(populate)
  90                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  91         foreach(TARGET ${PROJECT_TARGETS})
  92                 get_target_property(T ${TARGET} LABELS)
  93                 if(T)
  94                         # Declaration of a custom command that will populate widget tree with the target
  95                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  96
  97                         get_target_property(P ${TARGET} PREFIX)
  98                         get_target_property(BD ${TARGET} BINARY_DIR)
  99                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 100
 101                         if(P MATCHES "NOTFOUND$")
 102                                 if (${T} STREQUAL "BINDING")
 103                                         set(P "lib")
 104                                 else()
 105                                         set(P "")
 106                                 endif()
 107                         endif()
 108
 109                         if(${T} STREQUAL "BINDING")
 110                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
 111                                         DEPENDS ${TARGET}
 112                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 113                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 114                                 )
 115                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
 116                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 117                         elseif(${T} STREQUAL "EXECUTABLE")
 118                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
 119                                         DEPENDS ${TARGET}
 120                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 121                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 122                                 )
 123                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
 124                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 125                         elseif(${T} STREQUAL "HTDOCS")
 126                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 127                                         DEPENDS ${TARGET}
 128                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 129                                         COMMAND touch ${PACKAGE_HTTPDIR}
 130                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 131                                 )
 132                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 133                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 134                         elseif(${T} STREQUAL "DATA")
 135                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 136                                         DEPENDS ${TARGET}
 137                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 138                                         COMMAND touch ${PACKAGE_DATADIR}
 139                                         COMMAND cp -r ${BD}/${P}${OUT} ${PACKAGE_DATADIR}
 140                                 )
 141                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 142                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 143                         endif(${T} STREQUAL "BINDING")
 144                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 145                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 146                 endif()
 147         endforeach()
 148 endmacro(project_targets_populate)
 149
 150 macro(remote_targets_populate)
 151         if (DEFINED ENV{RSYNC_TARGET})
 152         set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 153         endif()
 154         if (DEFINED ENV{RSYNC_PREFIX})
 155         set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 156         endif()
 157
 158         set(
 159                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 160                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 161         )
 162
 163         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 164                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 165                 add_custom_target(remote-target-populate
 166                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 167                         COMMAND exit -1
 168                 )
 169         else()
 170
 171                 configure_file(${SSH_TEMPLATE_DIR}/start-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh)
 172                 configure_file(${GDB_TEMPLATE_DIR}/gdb-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/gdb-on-${RSYNC_TARGET}.ini)
 173
 174                 add_custom_target(remote-target-populate
 175                         DEPENDS populate
 176                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 177                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 178                         COMMENT "${REMOTE_LAUNCH}"
 179                 )
 180         endif()
 181 endmacro(remote_targets_populate)
 182
 183 macro(wgt_package_build)
 184         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 185                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 186         endif()
 187         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 188                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 189         endif()
 190     if(NOT WIDGET_TYPE)
 191         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 192     endif()
 193
 194         if(NOT WIDGET_ENTRY_POINT)
 195                 set(WIDGET_ENTRY_POINT lib)
 196         endif()
 197
 198         configure_file(${WIDGET_CONFIG_TEMPLATE} ${PROJECT_PKG_BUILD_DIR}/config.xml)
 199         file(COPY ${WGT_TEMPLATE_DIR}/icon-default.png DESTINATION ${PROJECT_PKG_BUILD_DIR})
 200         file(RENAME ${PROJECT_PKG_BUILD_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON})
 201
 202         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 203         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 204         if(${PROJECT_CONF_FILES})
 205                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 206         endif(${PROJECT_CONF_FILES})
 207
 208         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 209                 DEPENDS ${PROJECT_TARGETS}
 210                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 211         )
 212
 213         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 214         add_dependencies(widget populate)
 215         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 216
 217         if(NOT RSYNC_TARGET)
 218                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 219                 add_custom_target(widget-target-install
 220                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 221                         COMMAND exit -1
 222                 )
 223         else()
 224         configure_file(${WGT_TEMPLATE_DIR}/install-wgt-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh)
 225         add_custom_target(widget-target-install
 226             DEPENDS widget
 227             COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 228             COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 229         )
 230     endif()
 231
 232         if(PACKAGE_MESSAGE)
 233         add_custom_command(TARGET widget
 234                 POST_BUILD
 235                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 236         endif()
 237 endmacro(wgt_package_build)
 238
 239 macro(rpm_package_build)
 240         if(NOT EXISTS ${RPM_TEMPLATE_DIR}/rpm-config.spec.in)
 241                 MESSAGE(FATAL_ERROR "${Red}Missing mandatory files: you need rpm-config.spec.in in ${RPM_TEMPLATE_DIR} folder.${ColourReset}")
 242         endif()
 243
 244         # extract PROJECT_PKG_DEPS and replace ; by , for RPM spec file
 245         get_property(PROJECT_PKG_DEPS GLOBAL PROPERTY PROJECT_PKG_DEPS)
 246         foreach (PKFCONF ${PROJECT_PKG_DEPS})
 247                 set(RPM_PKG_DEPS "${RPM_PKG_DEPS}, pkgconfig(${PKFCONF})")
 248         endforeach()
 249
 250         # build rpm spec file from template
 251         configure_file(${RPM_TEMPLATE_DIR}/rpm-config.spec.in ${PROJECT_NAME}.spec)
 252         configure_file(${RPM_TEMPLATE_DIR}/rpm-config.spec.in ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}.spec)
 253
 254         add_custom_command(OUTPUT ${PROJECT_NAME}.spec
 255                 DEPENDS ${PROJECT_TARGETS}
 256                 COMMAND git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git  archive --format=tar.gz --prefix=${PROJECT_NAME}-${PROJECT_VERSION}/ HEAD -o ${PROJECT_PKG_BUILD_DIR}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz
 257                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_BUILD_DIR}\" -ba  ${PROJECT_PKG_BUILD_DIR}/${PROJECT_NAME}.spec
 258         )
 259
 260         add_custom_target(rpm DEPENDS ${PROJECT_NAME}.spec)
 261         add_dependencies(rpm populate)
 262         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 263
 264         if(PACKAGE_MESSAGE)
 265         add_custom_command(TARGET rpm
 266                 POST_BUILD
 267                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 268         endif()
 269 endmacro(rpm_package_build)
 270
 271 macro(project_package_build)
 272         if(EXISTS ${RPM_TEMPLATE_DIR})
 273                 rpm_package_build()
 274         endif()
 275
 276         if(EXISTS ${WGT_TEMPLATE_DIR})
 277                 wgt_package_build()
 278         endif()
 279
 280         if(EXISTS ${DEB_TEMPLATE_DIR})
 281                 deb_package_build()
 282         endif()
 283 endmacro(project_package_build)
 284
 285 macro(project_subdirs_add)
 286         set (ARGSLIST ${ARGN})
 287         list(LENGTH ARGSLIST ARGSNUM)
 288         if(${ARGSNUM} GREATER 0)
 289                 file(GLOB filelist "${ARGV0}")
 290         else()
 291         file(GLOB filelist "*")
 292         endif()
 293
 294         foreach(filename ${filelist})
 295                 if(EXISTS "${filename}/CMakeLists.txt")
 296                         add_subdirectory(${filename})
 297                 endif(EXISTS "${filename}/CMakeLists.txt")
 298         endforeach()
 299 endmacro(project_subdirs_add)
 300
 301 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 302 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 303 set(CMP0048 1)
 304
 305 # Include project configuration
 306 # ------------------------------
 307 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 308 set(PROJECT_LIBDIR "${CMAKE_SOURCE_DIR}/libs" CACHE PATH "Subpath to libraries")
 309 set(PROJECT_RESOURCES "${CMAKE_SOURCE_DIR}/data" CACHE PATH "Subpath to data")
 310
 311 set(AFB_TOKEN   ""      CACHE PATH "Default AFB_TOKEN")
 312 set(AFB_REMPORT "1234" CACHE PATH "Default AFB_TOKEN")
 313
 314 INCLUDE(FindPkgConfig)
 315 INCLUDE(CheckIncludeFiles)
 316 INCLUDE(CheckLibraryExists)
 317 INCLUDE(GNUInstallDirs)
 318
 319 # Default compilation options
 320 ############################################################################
 321 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 322 add_compile_options(-Wall -Wextra -Wconversion)
 323 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 324 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 325 add_compile_options(-Werror=maybe-uninitialized)
 326 add_compile_options(-Werror=implicit-function-declaration)
 327 add_compile_options(-ffunction-sections -fdata-sections)
 328 add_compile_options(-fPIC)
 329 add_compile_options(-g)
 330
 331 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 332 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 333 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 334 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 335
 336 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 337 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 338 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 339 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 340
 341 # Env variable overload default
 342 if(DEFINED ENV{INSTALL_PREFIX})
 343         set (INSTALL_PREFIX $ENV{INSTALL_PREFIX})
 344 else()
 345         set(INSTALL_PREFIX "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 346 endif()
 347 set(CMAKE_INSTALL_PREFIX ${INSTALL_PREFIX} CACHE STRING "Installation Prefix")
 348
 349 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 350 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 351
 352 # Loop on required package and add options
 353 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 354         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 355         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 356
 357         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 358         list (APPEND link_libraries ${${XPREFIX}_LDFLAGS})
 359         add_compile_options (${${XPREFIX}_CFLAGS})
 360 endforeach(PKG_CONFIG)
 361
 362 # Optional LibEfence Malloc debug library
 363 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 364 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 365 IF(HAVE_LIBEFENCE)
 366         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 367         SET(libefence_LIBRARIES "-lefence")
 368         list (APPEND link_libraries ${libefence_LIBRARIES})
 369 ENDIF(HAVE_LIBEFENCE)
 370 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 371
 372 # set default include directories
 373 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 374
 375 # If no install dir try to guess some smart default
 376 if(BINDINGS_INSTALL_PREFIX)
 377         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 378 else()
 379         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 380 endif()
 381
 382 set(PKGOUT_DIR package CACHE PATH "Output directory for packages")
 383
 384 # Define a default package directory
 385 if(PKG_PREFIX)
 386         set(PROJECT_PKG_BUILD_DIR ${PKG_PREFIX}/${PKGOUT_DIR} CACHE PATH "Application contents to be packaged")
 387 else()
 388         set(PROJECT_PKG_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PKGOUT_DIR} CACHE PATH "Application contents to be packaged")
 389 endif()
 390
 391 set (PROJECT_APP_TEMPLATES_DIR "conf.d/templates" CACHE PATH "Default Templates directory")
 392
 393 set (PKG_TEMPLATE_PREFIX ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR} CACHE PATH "Default Package Templates Directory")
 394 set(SSH_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/ssh" CACHE PATH "Subpath to a directory where are stored needed files to launch on remote target to debuging purposes")
 395 set(GDB_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/gdb" CACHE PATH "Subpath to a directory where are stored needed files to launch debuging server on a remote target. Use gdbserver.")
 396 set(WGT_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/wgt" CACHE PATH "Subpath to a directory where are stored needed files to build widget")
 397 if(NOT WIDGET_CONFIG_TEMPLATE)
 398         set(WIDGET_CONFIG_TEMPLATE ${WGT_TEMPLATE_DIR}/config.xml.in CACHE PATH "Path to widget config file template (config.xml.in)")
 399 endif()
 400 set(RPM_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/rpm" CACHE PATH "Subpath to a directory where are stored needed files to build rpm package")
 401 set(DEB_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/deb" CACHE PATH "Subpath to a directory where are stored needed files to build deb package")
 402
 403 string(REGEX REPLACE "^(.*)/.*$" "\\1" ENTRY_POINT "${PKG_TEMPLATE_PREFIX}")
 404 set(PROJECT_PKG_ENTRY_POINT ${ENTRY_POINT}/packaging CACHE PATH "Where package build files, like rpm.spec file or config.xml, are write.")
 405
 406 # Default Linkflag
 407 if(NOT BINDINGS_LINK_FLAG)
 408         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${PKG_TEMPLATE_PREFIX}/cmake/export.map")
 409 endif()
 410
 411 # Add a dummy target to enable global dependency order
 412 # -----------------------------------------------------
 413 if(EXTRA_DEPENDENCIES_ORDER)
 414         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 415         add_custom_target(${DEPENDENCIES_TARGET} ALL
 416                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 417         )
 418 endif()
 419
 420 # Print developer helper message when build is done
 421 # -------------------------------------------------------
 422 macro(project_closing_msg)
 423         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 424         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 425         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 426                 add_custom_target(${PROJECT_NAME}_build_done ALL
 427                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 428                 )
 429                  add_dependencies(${PROJECT_NAME}_build_done
 430                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 431         endif()
 432 endmacro()
 433
 434 # Add RSYNCTARGET
 435 remote_targets_populate()
 436
 437 add_custom_command(OUTPUT ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz
 438 DEPENDS ${PROJECT_TARGETS}
 439  COMMAND git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git archive --format=tar.gz --prefix=${PROJECT_NAME}-${PROJECT_VERSION}/ HEAD -o ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz
 440 )
 441
 442 add_custom_target(archive DEPENDS ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}_${PROJECT_VERSION}.orig.tar.gz)