cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # CMake 3.6 imported macros to simulate list(FILTER ...) subcommand
  26 # -----------------------
  27 MACRO(PARSE_ARGUMENTS prefix arg_names option_names)
  28 SET(DEFAULT_ARGS)
  29 FOREACH(arg_name ${arg_names})
  30   SET(${prefix}_${arg_name})
  31 ENDFOREACH(arg_name)
  32 FOREACH(option ${option_names})
  33   SET(${prefix}_${option} FALSE)
  34 ENDFOREACH(option)
  35
  36 SET(current_arg_name DEFAULT_ARGS)
  37 SET(current_arg_list)
  38 FOREACH(arg ${ARGN})
  39   LIST_CONTAINS(is_arg_name ${arg} ${arg_names})
  40   IF (is_arg_name)
  41         SET(${prefix}_${current_arg_name} ${current_arg_list})
  42         SET(current_arg_name ${arg})
  43         SET(current_arg_list)
  44   ELSE (is_arg_name)
  45         LIST_CONTAINS(is_option ${arg} ${option_names})
  46         IF (is_option)
  47   SET(${prefix}_${arg} TRUE)
  48         ELSE (is_option)
  49   SET(current_arg_list ${current_arg_list} ${arg})
  50         ENDIF (is_option)
  51   ENDIF (is_arg_name)
  52 ENDFOREACH(arg)
  53 SET(${prefix}_${current_arg_name} ${current_arg_list})
  54 ENDMACRO(PARSE_ARGUMENTS)
  55
  56 MACRO(LIST_CONTAINS var value)
  57 SET(${var})
  58 FOREACH (value2 ${ARGN})
  59   IF (${value} STREQUAL ${value2})
  60         SET(${var} TRUE)
  61   ENDIF (${value} STREQUAL ${value2})
  62 ENDFOREACH (value2)
  63 ENDMACRO(LIST_CONTAINS)
  64
  65 MACRO(LIST_FILTER)
  66 PARSE_ARGUMENTS(LIST_FILTER "OUTPUT_VARIABLE" "" ${ARGV})
  67 # Check arguments.
  68 LIST(LENGTH LIST_FILTER_DEFAULT_ARGS LIST_FILTER_default_length)
  69 IF(${LIST_FILTER_default_length} EQUAL 0)
  70   MESSAGE(FATAL_ERROR "LIST_FILTER: missing list variable.")
  71 ENDIF(${LIST_FILTER_default_length} EQUAL 0)
  72 IF(${LIST_FILTER_default_length} EQUAL 1)
  73   MESSAGE(FATAL_ERROR "LIST_FILTER: missing regular expression variable.")
  74 ENDIF(${LIST_FILTER_default_length} EQUAL 1)
  75 # Reset output variable
  76 IF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  77   SET(LIST_FILTER_OUTPUT_VARIABLE "LIST_FILTER_internal_output")
  78 ENDIF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  79 SET(${LIST_FILTER_OUTPUT_VARIABLE})
  80 # Extract input list from arguments
  81 LIST(GET LIST_FILTER_DEFAULT_ARGS 0 LIST_FILTER_input_list)
  82 LIST(REMOVE_AT LIST_FILTER_DEFAULT_ARGS 0)
  83 FOREACH(LIST_FILTER_item ${${LIST_FILTER_input_list}})
  84   FOREACH(LIST_FILTER_regexp_var ${LIST_FILTER_DEFAULT_ARGS})
  85         FOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  86           IF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  87                 LIST(APPEND ${LIST_FILTER_OUTPUT_VARIABLE} ${LIST_FILTER_item})
  88           ENDIF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  89         ENDFOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  90   ENDFOREACH(LIST_FILTER_regexp_var)
  91 ENDFOREACH(LIST_FILTER_item)
  92 # If OUTPUT_VARIABLE is not specified, overwrite the input list.
  93 IF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  94   SET(${LIST_FILTER_input_list} ${${LIST_FILTER_OUTPUT_VARIABLE}})
  95 ENDIF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  96 ENDMACRO(LIST_FILTER)
  97
  98 # Generic useful macro
  99 # -----------------------
 100 macro(PROJECT_TARGET_ADD TARGET_NAME)
 101         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
 102         set(TARGET_NAME ${TARGET_NAME})
 103 endmacro(PROJECT_TARGET_ADD)
 104
 105 macro(PROJECT_PKGDEP_ADD PKG_NAME)
 106         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
 107 endmacro(PROJECT_PKGDEP_ADD)
 108
 109 macro(defstr name value)
 110         add_definitions(-D${name}=${value})
 111 endmacro(defstr)
 112
 113 macro(configure_files_in_dir dir)
 114         file(GLOB filelist "${dir}/*in")
 115         foreach(file ${filelist})
 116                 get_filename_component(filename ${file} NAME)
 117                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
 118                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
 119                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
 120                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
 121         endforeach()
 122 endmacro(configure_files_in_dir)
 123
 124 # Create custom target dedicated for HTML5 and DATA AGL target type
 125 macro(add_input_files INPUT_FILES)
 126         if(NOT DEFINED XML_FILES)
 127                 set(ext_reg "xml$")
 128                 set(XML_LIST ${INPUT_FILES})
 129                 list_filter(XML_LIST ext_reg)
 130                 execute_process(
 131                         COMMAND which ${XML_CHECKER}
 132                         RESULT_VARIABLE XML_CHECKER_PRESENT
 133                         OUTPUT_QUIET ERROR_QUIET
 134                 )
 135         endif()
 136         if(NOT DEFINED LUA_LIST)
 137                 set(ext_reg "lua$")
 138                 set(LUA_LIST ${INPUT_FILES})
 139                 list_filter(LUA_LIST ext_reg)
 140                 execute_process(
 141                         COMMAND which ${LUA_CHECKER}
 142                         RESULT_VARIABLE LUA_CHECKER_PRESENT
 143                         OUTPUT_QUIET ERROR_QUIET
 144                 )
 145         endif()
 146         if(NOT DEFINED JSON_FILES)
 147                 set(ext_reg "json$")
 148                 set(JSON_LIST ${INPUT_FILES})
 149                 list_filter(JSON_LIST ext_reg)
 150                 execute_process(
 151                         COMMAND which ${JSON_CHECKER}
 152                         RESULT_VARIABLE JSON_CHECKER_PRESENT
 153                         OUTPUT_QUIET ERROR_QUIET
 154                 )
 155         endif()
 156
 157         # These are v3.6 subcommand. Not used as default for now as
 158         # many dev use Ubuntu 16.04 which have only 3.5 version
 159         #list(FILTER XML_LIST INCLUDE REGEX "xml$")
 160         #list(FILTER LUA_LIST INCLUDE REGEX "lua$")
 161         #list(FILTER JSON_LIST INCLUDE REGEX "json$")
 162
 163         add_custom_target(${TARGET_NAME} ALL
 164         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 165         )
 166
 167         if(XML_CHECKER_PRESENT EQUAL 0)
 168                 foreach(file ${XML_LIST})
 169                         add_custom_command(TARGET ${TARGET_NAME}
 170                                 PRE_BUILD
 171                                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 172                                 COMMAND ${XML_CHECKER} ${file}
 173                         )
 174                 endforeach()
 175         elseif(XML_LIST)
 176         add_custom_command(TARGET ${TARGET_NAME}
 177         PRE_BUILD
 178         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 179         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: XML_CHECKER not found. Not verification made on files !")
 180         endif()
 181         if(LUA_CHECKER_PRESENT EQUAL 0)
 182                 foreach(file ${LUA_LIST})
 183                 add_custom_command(TARGET ${TARGET_NAME}
 184                         PRE_BUILD
 185                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 186                         COMMAND ${LUA_CHECKER} ${file}
 187                 )
 188                 endforeach()
 189         elseif(LUA_LIST)
 190                 add_custom_command(TARGET ${TARGET_NAME}
 191                         PRE_BUILD
 192                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 193                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: LUA_CHECKER not found. Not verification made on files !")
 194         endif()
 195         if(JSON_CHECKER_PRESENT EQUAL 0)
 196                 foreach(file ${JSON_LIST})
 197                 add_custom_command(TARGET ${TARGET_NAME}
 198                         PRE_BUILD
 199                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 200                         COMMAND ${JSON_CHECKER} ${file}
 201                 )
 202                 endforeach()
 203         elseif(JSON_LIST)
 204         add_custom_command(TARGET ${TARGET_NAME}
 205         PRE_BUILD
 206         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 207         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: JSON_CHECKER not found. Not verification made on files !")
 208         endif()
 209
 210         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 211         DEPENDS ${INPUT_FILES}
 212         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 213         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 214         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 215         )
 216 endmacro()
 217
 218 # Set the name of the OPENAPI definition JSON file for binding v2
 219 macro(set_openapi_filename openapi_filename)
 220         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
 221 endmacro()
 222
 223 # Pre-packaging
 224 macro(project_targets_populate)
 225         # Default Widget default directory
 226         set(BINDIR bin)
 227         set(ETCDIR etc)
 228         set(LIBDIR lib)
 229         set(HTTPDIR htdocs)
 230         set(DATADIR data)
 231         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/${BINDIR})
 232         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/${ETCDIR})
 233         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/${LIBDIR})
 234         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/${HTTPDIR})
 235         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/${DATADIR})
 236
 237         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 238                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 239         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 240
 241         # Dirty trick to define a default INSTALL command for app-templates handled
 242         # targets
 243         INSTALL(CODE "execute_process(COMMAND make populate)")
 244         if(NO_DEDICATED_INSTALL_DIR)
 245                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 246                         DESTINATION ${CMAKE_INSTALL_PREFIX}
 247                 )
 248         else()
 249                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 250                         DESTINATION ${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME}
 251                 )
 252         endif()
 253
 254         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 255         foreach(TARGET ${PROJECT_TARGETS})
 256         get_target_property(T ${TARGET} LABELS)
 257         if(T)
 258                 # Declaration of a custom command that will populate widget tree with the target
 259                 set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 260
 261                 get_target_property(P ${TARGET} PREFIX)
 262                 get_target_property(S ${TARGET} SUFFIX)
 263                 get_target_property(BD ${TARGET} BINARY_DIR)
 264                 get_target_property(SD ${TARGET} SOURCE_DIR)
 265                 get_target_property(OUT ${TARGET} OUTPUT_NAME)
 266
 267                 if(P MATCHES "NOTFOUND$")
 268                         if (${T} STREQUAL "BINDING")
 269                                 set(P "lib")
 270                         else()
 271                                 set(P "")
 272                         endif()
 273                 endif()
 274
 275                 if(${T} STREQUAL "BINDING" OR ${T} STREQUAL "PLUGIN")
 276                         if(NOT S)
 277                                 list(APPEND BINDINGS_LIST "${P}${OUT}")
 278                                 set(S ".so")
 279                         else()
 280                                 set(PACKAGE_LIBDIR_BCK "${PACKAGE_LIBDIR}")
 281                                 set(PACKAGE_LIBDIR "${PACKAGE_LIBDIR}/plugins")
 282                         endif()
 283
 284                         add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}${S}
 285                                 DEPENDS ${BD}/${P}${OUT}${S}
 286                                 COMMAND mkdir -p ${PACKAGE_LIBDIR}
 287                                 COMMAND cp ${BD}/${P}${OUT}${S} ${PACKAGE_LIBDIR}
 288                         )
 289                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}${S})
 290                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 291                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 292                         set(PACKAGE_LIBDIR ${PACKAGE_LIBDIR_BCK})
 293                 elseif(${T} STREQUAL "BINDINGV2")
 294                         if (OPENAPI_DEF)
 295                                 add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 296                                         DEPENDS ${SD}/${OPENAPI_DEF}.json
 297                                         COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 298                                 )
 299                                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 300                                         COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 301                                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 302                         else()
 303                                 add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 304                                         DEPENDS ${SD}/${OUT}-apidef.json
 305                                         COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 306                                 )
 307                                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 308                                         COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 309                                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 310                         endif()
 311
 312                         add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 313                                         DEPENDS ${BD}/${P}${OUT}.so
 314                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 315                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 316                                 )
 317                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 318                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 319                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 320                 elseif(${T} STREQUAL "EXECUTABLE")
 321                         add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
 322                                 DEPENDS ${BD}/${P}${OUT}
 323                                 COMMAND mkdir -p ${PACKAGE_BINDIR}
 324                                 COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 325                         )
 326                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${OUT})
 327                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 328                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 329                 elseif(${T} STREQUAL "HTDOCS")
 330                         add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 331                                 DEPENDS ${BD}/${P}${OUT}
 332                                 COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 333                                 COMMAND touch ${PACKAGE_HTTPDIR}
 334                                 COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 335                         )
 336                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 337                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 338                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 339                 elseif(${T} STREQUAL "DATA")
 340                         # Generate list of output files instead of just one output directory
 341                         get_target_property(SF ${TARGET} SOURCES)
 342                         foreach(file ${SF})
 343                                 get_filename_component(JUST_FILENAME ${file} NAME)
 344                                 list(APPEND OUTPUT_FILES ${PACKAGE_DATADIR}/${JUST_FILENAME})
 345                         endforeach()
 346                         add_custom_target(${POPULE_PACKAGE_TARGET})
 347                         add_custom_command(TARGET ${POPULE_PACKAGE_TARGET}
 348                                 POST_BUILD
 349                                 COMMAND mkdir -p ${PACKAGE_DATADIR}
 350                                 COMMAND touch ${PACKAGE_DATADIR}
 351                                 COMMAND cp -r ${BD}/${TARGET} ${PACKAGE_DATADIR}
 352                         )
 353                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 354                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 355                         elseif(${T} STREQUAL "BINDING-CONFIG")
 356                         # Generate list of output files instead of just one output directory
 357                         get_target_property(SF ${TARGET} SOURCES)
 358                         foreach(file ${SF})
 359                                 get_filename_component(JUST_FILENAME ${file} NAME)
 360                                 list(APPEND OUTPUT_FILES ${PACKAGE_ETCDIR}/${JUST_FILENAME})
 361                         endforeach()
 362                         add_custom_target(${POPULE_PACKAGE_TARGET})
 363                         add_custom_command(TARGET ${POPULE_PACKAGE_TARGET}
 364                                 POST_BUILD
 365                                 COMMAND mkdir -p ${PACKAGE_ETCDIR}
 366                                 COMMAND touch ${PACKAGE_ETCDIR}
 367                                 COMMAND cp -r ${BD}/${TARGET}/* ${PACKAGE_ETCDIR}
 368                         )
 369                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 370                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 371                 endif()
 372                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 373                         MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 374                 endif()
 375         endforeach()
 376 endmacro(project_targets_populate)
 377
 378 macro(remote_targets_populate)
 379         if (DEFINED ENV{RSYNC_TARGET})
 380                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 381         endif()
 382         if (DEFINED ENV{RSYNC_PREFIX})
 383                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 384         endif()
 385
 386         set(
 387                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 388                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 389         )
 390
 391         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 392                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 393                 add_custom_target(remote-target-populate
 394                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 395                         COMMAND exit -1
 396                 )
 397         else()
 398                 set(BINDINGS_REGEX "not_set")
 399                 if(DEFINED BINDINGS_LIST)
 400                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 401                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 402                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 403                                 string(APPEND BINDINGS_REGEX ".so")
 404                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 405                                 foreach(B IN LISTS BINDINGS_LIST)
 406                                         STRING(APPEND BINDINGS_STR "${B}|")
 407                                 endforeach()
 408                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 409                         endif()
 410                 endif()
 411
 412                 configure_files_in_dir(${TEMPLATE_DIR})
 413                 configure_files_in_dir(${TEMPLATE_DIR})
 414
 415                 add_custom_target(remote-target-populate
 416                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 417                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 418                 )
 419
 420                 add_custom_command(TARGET remote-target-populate
 421                 POST_BUILD
 422                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --green --bold ${REMOTE_LAUNCH}
 423                 )
 424
 425                 add_dependencies(remote-target-populate populate)
 426         endif()
 427 endmacro(remote_targets_populate)
 428
 429 macro(wgt_package_build)
 430         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 431                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 432         endif()
 433         if(NOT WIDGET_TYPE)
 434                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 435         endif()
 436         if(NOT DEFINED PROJECT_ICON)
 437                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 438                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 439                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 440                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 441                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 442                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 443                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 444                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 445                 endif()
 446         elseif(EXISTS "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 447                 set(ICON_PATH "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 448         elseif(EXISTS "${WIDGET_ICON}")
 449                 set(ICON_PATH "${WIDGET_ICON}")
 450         else()
 451                 set(ICON_PATH ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/wgt/icon-default.png)
 452         endif()
 453
 454         if(NOT WIDGET_ENTRY_POINT)
 455                 set(WIDGET_ENTRY_POINT lib)
 456         endif()
 457
 458         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 459                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 460                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 461
 462         )
 463         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 464
 465         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 466         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 467         if(${PROJECT_CONF_FILES})
 468                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 469         endif(${PROJECT_CONF_FILES})
 470
 471         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 472                 DEPENDS ${PROJECT_TARGETS}
 473                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 474         )
 475
 476         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 477         add_dependencies(widget populate packaging_wgt)
 478         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 479
 480         if(NOT RSYNC_TARGET)
 481                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 482                 add_custom_target(widget-target-install
 483                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 484                         COMMAND exit -1
 485                 )
 486         else()
 487         configure_files_in_dir(${TEMPLATE_DIR})
 488         add_custom_target(widget-target-install
 489         DEPENDS widget
 490         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 491         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 492         )
 493 endif()
 494
 495         if(PACKAGE_MESSAGE)
 496         add_custom_command(TARGET widget
 497                 POST_BUILD
 498                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 499         endif()
 500 endmacro(wgt_package_build)
 501
 502 macro(rpm_package_build)
 503         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 504                 DEPENDS ${PROJECT_TARGETS}
 505                                 archive
 506                                 packaging
 507                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 508         )
 509
 510         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 511         add_dependencies(rpm populate packaging)
 512
 513         if(PACKAGE_MESSAGE)
 514         add_custom_command(TARGET rpm
 515                 POST_BUILD
 516                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 517         endif()
 518 endmacro(rpm_package_build)
 519
 520 macro(deb_package_build)
 521 #TODO
 522 endmacro(deb_package_build)
 523
 524 macro(project_package_build)
 525 #       if(EXISTS ${TEMPLATE_DIR})
 526 #               rpm_package_build()
 527 #       endif()
 528
 529         if(EXISTS ${TEMPLATE_DIR})
 530                 wgt_package_build()
 531         endif()
 532
 533 #       if(EXISTS ${TEMPLATE_DIR})
 534 #               deb_package_build()
 535 #       endif()
 536 endmacro(project_package_build)
 537
 538 macro(project_subdirs_add)
 539         set (ARGSLIST ${ARGN})
 540         list(LENGTH ARGSLIST ARGSNUM)
 541         if(${ARGSNUM} GREATER 0)
 542                 file(GLOB filelist "${ARGV0}")
 543         else()
 544         file(GLOB filelist "*")
 545         endif()
 546
 547         foreach(filename ${filelist})
 548                 if(EXISTS "${filename}/CMakeLists.txt")
 549                         add_subdirectory(${filename})
 550                 endif(EXISTS "${filename}/CMakeLists.txt")
 551         endforeach()
 552 endmacro(project_subdirs_add)
 553
 554 # Print developer helper message when build is done
 555 # -------------------------------------------------------
 556 macro(project_closing_msg)
 557         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 558         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 559         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 560                 add_custom_target(${PROJECT_NAME}_build_done ALL
 561                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 562                 )
 563                 add_dependencies(${PROJECT_NAME}_build_done
 564                         ${PROJECT_TARGETS} populate)
 565         endif()
 566 endmacro()