cmake/common.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Get colorized message output non Windows OS. You know bash ? :)
  28 if(NOT WIN32)
  29   string(ASCII 27 Esc)
  30   set(ColourReset "${Esc}[m")
  31   set(ColourBold  "${Esc}[1m")
  32   set(Red         "${Esc}[31m")
  33   set(Green       "${Esc}[32m")
  34   set(Yellow      "${Esc}[33m")
  35   set(Blue        "${Esc}[34m")
  36   set(Magenta     "${Esc}[35m")
  37   set(Cyan        "${Esc}[36m")
  38   set(White       "${Esc}[37m")
  39   set(BoldRed     "${Esc}[1;31m")
  40   set(BoldGreen   "${Esc}[1;32m")
  41   set(BoldYellow  "${Esc}[1;33m")
  42   set(BoldBlue    "${Esc}[1;34m")
  43   set(BoldMagenta "${Esc}[1;35m")
  44   set(BoldCyan    "${Esc}[1;36m")
  45   set(BoldWhite   "${Esc}[1;37m")
  46 endif()
  47
  48 # Generic useful macro
  49 # -----------------------
  50 macro(PROJECT_TARGET_ADD TARGET_NAME)
  51         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  52         set(TARGET_NAME ${TARGET_NAME})
  53 endmacro(PROJECT_TARGET_ADD)
  54
  55 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  56         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  57 endmacro(PROJECT_PKGDEP_ADD)
  58
  59 # Check GCC minimal version
  60 if (gcc_minimal_version)
  61         message (STATUS "${Blue}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION})  (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  62 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  63         message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  64 endif()
  65 endif(gcc_minimal_version)
  66
  67 # Check Kernel minimal version
  68 if (kernel_minimal_version)
  69         message (STATUS "${Blue}-- Check kernel_minimal_version (found kernel version ${CMAKE_SYSTEM_VERSION})${ColourReset}")
  70         if (CMAKE_SYSTEM_VERSION VERSION_LESS ${kernel_minimal_version})
  71         message(FATAL_ERROR "${Red}**** FATAL: Require at least ${kernel_minimal_version} please use a recent kernel.")
  72 endif()
  73 endif(kernel_minimal_version)
  74
  75 macro(defstr name value)
  76         add_definitions(-D${name}=${value})
  77 endmacro(defstr)
  78
  79 # Pre-packaging
  80 macro(project_targets_populate)
  81
  82         # Default Widget default directory
  83         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  84         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  85         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  86         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  87         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  88
  89         add_custom_target(populate)
  90         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  91         foreach(TARGET ${PROJECT_TARGETS})
  92                 get_target_property(T ${TARGET} LABELS)
  93                 if(T)
  94                         # Declaration of a custom command that will populate widget tree with the target
  95                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  96
  97                         get_target_property(P ${TARGET} PREFIX)
  98                         get_target_property(BD ${TARGET} BINARY_DIR)
  99                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 100
 101                         if(P MATCHES "NOTFOUND$")
 102                                 if (${T} STREQUAL "BINDING")
 103                                         set(P "lib")
 104                                 else()
 105                                         set(P "")
 106                                 endif()
 107                         endif()
 108
 109                         if(${T} STREQUAL "BINDING")
 110                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
 111                                         DEPENDS ${TARGET}
 112                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 113                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 114                                 )
 115                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
 116                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 117                         elseif(${T} STREQUAL "EXECUTABLE")
 118                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
 119                                         DEPENDS ${TARGET}
 120                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 121                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 122                                 )
 123                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
 124                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 125                         elseif(${T} STREQUAL "HTDOCS")
 126                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}
 127                                         DEPENDS ${TARGET}
 128                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 129                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 130                                 )
 131                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR})
 132                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 133                         elseif(${T} STREQUAL "DATA")
 134                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}
 135                                         DEPENDS ${TARGET}
 136                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 137                                         COMMAND cp -r ${BD}/${P}${OUT} ${PACKAGE_DATADIR}
 138                                 )
 139                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR})
 140                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 141                         endif(${T} STREQUAL "BINDING")
 142                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 143                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 144                 endif()
 145         endforeach()
 146 endmacro(project_targets_populate)
 147
 148 macro(remote_targets_populate)
 149         if (DEFINED ENV{RSYNC_TARGET})
 150         set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 151         endif()
 152         if (DEFINED ENV{RSYNC_PREFIX})
 153         set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 154         endif()
 155
 156         set(
 157                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 158                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 159         )
 160
 161         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 162                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 163                 add_custom_target(remote-target-populate
 164                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 165                         COMMAND exit -1
 166                 )
 167         else()
 168
 169                 configure_file(${SSH_TEMPLATE_DIR}/start-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh)
 170                 configure_file(${GDB_TEMPLATE_DIR}/gdb-on-target.in ${CMAKE_CURRENT_BINARY_DIR}/target/gdb-on-${RSYNC_TARGET}.ini)
 171
 172                 add_custom_target(remote-target-populate
 173                         DEPENDS populate
 174                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh
 175                         COMMAND rsync --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 176                         COMMENT "${REMOTE_LAUNCH}"
 177                 )
 178         endif()
 179 endmacro(remote_targets_populate)
 180
 181 macro(wgt_package_build)
 182                 # Build widget spec file from template only once (Fulup good idea or should depend on time ????)
 183                 if(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 184                         configure_file(${TEMPLATE_WGT_DIR}/config.xml.in ${PROJECT_PKG_BUILD_DIR}/config.xml)
 185                         configure_file(${TEMPLATE_WGT_DIR}/config.xml.in ${PROJECT_PKG_ENTRY_POINT}/config.xml)
 186                         file(COPY ${TEMPLATE_WGT_DIR}/icon-default.png DESTINATION ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON})
 187                 endif(NOT EXISTS ${TEMPLATE_WGT_DIR}/config.xml.in OR NOT EXISTS ${TEMPLATE_WGT_DIR}/${PROJECT_ICON})
 188         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/config.xml.in OR NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 189                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need config.xml.in and ${PROJECT_ICON} files in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 190         endif()
 191
 192         configure_file(${WGT_TEMPLATE_DIR}/config.xml.in ${PROJECT_PKG_BUILD_DIR}/config.xml)
 193         configure_file(${WGT_TEMPLATE_DIR}/config.xml.in ${PROJECT_PKG_ENTRY_POINT}/config.xml)
 194         file(COPY ${WGT_TEMPLATE_DIR}/icon-default.png DESTINATION ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON})
 195
 196         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 197         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 198         if(${PROJECT_CONF_FILES})
 199                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 200         endif(${PROJECT_CONF_FILES})
 201
 202         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 203                 DEPENDS ${PROJECT_TARGETS}
 204                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 205         )
 206
 207         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 208         add_dependencies(widget populate)
 209         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 210
 211         if(PACKAGE_MESSAGE)
 212         add_custom_command(TARGET widget
 213                 POST_BUILD
 214                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 215         endif()
 216 endmacro(wgt_package_build)
 217
 218 macro(rpm_package_build)
 219         if(NOT EXISTS ${RPM_TEMPLATE_DIR}/rpm-config.spec.in)
 220                 MESSAGE(FATAL_ERROR "${Red}Missing mandatory files: you need rpm-config.spec.in in ${RPM_TEMPLATE_DIR} folder.${ColourReset}")
 221         endif()
 222
 223         # extract PROJECT_PKG_DEPS and replace ; by , for RPM spec file
 224         get_property(PROJECT_PKG_DEPS GLOBAL PROPERTY PROJECT_PKG_DEPS)
 225         foreach (PKFCONF ${PROJECT_PKG_DEPS})
 226                 set(RPM_PKG_DEPS "${RPM_PKG_DEPS}, pkgconfig(${PKFCONF})")
 227         endforeach()
 228
 229         # build rpm spec file from template
 230         configure_file(${RPM_TEMPLATE_DIR}/rpm-config.spec.in ${PROJECT_PKG_BUILD_DIR}/${PROJECT_NAME}.spec)
 231         configure_file(${RPM_TEMPLATE_DIR}/rpm-config.spec.in ${PROJECT_PKG_ENTRY_POINT}/${PROJECT_NAME}.spec)
 232
 233         add_custom_command(OUTPUT ${PROJECT_NAME}.spec
 234                 DEPENDS ${PROJECT_TARGETS}
 235                 COMMAND rpmbuild -ba  ${PROJECT_PKG_BUILD_DIR}/${PROJECT_NAME}.spec
 236         )
 237
 238         add_custom_target(rpm DEPENDS ${PROJECT_NAME}.spec)
 239         add_dependencies(rpm populate)
 240         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 241
 242         if(PACKAGE_MESSAGE)
 243         add_custom_command(TARGET rpm
 244                 POST_BUILD
 245                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 246         endif()
 247 endmacro(rpm_package_build)
 248
 249 macro(project_package_build)
 250         if(EXISTS ${RPM_TEMPLATE_DIR})
 251                 rpm_package_build()
 252         endif()
 253
 254         if(EXISTS ${WGT_TEMPLATE_DIR})
 255                 wgt_package_build()
 256         endif()
 257
 258         if(EXISTS ${DEB_TEMPLATE_DIR})
 259                 deb_package_build()
 260         endif()
 261 endmacro(project_package_build)
 262
 263 macro(project_subdirs_add)
 264         set (ARGSLIST ${ARGN})
 265         list(LENGTH ARGSLIST ARGSNUM)
 266         if(${ARGSNUM} GREATER 0)
 267                 file(GLOB filelist "${ARGV0}")
 268         else()
 269         file(GLOB filelist "*")
 270         endif()
 271
 272         foreach(filename ${filelist})
 273                 if(EXISTS "${filename}/CMakeLists.txt")
 274                         add_subdirectory(${filename})
 275                 endif(EXISTS "${filename}/CMakeLists.txt")
 276         endforeach()
 277 endmacro(project_subdirs_add)
 278
 279 set(CMAKE_BUILD_TYPE Debug CACHE STRING "the type of build")
 280 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 281 set(CMP0048 1)
 282
 283 # Include project configuration
 284 # ------------------------------
 285 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
 286 set(PROJECT_LIBDIR "${CMAKE_SOURCE_DIR}/libs" CACHE PATH "Subpath to libraries")
 287 set(PROJECT_RESOURCES "${CMAKE_SOURCE_DIR}/data" CACHE PATH "Subpath to data")
 288
 289 set(AFB_TOKEN   ""      CACHE PATH "Default AFB_TOKEN")
 290 set(AFB_REMPORT "1234" CACHE PATH "Default AFB_TOKEN")
 291
 292 INCLUDE(FindPkgConfig)
 293 INCLUDE(CheckIncludeFiles)
 294 INCLUDE(CheckLibraryExists)
 295 INCLUDE(GNUInstallDirs)
 296
 297 # Default compilation options
 298 ############################################################################
 299 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 300 add_compile_options(-Wall -Wextra -Wconversion)
 301 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 302 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 303 add_compile_options(-Werror=maybe-uninitialized)
 304 add_compile_options(-Werror=implicit-function-declaration)
 305 add_compile_options(-ffunction-sections -fdata-sections)
 306 add_compile_options(-fPIC)
 307 add_compile_options(-g)
 308
 309 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
 310 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
 311 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
 312 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
 313
 314 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
 315 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
 316 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
 317 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
 318
 319 set(CMAKE_INSTALL_PREFIX      "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
 320
 321 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 322 set(PKG_CONFIG_USE_CMAKE_PREFIX_PATH ON CACHE BOOLEAN "Flag for using prefix path")
 323
 324 # Loop on required package and add options
 325 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 326         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 327         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 328
 329         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 330         list (APPEND link_libraries ${${XPREFIX}_LIBRARIES})
 331         add_compile_options (${${XPREFIX}_CFLAGS})
 332 endforeach(PKG_CONFIG)
 333
 334 # Optional LibEfence Malloc debug library
 335 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 336 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 337 IF(HAVE_LIBEFENCE)
 338         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 339         SET(libefence_LIBRARIES "-lefence")
 340         list (APPEND link_libraries ${libefence_LIBRARIES})
 341 ENDIF(HAVE_LIBEFENCE)
 342 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 343
 344 # set default include directories
 345 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 346
 347 # If no install dir try to guess some smart default
 348 if(BINDINGS_INSTALL_PREFIX)
 349         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 350 else()
 351         set(BINDINGS_INSTALL_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 352 endif()
 353
 354 # Define a default package directory
 355 if(PACKAGE_PREFIX)
 356         set(PROJECT_PKG_BUILD_DIR ${PKG_PREFIX}/package CACHE PATH "Where the package will be built.")
 357 else()
 358         set(PROJECT_PKG_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/package CACHE PATH "Where the package will be built")
 359 endif()
 360
 361 set (PKG_TEMPLATE_PREFIX ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR} CACHE PATH "Default Package Templates Directory")
 362 set(SSH_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/ssh" CACHE PATH "Subpath to a directory where are stored needed files to launch on remote target to debuging purposes")
 363 set(GDB_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/gdb" CACHE PATH "Subpath to a directory where are stored needed files to launch debuging server on a remote target. Use gdbserver.")
 364 set(WGT_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/wgt" CACHE PATH "Subpath to a directory where are stored needed files to build widget")
 365 set(RPM_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/rpm" CACHE PATH "Subpath to a directory where are stored needed files to build rpm package")
 366 set(DEB_TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/deb" CACHE PATH "Subpath to a directory where are stored needed files to build deb package")
 367
 368 string(REGEX REPLACE "^(.*)/.*$" "\\1" ENTRY_POINT "${PKG_TEMPLATE_PREFIX}")
 369 set(PROJECT_PKG_ENTRY_POINT ${ENTRY_POINT}/packaging CACHE PATH "Where package build files, like rpm.spec file or config.xml, are write.")
 370
 371 # Default Linkflag
 372 if(NOT BINDINGS_LINK_FLAG)
 373         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${PKG_TEMPLATE_PREFIX}/cmake/export.map")
 374 endif()
 375
 376 # Add a dummy target to enable global dependency order
 377 # -----------------------------------------------------
 378 if(EXTRA_DEPENDENCIES_ORDER)
 379         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 380         add_custom_target(${DEPENDENCIES_TARGET} ALL
 381                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 382         )
 383 endif()
 384
 385 # Print developer helper message when build is done
 386 # -------------------------------------------------------
 387 macro(project_closing_msg)
 388         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 389         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 390         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 391                 add_custom_target(${PROJECT_NAME}_build_done ALL
 392                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 393                 )
 394                  add_dependencies(${PROJECT_NAME}_build_done
 395                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 396         endif()
 397 endmacro()
 398
 399 # Add RSYSTARGET
 400 remote_targets_populate()