cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 macro(configure_files_in_dir dir)
  41         file(GLOB filelist "${dir}/*in")
  42         foreach(file ${filelist})
  43                 get_filename_component(filename ${file} NAME)
  44                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
  45                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
  46                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
  47                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
  48         endforeach()
  49 endmacro(configure_files_in_dir)
  50
  51 # Create custom target dedicated for HTML5 and DATA AGL target type
  52 macro(add_input_files INPUT_FILES)
  53         set(XML_LIST ${INPUT_FILES})
  54         set(LUA_LIST ${INPUT_FILES})
  55         set(JSON_LIST ${INPUT_FILES})
  56         list(FILTER XML_LIST INCLUDE REGEX "xml$")
  57         list(FILTER LUA_LIST INCLUDE REGEX "lua$")
  58         list(FILTER JSON_LIST INCLUDE REGEX "json$")
  59
  60         add_custom_target(${TARGET_NAME}
  61         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  62         )
  63
  64         foreach(file ${XML_LIST})
  65                 add_custom_command(TARGET ${TARGET_NAME}
  66                         PRE_BUILD
  67                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  68                         COMMAND ${XML_CHECKER} ${file}
  69                 )
  70         endforeach()
  71         foreach(file ${LUA_LIST})
  72         add_custom_command(TARGET ${TARGET_NAME}
  73                 PRE_BUILD
  74                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  75                 COMMAND ${LUA_CHECKER} ${file}
  76         )
  77         endforeach()
  78         foreach(file ${JSON_LIST})
  79         add_custom_command(TARGET ${TARGET_NAME}
  80                 PRE_BUILD
  81                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  82                 COMMAND cat ${file} | ${JSON_CHECKER}
  83         )
  84         endforeach()
  85
  86         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  87         DEPENDS ${INPUT_FILES}
  88         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  89         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  90         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  91         )
  92 endmacro()
  93
  94 # Set the name of the OPENAPI definition JSON file for binding v2
  95 macro(set_openapi_filename openapi_filename)
  96         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
  97 endmacro()
  98
  99 # Pre-packaging
 100 macro(project_targets_populate)
 101         # Default Widget default directory
 102         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
 103         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
 104         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
 105         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
 106         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
 107
 108         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 109                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 110         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 111                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 112         foreach(TARGET ${PROJECT_TARGETS})
 113                 get_target_property(T ${TARGET} LABELS)
 114                 if(T)
 115                         # Declaration of a custom command that will populate widget tree with the target
 116                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 117
 118                         get_target_property(P ${TARGET} PREFIX)
 119                         get_target_property(BD ${TARGET} BINARY_DIR)
 120                         get_target_property(SD ${TARGET} SOURCE_DIR)
 121                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 122
 123                         if(P MATCHES "NOTFOUND$")
 124                                 if (${T} STREQUAL "BINDING")
 125                                         set(P "lib")
 126                                 else()
 127                                         set(P "")
 128                                 endif()
 129                         endif()
 130
 131                         if(${T} STREQUAL "BINDING")
 132                                 list(APPEND BINDINGS_LIST "${P}${OUT}")
 133                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 134                                         DEPENDS ${BD}/${P}${OUT}.so
 135                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 136                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 137                                 )
 138                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 139                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 140                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 141                         elseif(${T} STREQUAL "BINDINGV2")
 142                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 143                                         DEPENDS ${BD}/${P}${OUT}.so
 144                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 145                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 146                                 )
 147                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 148
 149                                 if (OPENAPI_DEF)
 150                                         add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 151                                                 DEPENDS ${SD}/${OPENAPI_DEF}.json
 152                                                 COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 153                                         )
 154                                         add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 155                                                 COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 156                                         add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 157                                 else()
 158                                         add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 159                                                 DEPENDS ${SD}/${OUT}-apidef.json
 160                                                 COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 161                                         )
 162                                         add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 163                                                 COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 164                                         add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 165                                 endif()
 166                         elseif(${T} STREQUAL "EXECUTABLE")
 167                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
 168                                         DEPENDS ${BD}/${P}${OUT}
 169                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 170                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 171                                 )
 172                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${OUT})
 173                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 174                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 175                         elseif(${T} STREQUAL "HTDOCS")
 176                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 177                                         DEPENDS ${BD}/${P}${OUT}
 178                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 179                                         COMMAND touch ${PACKAGE_HTTPDIR}
 180                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 181                                 )
 182                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 183                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 184                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 185                         elseif(${T} STREQUAL "DATA")
 186                                 # Generate list of output files instead of just one output directory
 187                                 get_target_property(SF ${TARGET} SOURCES)
 188                                 foreach(file ${SF})
 189                                         get_filename_component(JUST_FILENAME ${file} NAME)
 190                                         list(APPEND OUTPUT_FILES ${PACKAGE_DATADIR}/${JUST_FILENAME})
 191                                 endforeach()
 192                                 add_custom_target(${POPULE_PACKAGE_TARGET})
 193                                 add_custom_command(TARGET ${POPULE_PACKAGE_TARGET}
 194                                         POST_BUILD
 195                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 196                                         COMMAND touch ${PACKAGE_DATADIR}
 197                                         COMMAND cp -r ${BD}/${TARGET} ${PACKAGE_DATADIR}
 198                                 )
 199                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 200                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 201                         endif(${T} STREQUAL "BINDING")
 202                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 203                         MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 204                 endif()
 205         endforeach()
 206 endmacro(project_targets_populate)
 207
 208 macro(remote_targets_populate)
 209         if (DEFINED ENV{RSYNC_TARGET})
 210                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 211         endif()
 212         if (DEFINED ENV{RSYNC_PREFIX})
 213                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 214         endif()
 215
 216         set(
 217                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 218                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 219         )
 220
 221         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 222                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 223                 add_custom_target(remote-target-populate
 224                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 225                         COMMAND exit -1
 226                 )
 227         else()
 228                 set(BINDINGS_REGEX "not_set")
 229                 if(DEFINED BINDINGS_LIST)
 230                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 231                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 232                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 233                                 string(APPEND BINDINGS_REGEX ".so")
 234                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 235                                 foreach(B IN LISTS BINDINGS_LIST)
 236                                         STRING(APPEND BINDINGS_STR "${B}|")
 237                                 endforeach()
 238                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 239                         endif()
 240                 endif()
 241
 242                 configure_files_in_dir(${TEMPLATE_DIR})
 243                 configure_files_in_dir(${TEMPLATE_DIR})
 244
 245                 add_custom_target(remote-target-populate
 246                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 247                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 248                         COMMENT "${REMOTE_LAUNCH}"
 249                 )
 250                 add_dependencies(remote-target-populate populate)
 251         endif()
 252 endmacro(remote_targets_populate)
 253
 254 macro(wgt_package_build)
 255         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 256                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 257         endif()
 258         if(NOT WIDGET_TYPE)
 259                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 260         endif()
 261         if(NOT DEFINED PROJECT_ICON)
 262                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 263                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 264                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 265                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 266                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 267                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 268                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 269                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 270                 else()
 271                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-default.png)
 272                 endif()
 273         endif()
 274
 275         if(NOT WIDGET_ENTRY_POINT)
 276                 set(WIDGET_ENTRY_POINT lib)
 277         endif()
 278
 279         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 280                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 281                 COMMAND cp ${TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 282
 283         )
 284         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 285
 286         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 287         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 288         if(${PROJECT_CONF_FILES})
 289                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 290         endif(${PROJECT_CONF_FILES})
 291
 292         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 293                 DEPENDS ${PROJECT_TARGETS}
 294                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 295         )
 296
 297         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 298         add_dependencies(widget populate packaging_wgt)
 299         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 300
 301         if(NOT RSYNC_TARGET)
 302                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 303                 add_custom_target(widget-target-install
 304                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 305                         COMMAND exit -1
 306                 )
 307         else()
 308         configure_files_in_dir(${TEMPLATE_DIR})
 309         add_custom_target(widget-target-install
 310         DEPENDS widget
 311         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 312         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 313         )
 314 endif()
 315
 316         if(PACKAGE_MESSAGE)
 317         add_custom_command(TARGET widget
 318                 POST_BUILD
 319                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 320         endif()
 321 endmacro(wgt_package_build)
 322
 323 macro(rpm_package_build)
 324         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 325                 DEPENDS ${PROJECT_TARGETS}
 326                                 archive
 327                                 packaging
 328                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 329         )
 330
 331         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 332         add_dependencies(rpm populate packaging)
 333
 334         if(PACKAGE_MESSAGE)
 335         add_custom_command(TARGET rpm
 336                 POST_BUILD
 337                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 338         endif()
 339 endmacro(rpm_package_build)
 340
 341 macro(deb_package_build)
 342 #TODO
 343 endmacro(deb_package_build)
 344
 345 macro(project_package_build)
 346         if(EXISTS ${TEMPLATE_DIR})
 347                 rpm_package_build()
 348         endif()
 349
 350         if(EXISTS ${TEMPLATE_DIR})
 351                 wgt_package_build()
 352         endif()
 353
 354         if(EXISTS ${TEMPLATE_DIR})
 355                 deb_package_build()
 356         endif()
 357 endmacro(project_package_build)
 358
 359 macro(project_subdirs_add)
 360         set (ARGSLIST ${ARGN})
 361         list(LENGTH ARGSLIST ARGSNUM)
 362         if(${ARGSNUM} GREATER 0)
 363                 file(GLOB filelist "${ARGV0}")
 364         else()
 365         file(GLOB filelist "*")
 366         endif()
 367
 368         foreach(filename ${filelist})
 369                 if(EXISTS "${filename}/CMakeLists.txt")
 370                         add_subdirectory(${filename})
 371                 endif(EXISTS "${filename}/CMakeLists.txt")
 372         endforeach()
 373 endmacro(project_subdirs_add)
 374
 375 # Print developer helper message when build is done
 376 # -------------------------------------------------------
 377 macro(project_closing_msg)
 378         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 379         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 380         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 381                 add_custom_target(${PROJECT_NAME}_build_done ALL
 382                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 383                 )
 384                  add_dependencies(${PROJECT_NAME}_build_done
 385                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 386         endif()
 387 endmacro()