cmake/cmake.d/04-build_options.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Check GCC minimal version
  28 if (gcc_minimal_version)
  29                 message (STATUS "${Cyan}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION}) \
  30                 (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  31         if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  32                 message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  33         endif()
  34 endif(gcc_minimal_version)
  35
  36 # Check Kernel mandatory version, will fail the configuration if required version not matched.
  37 if (kernel_mandatory_version)
  38         message (STATUS "${Cyan}-- Check kernel_mandatory_version (found kernel version ${KERNEL_VERSION})${ColourReset}")
  39         if (KERNEL_VERSION VERSION_LESS ${kernel_mandatory_version})
  40                 message(FATAL_ERROR "${Red}**** FATAL: Require at least ${kernel_mandatory_version} please use a recent kernel or source your SDK environment then clean and reconfigure your CMake project.")
  41         endif (KERNEL_VERSION VERSION_LESS ${kernel_mandatory_version})
  42 endif(kernel_mandatory_version)
  43
  44 # Check Kernel minimal version just print a Warning about missing features
  45 # and set a definition to be used as preprocessor condition in code to disable
  46 # incompatibles features.
  47 if (kernel_minimal_version)
  48         message (STATUS "${Cyan}-- Check kernel_minimal_version (found kernel version ${KERNEL_VERSION})${ColourReset}")
  49         if (KERNEL_VERSION VERSION_LESS ${kernel_minimal_version})
  50                 message(WARNING "${Yellow}**** Warning: Some feature(s) require at least ${kernel_minimal_version}. Please use a recent kernel or source your SDK environment then clean and reconfigure your CMake project.${ColourReset}")
  51         else (KERNEL_VERSION VERSION_LESS ${kernel_minimal_version})
  52                 add_definitions(-DKERNEL_MINIMAL_VERSION_OK)
  53         endif (KERNEL_VERSION VERSION_LESS ${kernel_minimal_version})
  54 endif(kernel_minimal_version)
  55
  56 INCLUDE(FindPkgConfig)
  57 INCLUDE(CheckIncludeFiles)
  58 INCLUDE(CheckLibraryExists)
  59 INCLUDE(GNUInstallDirs)
  60
  61 # Default compilation options
  62 ############################################################################
  63 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
  64 add_compile_options(-Wall -Wextra -Wconversion)
  65 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
  66 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
  67 add_compile_options(-Werror=maybe-uninitialized)
  68 add_compile_options(-Werror=implicit-function-declaration)
  69 add_compile_options(-ffunction-sections -fdata-sections)
  70 add_compile_options(-fPIC)
  71
  72 # TODO: make more visible readable compile (macro ? split ?)
  73 # Compilation option depending on CMAKE_BUILD_TYPE
  74 ##################################################
  75 add_compile_options($<$<CONFIG:PROFILING>:-g>)
  76 add_compile_options($<$<CONFIG:PROFILING>:-O0>)
  77 add_compile_options($<$<CONFIG:PROFILING>:-pg>)
  78 add_compile_options($<$<CONFIG:PROFILING>:-Wp,-U_FORTIFY_SOURCE>)
  79
  80 add_compile_options($<$<CONFIG:DEBUG>:-g>)
  81 add_compile_options($<$<CONFIG:DEBUG>:-O0>)
  82 add_compile_options($<$<CONFIG:DEBUG>:-ggdb>)
  83 add_compile_options($<$<CONFIG:DEBUG>:-Wp,-U_FORTIFY_SOURCE>)
  84
  85 add_compile_options($<$<CONFIG:CCOV>:-g>)
  86 add_compile_options($<$<CONFIG:CCOV>:-O2>)
  87 add_compile_options($<$<CONFIG:CCOV>:--coverage>)
  88
  89 # Env variable overload default
  90 if(DEFINED ENV{INSTALL_PREFIX})
  91         set(INSTALL_PREFIX $ENV{INSTALL_PREFIX} CACHE PATH "The path where to install")
  92 else()
  93         set(INSTALL_PREFIX "${CMAKE_SOURCE_DIR}/Install" CACHE PATH "The path where to install")
  94 endif()
  95 set(CMAKE_INSTALL_PREFIX ${INSTALL_PREFIX} CACHE STRING "Installation Prefix")
  96
  97 # Loop on required package and add options
  98 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
  99         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 100         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 101
 102         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 103         list (APPEND link_libraries ${${XPREFIX}_LDFLAGS})
 104         add_compile_options (${${XPREFIX}_CFLAGS})
 105 endforeach(PKG_CONFIG)
 106
 107 # Optional LibEfence Malloc debug library
 108 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 109 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 110 IF(HAVE_LIBEFENCE)
 111         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 112         SET(libefence_LIBRARIES "-lefence")
 113         list (APPEND link_libraries ${libefence_LIBRARIES})
 114 ENDIF(HAVE_LIBEFENCE)
 115 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 116
 117 # set default include directories
 118 INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 119
 120 # Default Linkflag
 121 if(NOT BINDINGS_LINK_FLAG)
 122         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${PKG_TEMPLATE_PREFIX}/cmake/export.map")
 123 endif()