cmake/cmake.d/04-extra_targets.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # ----------------------------------------------------------------------------
  28 #                                Archive target
  29 # ----------------------------------------------------------------------------
  30 add_custom_command(OUTPUT  ${ARCHIVE_OUTPUT}
  31         DEPENDS ${PROJECT_TARGETS}
  32         #Create git archive of the main project
  33         COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR}\; git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git archive --format=tar --prefix=${NPKG_PROJECT_NAME}-${PROJECT_VERSION}/ HEAD -o ${ARCHIVE_OUTPUT_ARCHIVE}
  34         #Create tmp git archive for each submodule
  35         COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR}\; git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git submodule foreach --recursive ${CMD_ARCHIVE_SUBMODULE}
  36         #Concatenate main archive and tmp submodule archive
  37         COMMAND  for SUBTAR in ${TMP_ARCHIVE_SUBMODULE}-*.tar\; do tar --concatenate --file=${ARCHIVE_OUTPUT_ARCHIVE} $$SUBTAR\;done
  38         #Remove tmp submodule archive
  39         COMMAND rm -rf ${TMP_ARCHIVE_SUBMODULE}-*.tar
  40         #Compress main archive
  41         COMMAND gzip --force --verbose ${ARCHIVE_OUTPUT_ARCHIVE}
  42 )
  43 add_custom_target(archive DEPENDS ${ARCHIVE_OUTPUT})
  44
  45 # ----------------------------------------------------------------------------
  46 #                                Packaging target
  47 # ----------------------------------------------------------------------------
  48 #Format Build require package
  49 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
  50         #Unset TMP variable
  51         unset(XPREFIX)
  52         unset(XRULE)
  53         unset(RPM_EXTRA_DEP)
  54         unset(DEB_EXTRA_DEP)
  55         #For deb package,add EOL format only for a new line
  56         if(DEB_PKG_DEPS)
  57                 set(DEB_PKG_DEPS "${DEB_PKG_DEPS},\n")
  58         endif()
  59         #Get pkg-config rule on version
  60         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
  61         string(REGEX MATCH "[<>]?="  XRULE ${PKG_CONFIG})
  62         #Only if pkg-config has rule on version
  63         if(XRULE)
  64                 string(REGEX REPLACE ".*[<>]?=" "" XVERS ${PKG_CONFIG})
  65                 set(RPM_EXTRA_DEP " ${XRULE} ${XVERS}")
  66                 set(DEB_EXTRA_DEP " (${XRULE} ${XVERS})")
  67         endif()
  68         # Format for rpm package
  69         set(RPM_PKG_DEPS "${RPM_PKG_DEPS}BuildRequires: pkgconfig(${XPREFIX})${RPM_EXTRA_DEP}\n")
  70
  71         # Format for deb package
  72         # Because the tool "dpkg" is used on the packages db to find the
  73         # package providing the pkg-cong file ${XPREFIX}.pc, we need
  74         # to test the OS release package type
  75         # Only doable within a native environment not under SDK
  76         if( OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
  77                 execute_process(
  78                         COMMAND dpkg -S *${XPREFIX}.pc
  79                                         OUTPUT_VARIABLE TMP_PKG_BIN
  80                 )
  81                 if(TMP_PKG_BIN)
  82                         string(REGEX REPLACE ":.*$" "" PKG_BIN ${TMP_PKG_BIN})
  83                         set(DEB_PKG_DEPS "${DEB_PKG_DEPS} ${PKG_BIN} ${DEB_EXTRA_DEP}")
  84                 else()
  85                         message(FATAL_ERROR "-- ${Red}${XPREFIX} development files not installed. Abort.${ColourReset}")
  86                 endif()
  87         endif()
  88 endforeach()
  89
  90 if(NOT EXISTS ${TEMPLATE_DIR}/rpm-config.spec.in)
  91         MESSAGE(FATAL_ERROR "${Red}Missing mandatory files: you need rpm-config.spec.in in ${TEMPLATE_DIR} folder.${ColourReset}")
  92 endif()
  93
  94 # Because the tool "dpkg" is used on the packages db to find the
  95 # package providing the pkg-cong file ${XPREFIX}.pc, we need
  96 # to test the OS release package type
  97 # Only doable within a native environment not under SDK
  98 if(OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
  99         add_custom_target(packaging_deb DEPENDS ${TEMPLATE_DIR}/debian.compat.in
 100                                 ${TEMPLATE_DIR}/debian.changelog.in
 101                                 ${TEMPLATE_DIR}/deb-config.dsc.in
 102                                 ${TEMPLATE_DIR}/deb-config.install.in
 103                                 ${TEMPLATE_DIR}/debian.control.in
 104                                 ${TEMPLATE_DIR}/debian.rules.in
 105                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/debian.compat.in              -DOUTFILE=${PACKAGING_DEB_OUTPUT_COMPAT}        -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 106                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/debian.changelog.in   -DOUTFILE=${PACKAGING_DEB_OUTPUT_CHANGELOG}     -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 107                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/deb-config.dsc.in             -DOUTFILE=${PACKAGING_DEB_OUTPUT_DSC}           -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 108                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/deb-config.install.in -DOUTFILE=${PACKAGING_DEB_OUTPUT_INSTALL}       -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 109                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/debian.control.in             -DOUTFILE=${PACKAGING_DEB_OUTPUT_CONTROL}       -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 110                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/debian.rules.in               -DOUTFILE=${PACKAGING_DEB_OUTPUT_RULES}         -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 111         )
 112 endif()
 113
 114 add_custom_target(packaging)
 115 set(PACKAGING_SPEC_OUTPUT ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec)
 116 add_custom_target(packaging_rpm DEPENDS ${TEMPLATE_DIR}/rpm-config.spec.in
 117         COMMAND ${CMAKE_COMMAND} -DINFILE=${TEMPLATE_DIR}/rpm-config.spec.in -DOUTFILE=${PACKAGING_SPEC_OUTPUT} -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 118 )
 119 add_dependencies(packaging packaging_rpm)
 120 if(TARGET packaging_wgt)
 121         add_dependencies(packaging packaging_wgt)
 122 endif()
 123 if(OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
 124         # Target to add dependencies indirectly to "packaging" target.
 125         add_dependencies(packaging packaging_deb)
 126 endif()
 127
 128 #Generate a cmake cache file usable by cmake script.
 129 set(CacheForScript ${CMAKE_BINARY_DIR}/CMakeCacheForScript.cmake)
 130 #Create a tmp cmake file.
 131 file(WRITE ${CacheForScript} "")
 132
 133 get_cmake_property(Vars VARIABLES)
 134 foreach(Var ${Vars})
 135         if(${Var})
 136                 #Replace unwanted char.
 137                 string(REPLACE "\\" "\\\\" VALUE ${${Var}})
 138                 string(REPLACE "\n" "\\n" VALUE ${VALUE})
 139                 string(REPLACE "\r" "\\n" VALUE ${VALUE})
 140                 string(REPLACE "\"" "\\\"" VALUE ${VALUE})
 141         endif()
 142         file(APPEND ${CacheForScript} "set(${Var} \"${VALUE}\")\n")
 143 endforeach()
 144
 145 # ----------------------------------------------------------------------------
 146 #                                Autobuild target
 147 # ----------------------------------------------------------------------------
 148
 149 add_custom_target(autobuild ALL DEPENDS ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/template.d/autobuild/agl/autobuild.in
 150         ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/template.d/autobuild/linux/autobuild.in
 151         COMMAND ${CMAKE_COMMAND} -DINFILE=${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/template.d/autobuild/agl/autobuild.in -DOUTFILE=${PROJECT_TEMPLATE_AGL_AUTOBUILD_DIR}/autobuild -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 152         COMMAND ${CMAKE_COMMAND} -DINFILE=${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/template.d/autobuild/agl/autobuild.in -DOUTFILE=${PROJECT_TEMPLATE_LINUX_AUTOBUILD_DIR}/autobuild -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 153 )