cmake/cmake.d/04-extra_targets.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Add a dummy target to enable global dependency order
  28 # -----------------------------------------------------
  29 if(EXTRA_DEPENDENCIES_ORDER)
  30         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
  31         add_custom_target(${DEPENDENCIES_TARGET} ALL
  32                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
  33         )
  34 endif()
  35
  36 # ----------------------------------------------------------------------------
  37 #                                Archive target
  38 # ----------------------------------------------------------------------------
  39 add_custom_command(OUTPUT  ${ARCHIVE_OUTPUT}
  40         DEPENDS ${PROJECT_TARGETS}
  41         #Create git archive of the main project
  42         COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR}\; git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git archive --format=tar --prefix=${NPKG_PROJECT_NAME}-${PROJECT_VERSION}/ HEAD -o ${ARCHIVE_OUTPUT_ARCHIVE}
  43         #Create tmp git archive for each submodule
  44         COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR}\; git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git submodule foreach --recursive ${CMD_ARCHIVE_SUBMODULE}
  45         #Concatenate main archive and tmp submodule archive
  46         COMMAND  for SUBTAR in ${TMP_ARCHIVE_SUBMODULE}-*.tar\; do tar --concatenate --file=${ARCHIVE_OUTPUT_ARCHIVE} $$SUBTAR\;done
  47         #Remove tmp submodule archive
  48         COMMAND rm -rf ${TMP_ARCHIVE_SUBMODULE}-*.tar
  49         #Compress main archive
  50         COMMAND gzip --force --verbose ${ARCHIVE_OUTPUT_ARCHIVE}
  51 )
  52 add_custom_target(archive DEPENDS ${ARCHIVE_OUTPUT})
  53
  54 # ----------------------------------------------------------------------------
  55 #                                Packaging target
  56 # ----------------------------------------------------------------------------
  57 #Format Build require package
  58 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
  59         #Unset TMP variable
  60         unset(XPREFIX)
  61         unset(XRULE)
  62         unset(RPM_EXTRA_DEP)
  63         unset(DEB_EXTRA_DEP)
  64         #For deb package,add EOL format only for a new line
  65         if(DEB_PKG_DEPS)
  66                 set(DEB_PKG_DEPS "${DEB_PKG_DEPS},\n")
  67         endif()
  68         #Get pkg-config rule on version
  69         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
  70         string(REGEX MATCH "[<>]?="  XRULE ${PKG_CONFIG})
  71         #Only if pkg-config has rule on version
  72         if(XRULE)
  73                 string(REGEX REPLACE ".*[<>]?=" "" XVERS ${PKG_CONFIG})
  74                 set(RPM_EXTRA_DEP " ${XRULE} ${XVERS}")
  75                 set(DEB_EXTRA_DEP " (${XRULE} ${XVERS})")
  76         endif()
  77         # Format for rpm package
  78         set(RPM_PKG_DEPS "${RPM_PKG_DEPS}BuildRequires: pkgconfig(${XPREFIX})${RPM_EXTRA_DEP}\n")
  79
  80         # Format for deb package
  81         # Because the tool "dpkg" is used on the packages db to find the
  82         # package providing the pkg-cong file ${XPREFIX}.pc, we need
  83         # to test the OS release package type
  84         # Only doable within a native environment not under SDK
  85         if( OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
  86                 execute_process(
  87                         COMMAND dpkg -S *${XPREFIX}.pc
  88                                         OUTPUT_VARIABLE TMP_PKG_BIN
  89                 )
  90                 #Need to be harden check
  91                 string(REGEX REPLACE ":.*$" "" PKG_BIN ${TMP_PKG_BIN})
  92                 set(DEB_PKG_DEPS "${DEB_PKG_DEPS} ${PKG_BIN} ${DEB_EXTRA_DEP}")
  93         endif()
  94 endforeach()
  95
  96 if(NOT EXISTS ${TEMPLATE_DIR}/rpm-config.spec.in)
  97         MESSAGE(FATAL_ERROR "${Red}Missing mandatory files: you need rpm-config.spec.in in ${TEMPLATE_DIR} folder.${ColourReset}")
  98 endif()
  99
 100 # Because the tool "dpkg" is used on the packages db to find the
 101 # package providing the pkg-cong file ${XPREFIX}.pc, we need
 102 # to test the OS release package type
 103 # Only doable within a native environment not under SDK
 104 if(OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
 105         add_custom_target(packaging_deb DEPENDS ${TEMPLATE_DIR}/debian.compat.in
 106                                 ${TEMPLATE_DIR}/debian.changelog.in
 107                                 ${TEMPLATE_DIR}/deb-config.dsc.in
 108                                 ${TEMPLATE_DIR}/deb-config.install.in
 109                                 ${TEMPLATE_DIR}/debian.control.in
 110                                 ${TEMPLATE_DIR}/debian.rules.in
 111                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/debian.compat.in              -DOUTFILE=${PACKAGING_DEB_OUTPUT_COMPAT}        -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 112                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/debian.changelog.in   -DOUTFILE=${PACKAGING_DEB_OUTPUT_CHANGELOG}     -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 113                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/deb-config.dsc.in             -DOUTFILE=${PACKAGING_DEB_OUTPUT_DSC}           -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 114                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/deb-config.install.in -DOUTFILE=${PACKAGING_DEB_OUTPUT_INSTALL}       -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 115                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/debian.control.in             -DOUTFILE=${PACKAGING_DEB_OUTPUT_CONTROL}       -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 116                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/debian.rules.in               -DOUTFILE=${PACKAGING_DEB_OUTPUT_RULES}         -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 117         )
 118 endif()
 119
 120 add_custom_target(packaging)
 121 set(PACKAGING_SPEC_OUTPUT ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec)
 122 add_custom_target(packaging_rpm DEPENDS ${TEMPLATE_DIR}/rpm-config.spec.in
 123         COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/rpm-config.spec.in -DOUTFILE=${PACKAGING_SPEC_OUTPUT} -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 124 )
 125 add_dependencies(packaging packaging_rpm)
 126 if(TARGET packaging_wgt)
 127         add_dependencies(packaging packaging_wgt)
 128 endif()
 129 if(OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
 130         # Target to add dependencies indirectly to "packaging" target.
 131         add_dependencies(packaging packaging_deb)
 132 endif()
 133
 134 #Generate a cmake cache file usable by cmake script.
 135 set(CacheForScript ${CMAKE_BINARY_DIR}/CMakeCacheForScript.cmake)
 136 #Create a tmp cmake file.
 137 file(WRITE ${CacheForScript} "")
 138
 139 get_cmake_property(Vars VARIABLES)
 140 foreach(Var ${Vars})
 141         if(${Var})
 142                 #Replace unwanted char.
 143                 string(REPLACE "\\" "\\\\" VALUE ${${Var}})
 144                 string(REPLACE "\n" "\\n" VALUE ${VALUE})
 145                 string(REPLACE "\r" "\\n" VALUE ${VALUE})
 146                 string(REPLACE "\"" "\\\"" VALUE ${VALUE})
 147         endif()
 148         file(APPEND ${CacheForScript} "set(${Var} \"${VALUE}\")\n")
 149 endforeach()
 150
 151 # ----------------------------------------------------------------------------
 152 #                                Autobuild target
 153 # ----------------------------------------------------------------------------
 154
 155 add_custom_target(autobuild ALL DEPENDS ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/template.d/autobuild/agl/autobuild.in
 156         ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/template.d/autobuild/linux/autobuild.in
 157         COMMAND ${CMAKE_COMMAND} -DINFILE=${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/template.d/autobuild/agl/autobuild.in -DOUTFILE=${PROJECT_TEMPLATE_AGL_AUTOBUILD_DIR}/autobuild -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 158         COMMAND ${CMAKE_COMMAND} -DINFILE=${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/template.d/autobuild/agl/autobuild.in -DOUTFILE=${PROJECT_TEMPLATE_LINUX_AUTOBUILD_DIR}/autobuild -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 159 )