cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # CMake 3.6 imported macros to simulate list(FILTER ...) subcommand
  26 # -----------------------
  27 MACRO(PARSE_ARGUMENTS prefix arg_names option_names)
  28 SET(DEFAULT_ARGS)
  29 FOREACH(arg_name ${arg_names})
  30   SET(${prefix}_${arg_name})
  31 ENDFOREACH(arg_name)
  32 FOREACH(option ${option_names})
  33   SET(${prefix}_${option} FALSE)
  34 ENDFOREACH(option)
  35
  36 SET(current_arg_name DEFAULT_ARGS)
  37 SET(current_arg_list)
  38 FOREACH(arg ${ARGN})
  39   LIST_CONTAINS(is_arg_name ${arg} ${arg_names})
  40   IF (is_arg_name)
  41         SET(${prefix}_${current_arg_name} ${current_arg_list})
  42         SET(current_arg_name ${arg})
  43         SET(current_arg_list)
  44   ELSE (is_arg_name)
  45         LIST_CONTAINS(is_option ${arg} ${option_names})
  46         IF (is_option)
  47   SET(${prefix}_${arg} TRUE)
  48         ELSE (is_option)
  49   SET(current_arg_list ${current_arg_list} ${arg})
  50         ENDIF (is_option)
  51   ENDIF (is_arg_name)
  52 ENDFOREACH(arg)
  53 SET(${prefix}_${current_arg_name} ${current_arg_list})
  54 ENDMACRO(PARSE_ARGUMENTS)
  55
  56 MACRO(LIST_CONTAINS var value)
  57 SET(${var})
  58 FOREACH (value2 ${ARGN})
  59   IF (${value} STREQUAL ${value2})
  60         SET(${var} TRUE)
  61   ENDIF (${value} STREQUAL ${value2})
  62 ENDFOREACH (value2)
  63 ENDMACRO(LIST_CONTAINS)
  64
  65 MACRO(LIST_FILTER)
  66 PARSE_ARGUMENTS(LIST_FILTER "OUTPUT_VARIABLE" "" ${ARGV})
  67 # Check arguments.
  68 LIST(LENGTH LIST_FILTER_DEFAULT_ARGS LIST_FILTER_default_length)
  69 IF(${LIST_FILTER_default_length} EQUAL 0)
  70   MESSAGE(FATAL_ERROR "LIST_FILTER: missing list variable.")
  71 ENDIF(${LIST_FILTER_default_length} EQUAL 0)
  72 IF(${LIST_FILTER_default_length} EQUAL 1)
  73   MESSAGE(FATAL_ERROR "LIST_FILTER: missing regular expression variable.")
  74 ENDIF(${LIST_FILTER_default_length} EQUAL 1)
  75 # Reset output variable
  76 IF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  77   SET(LIST_FILTER_OUTPUT_VARIABLE "LIST_FILTER_internal_output")
  78 ENDIF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  79 SET(${LIST_FILTER_OUTPUT_VARIABLE})
  80 # Extract input list from arguments
  81 LIST(GET LIST_FILTER_DEFAULT_ARGS 0 LIST_FILTER_input_list)
  82 LIST(REMOVE_AT LIST_FILTER_DEFAULT_ARGS 0)
  83 FOREACH(LIST_FILTER_item ${${LIST_FILTER_input_list}})
  84   FOREACH(LIST_FILTER_regexp_var ${LIST_FILTER_DEFAULT_ARGS})
  85         FOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  86           IF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  87                 LIST(APPEND ${LIST_FILTER_OUTPUT_VARIABLE} ${LIST_FILTER_item})
  88           ENDIF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  89         ENDFOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  90   ENDFOREACH(LIST_FILTER_regexp_var)
  91 ENDFOREACH(LIST_FILTER_item)
  92 # If OUTPUT_VARIABLE is not specified, overwrite the input list.
  93 IF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  94   SET(${LIST_FILTER_input_list} ${${LIST_FILTER_OUTPUT_VARIABLE}})
  95 ENDIF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  96 ENDMACRO(LIST_FILTER)
  97
  98 # Generic useful macro
  99 # -----------------------
 100 macro(PROJECT_TARGET_ADD TARGET_NAME)
 101         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
 102         set(TARGET_NAME ${TARGET_NAME})
 103 endmacro(PROJECT_TARGET_ADD)
 104
 105 macro(PROJECT_PKGDEP_ADD PKG_NAME)
 106         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
 107 endmacro(PROJECT_PKGDEP_ADD)
 108
 109 macro(defstr name value)
 110         add_definitions(-D${name}=${value})
 111 endmacro(defstr)
 112
 113 macro(configure_files_in_dir dir)
 114         file(GLOB filelist "${dir}/*in")
 115         foreach(file ${filelist})
 116                 get_filename_component(filename ${file} NAME)
 117                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
 118                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
 119                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
 120                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
 121         endforeach()
 122 endmacro(configure_files_in_dir)
 123
 124 macro(add_required_module PKG_CONFIG)
 125         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 126         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 127
 128         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 129         list(APPEND link_libraries ${${XPREFIX}_LDFLAGS})
 130         add_compile_options (${${XPREFIX}_CFLAGS})
 131 endmacro(add_required_module)
 132
 133 # Create custom target dedicated for HTML5 and DATA AGL target type
 134 macro(add_input_files INPUT_FILES)
 135         if(NOT DEFINED XML_FILES)
 136                 set(XML_LIST ${INPUT_FILES})
 137                 list_filter(XML_LIST "xml$")
 138         endif()
 139         if(NOT DEFINED LUA_LIST)
 140                 set(LUA_LIST ${INPUT_FILES})
 141                 list_filter(LUA_LIST "lua$")
 142         endif()
 143         if(NOT DEFINED JSON_FILES)
 144                 set(JSON_LIST ${INPUT_FILES})
 145                 list_filter(JSON_LIST "json$")
 146         endif()
 147
 148         # These are v3.6 subcommand. Not used as default for now as
 149         # many dev use Ubuntu 16.04 which have only 3.5 version
 150         #list(FILTER XML_LIST INCLUDE REGEX "xml$")
 151         #list(FILTER LUA_LIST INCLUDE REGEX "lua$")
 152         #list(FILTER JSON_LIST INCLUDE REGEX "json$")
 153
 154         add_custom_target(${TARGET_NAME}
 155         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 156         )
 157
 158         foreach(file ${XML_LIST})
 159                 add_custom_command(TARGET ${TARGET_NAME}
 160                         PRE_BUILD
 161                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 162                         COMMAND ${XML_CHECKER} ${file}
 163                 )
 164         endforeach()
 165         foreach(file ${LUA_LIST})
 166         add_custom_command(TARGET ${TARGET_NAME}
 167                 PRE_BUILD
 168                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 169                 COMMAND ${LUA_CHECKER} ${file}
 170         )
 171         endforeach()
 172         foreach(file ${JSON_LIST})
 173         add_custom_command(TARGET ${TARGET_NAME}
 174                 PRE_BUILD
 175                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 176                 COMMAND cat ${file} | ${JSON_CHECKER}
 177         )
 178         endforeach()
 179
 180         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 181         DEPENDS ${INPUT_FILES}
 182         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 183         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 184         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 185         )
 186 endmacro()
 187
 188 # Set the name of the OPENAPI definition JSON file for binding v2
 189 macro(set_openapi_filename openapi_filename)
 190         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
 191 endmacro()
 192
 193 # Pre-packaging
 194 macro(project_targets_populate)
 195         # Default Widget default directory
 196         set(BINDIR bin)
 197         set(ETCDIR etc)
 198         set(LIBDIR lib)
 199         set(HTTPDIR htdocs)
 200         set(DATADIR data)
 201         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/${BINDIR})
 202         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/${ETCDIR})
 203         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/${LIBDIR})
 204         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/${HTTPDIR})
 205         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/${DATADIR})
 206
 207         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 208                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 209         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 210
 211         INSTALL(CODE "execute_process(COMMAND make populate)")
 212         INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 213                 DESTINATION ${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME}
 214         )
 215
 216         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 217         foreach(TARGET ${PROJECT_TARGETS})
 218         get_target_property(T ${TARGET} LABELS)
 219         if(T)
 220                 # Declaration of a custom command that will populate widget tree with the target
 221                 set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 222
 223                 get_target_property(P ${TARGET} PREFIX)
 224                 get_target_property(BD ${TARGET} BINARY_DIR)
 225                 get_target_property(SD ${TARGET} SOURCE_DIR)
 226                 get_target_property(OUT ${TARGET} OUTPUT_NAME)
 227
 228                 if(P MATCHES "NOTFOUND$")
 229                         if (${T} STREQUAL "BINDING")
 230                                 set(P "lib")
 231                         else()
 232                                 set(P "")
 233                         endif()
 234                 endif()
 235
 236                 if(${T} STREQUAL "BINDING")
 237                         list(APPEND BINDINGS_LIST "${P}${OUT}")
 238                         add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 239                                 DEPENDS ${BD}/${P}${OUT}.so
 240                                 COMMAND mkdir -p ${PACKAGE_LIBDIR}
 241                                 COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 242                         )
 243                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 244                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 245                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 246                 elseif(${T} STREQUAL "BINDINGV2")
 247                         if (OPENAPI_DEF)
 248                                 add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 249                                         DEPENDS ${SD}/${OPENAPI_DEF}.json
 250                                         COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 251                                 )
 252                                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 253                                         COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 254                                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 255                         else()
 256                                 add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 257                                         DEPENDS ${SD}/${OUT}-apidef.json
 258                                         COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 259                                 )
 260                                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 261                                         COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 262                                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 263                         endif()
 264
 265                         add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 266                                         DEPENDS ${BD}/${P}${OUT}.so
 267                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 268                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 269                                 )
 270                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 271                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 272                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 273                 elseif(${T} STREQUAL "EXECUTABLE")
 274                         add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
 275                                 DEPENDS ${BD}/${P}${OUT}
 276                                 COMMAND mkdir -p ${PACKAGE_BINDIR}
 277                                 COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 278                         )
 279                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${OUT})
 280                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 281                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 282                 elseif(${T} STREQUAL "HTDOCS")
 283                         add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 284                                 DEPENDS ${BD}/${P}${OUT}
 285                                 COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 286                                 COMMAND touch ${PACKAGE_HTTPDIR}
 287                                 COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 288                         )
 289                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 290                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 291                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 292                 elseif(${T} STREQUAL "DATA")
 293                         # Generate list of output files instead of just one output directory
 294                         get_target_property(SF ${TARGET} SOURCES)
 295                         foreach(file ${SF})
 296                                 get_filename_component(JUST_FILENAME ${file} NAME)
 297                                 list(APPEND OUTPUT_FILES ${PACKAGE_DATADIR}/${JUST_FILENAME})
 298                         endforeach()
 299                         add_custom_target(${POPULE_PACKAGE_TARGET})
 300                         add_custom_command(TARGET ${POPULE_PACKAGE_TARGET}
 301                                 POST_BUILD
 302                                 COMMAND mkdir -p ${PACKAGE_DATADIR}
 303                                 COMMAND touch ${PACKAGE_DATADIR}
 304                                 COMMAND cp -r ${BD}/${TARGET} ${PACKAGE_DATADIR}
 305                         )
 306                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 307                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 308                 endif(${T} STREQUAL "BINDING")
 309                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 310                         MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 311                 endif()
 312         endforeach()
 313 endmacro(project_targets_populate)
 314
 315 macro(remote_targets_populate)
 316         if (DEFINED ENV{RSYNC_TARGET})
 317                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 318         endif()
 319         if (DEFINED ENV{RSYNC_PREFIX})
 320                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 321         endif()
 322
 323         set(
 324                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 325                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 326         )
 327
 328         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 329                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 330                 add_custom_target(remote-target-populate
 331                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 332                         COMMAND exit -1
 333                 )
 334         else()
 335                 set(BINDINGS_REGEX "not_set")
 336                 if(DEFINED BINDINGS_LIST)
 337                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 338                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 339                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 340                                 string(APPEND BINDINGS_REGEX ".so")
 341                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 342                                 foreach(B IN LISTS BINDINGS_LIST)
 343                                         STRING(APPEND BINDINGS_STR "${B}|")
 344                                 endforeach()
 345                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 346                         endif()
 347                 endif()
 348
 349                 configure_files_in_dir(${TEMPLATE_DIR})
 350                 configure_files_in_dir(${TEMPLATE_DIR})
 351
 352                 add_custom_target(remote-target-populate
 353                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 354                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 355                         COMMENT "${REMOTE_LAUNCH}"
 356                 )
 357                 add_dependencies(remote-target-populate populate)
 358         endif()
 359 endmacro(remote_targets_populate)
 360
 361 macro(wgt_package_build)
 362         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 363                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 364         endif()
 365         if(NOT WIDGET_TYPE)
 366                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 367         endif()
 368         if(NOT DEFINED PROJECT_ICON)
 369                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 370                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 371                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 372                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 373                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 374                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 375                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 376                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 377                 endif()
 378         elseif(EXISTS "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 379                 set(ICON_PATH "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 380         elseif(EXISTS "${WIDGET_ICON}")
 381                 set(ICON_PATH "${WIDGET_ICON}")
 382         else()
 383                 set(ICON_PATH ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/wgt/icon-default.png)
 384         endif()
 385
 386         if(NOT WIDGET_ENTRY_POINT)
 387                 set(WIDGET_ENTRY_POINT lib)
 388         endif()
 389
 390         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 391                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 392                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 393
 394         )
 395         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 396
 397         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 398         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 399         if(${PROJECT_CONF_FILES})
 400                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 401         endif(${PROJECT_CONF_FILES})
 402
 403         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 404                 DEPENDS ${PROJECT_TARGETS}
 405                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 406         )
 407
 408         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 409         add_dependencies(widget populate packaging_wgt)
 410         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 411
 412         if(NOT RSYNC_TARGET)
 413                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 414                 add_custom_target(widget-target-install
 415                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 416                         COMMAND exit -1
 417                 )
 418         else()
 419         configure_files_in_dir(${TEMPLATE_DIR})
 420         add_custom_target(widget-target-install
 421         DEPENDS widget
 422         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 423         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 424         )
 425 endif()
 426
 427         if(PACKAGE_MESSAGE)
 428         add_custom_command(TARGET widget
 429                 POST_BUILD
 430                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 431         endif()
 432 endmacro(wgt_package_build)
 433
 434 macro(rpm_package_build)
 435         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 436                 DEPENDS ${PROJECT_TARGETS}
 437                                 archive
 438                                 packaging
 439                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 440         )
 441
 442         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 443         add_dependencies(rpm populate packaging)
 444
 445         if(PACKAGE_MESSAGE)
 446         add_custom_command(TARGET rpm
 447                 POST_BUILD
 448                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 449         endif()
 450 endmacro(rpm_package_build)
 451
 452 macro(deb_package_build)
 453 #TODO
 454 endmacro(deb_package_build)
 455
 456 macro(project_package_build)
 457         if(EXISTS ${TEMPLATE_DIR})
 458                 rpm_package_build()
 459         endif()
 460
 461         if(EXISTS ${TEMPLATE_DIR})
 462                 wgt_package_build()
 463         endif()
 464
 465         if(EXISTS ${TEMPLATE_DIR})
 466                 deb_package_build()
 467         endif()
 468 endmacro(project_package_build)
 469
 470 macro(project_subdirs_add)
 471         set (ARGSLIST ${ARGN})
 472         list(LENGTH ARGSLIST ARGSNUM)
 473         if(${ARGSNUM} GREATER 0)
 474                 file(GLOB filelist "${ARGV0}")
 475         else()
 476         file(GLOB filelist "*")
 477         endif()
 478
 479         foreach(filename ${filelist})
 480                 if(EXISTS "${filename}/CMakeLists.txt")
 481                         add_subdirectory(${filename})
 482                 endif(EXISTS "${filename}/CMakeLists.txt")
 483         endforeach()
 484 endmacro(project_subdirs_add)
 485
 486 # Print developer helper message when build is done
 487 # -------------------------------------------------------
 488 macro(project_closing_msg)
 489         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 490         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 491         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 492                 add_custom_target(${PROJECT_NAME}_build_done ALL
 493                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 494                 )
 495                  add_dependencies(${PROJECT_NAME}_build_done
 496                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 497         endif()
 498 endmacro()