cmake/cmake.d/04-build_options.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Check GCC minimal version
  28 if (gcc_minimal_version)
  29                 message (STATUS "${Cyan}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION}) \
  30                 (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  31         if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  32                 message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  33         endif()
  34 endif(gcc_minimal_version)
  35
  36 # Check Kernel minimal version
  37 if (kernel_minimal_version)
  38         if(DEFINED ENV{SDKTARGETSYSROOT})
  39                 file(STRINGS $ENV{SDKTARGETSYSROOT}/usr/include/linux/version.h LINUX_VERSION_CODE_LINE REGEX "LINUX_VERSION_CODE")
  40         elseif(DEFINED ENV{PKG_CONFIG_SYSROOT_DIR})
  41                 file(STRINGS $ENV{PKG_CONFIG_SYSROOT_DIR}/usr/include/linux/version.h LINUX_VERSION_CODE_LINE REGEX "LINUX_VERSION_CODE")
  42         else()
  43                 file(STRINGS /usr/include/linux/version.h LINUX_VERSION_CODE_LINE REGEX "LINUX_VERSION_CODE")
  44         endif()
  45
  46         string(REGEX MATCH "[0-9]+" LINUX_VERSION_CODE ${LINUX_VERSION_CODE_LINE})
  47         math(EXPR a "${LINUX_VERSION_CODE} >> 16")
  48         math(EXPR b "(${LINUX_VERSION_CODE} >> 8) & 255")
  49         math(EXPR c "(${LINUX_VERSION_CODE} & 255)")
  50
  51         set(KERNEL_VERSION "${a}.${b}.${c}")
  52         message (STATUS "${Cyan}-- Check kernel_minimal_version (found kernel version ${KERNEL_VERSION})${ColourReset}")
  53
  54         if (KERNEL_VERSION VERSION_LESS ${kernel_minimal_version})
  55                 message(FATAL_ERROR "${Red}**** FATAL: Require at least ${kernel_minimal_version} please use a recent kernel or source your SDK environment then clean and reconfigure your CMake project.")
  56         endif (KERNEL_VERSION VERSION_LESS ${kernel_minimal_version})
  57 endif(kernel_minimal_version)
  58
  59 INCLUDE(FindPkgConfig)
  60 INCLUDE(CheckIncludeFiles)
  61 INCLUDE(CheckLibraryExists)
  62 INCLUDE(GNUInstallDirs)
  63
  64 # Default compilation options
  65 ############################################################################
  66 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
  67 add_compile_options(-Wall -Wextra -Wconversion)
  68 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
  69 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
  70 add_compile_options(-Werror=maybe-uninitialized)
  71 add_compile_options(-Werror=implicit-function-declaration)
  72 add_compile_options(-ffunction-sections -fdata-sections)
  73 add_compile_options(-fPIC)
  74 add_compile_options(-g)
  75
  76 set(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for profiling")
  77 set(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE" CACHE STRING "Flags for debugging")
  78 set(CMAKE_C_FLAGS_RELEASE     "-O2" CACHE STRING "Flags for releasing")
  79 set(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage" CACHE STRING "Flags for coverage test")
  80
  81 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -pg -Wp,-U_FORTIFY_SOURCE")
  82 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -ggdb -Wp,-U_FORTIFY_SOURCE")
  83 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2")
  84 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 --coverage")
  85
  86 # Env variable overload default
  87 if(DEFINED ENV{INSTALL_PREFIX})
  88         set (INSTALL_PREFIX $ENV{INSTALL_PREFIX})
  89 else()
  90         set(INSTALL_PREFIX "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
  91 endif()
  92 set(CMAKE_INSTALL_PREFIX ${INSTALL_PREFIX} CACHE STRING "Installation Prefix")
  93
  94 # Loop on required package and add options
  95 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
  96         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
  97         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
  98
  99         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 100         list (APPEND link_libraries ${${XPREFIX}_LDFLAGS})
 101         add_compile_options (${${XPREFIX}_CFLAGS})
 102 endforeach(PKG_CONFIG)
 103
 104 # Optional LibEfence Malloc debug library
 105 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 106 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 107 IF(HAVE_LIBEFENCE)
 108         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 109         SET(libefence_LIBRARIES "-lefence")
 110         list (APPEND link_libraries ${libefence_LIBRARIES})
 111 ENDIF(HAVE_LIBEFENCE)
 112 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 113
 114 # set default include directories
 115 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 116
 117 # Default Linkflag
 118 if(NOT BINDINGS_LINK_FLAG)
 119         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${PKG_TEMPLATE_PREFIX}/cmake/export.map")
 120 endif()