cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # CMake 3.6 imported macros to simulate list(FILTER ...) subcommand
  26 # -----------------------
  27 MACRO(PARSE_ARGUMENTS prefix arg_names option_names)
  28 SET(DEFAULT_ARGS)
  29 FOREACH(arg_name ${arg_names})
  30   SET(${prefix}_${arg_name})
  31 ENDFOREACH(arg_name)
  32 FOREACH(option ${option_names})
  33   SET(${prefix}_${option} FALSE)
  34 ENDFOREACH(option)
  35
  36 SET(current_arg_name DEFAULT_ARGS)
  37 SET(current_arg_list)
  38 FOREACH(arg ${ARGN})
  39   LIST_CONTAINS(is_arg_name ${arg} ${arg_names})
  40   IF (is_arg_name)
  41         SET(${prefix}_${current_arg_name} ${current_arg_list})
  42         SET(current_arg_name ${arg})
  43         SET(current_arg_list)
  44   ELSE (is_arg_name)
  45         LIST_CONTAINS(is_option ${arg} ${option_names})
  46         IF (is_option)
  47   SET(${prefix}_${arg} TRUE)
  48         ELSE (is_option)
  49   SET(current_arg_list ${current_arg_list} ${arg})
  50         ENDIF (is_option)
  51   ENDIF (is_arg_name)
  52 ENDFOREACH(arg)
  53 SET(${prefix}_${current_arg_name} ${current_arg_list})
  54 ENDMACRO(PARSE_ARGUMENTS)
  55
  56 MACRO(LIST_CONTAINS var value)
  57 SET(${var})
  58 FOREACH (value2 ${ARGN})
  59   IF (${value} STREQUAL ${value2})
  60         SET(${var} TRUE)
  61   ENDIF (${value} STREQUAL ${value2})
  62 ENDFOREACH (value2)
  63 ENDMACRO(LIST_CONTAINS)
  64
  65 MACRO(LIST_FILTER)
  66 PARSE_ARGUMENTS(LIST_FILTER "OUTPUT_VARIABLE" "" ${ARGV})
  67 # Check arguments.
  68 LIST(LENGTH LIST_FILTER_DEFAULT_ARGS LIST_FILTER_default_length)
  69 IF(${LIST_FILTER_default_length} EQUAL 0)
  70   MESSAGE(FATAL_ERROR "LIST_FILTER: missing list variable.")
  71 ENDIF(${LIST_FILTER_default_length} EQUAL 0)
  72 IF(${LIST_FILTER_default_length} EQUAL 1)
  73   MESSAGE(FATAL_ERROR "LIST_FILTER: missing regular expression variable.")
  74 ENDIF(${LIST_FILTER_default_length} EQUAL 1)
  75 # Reset output variable
  76 IF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  77   SET(LIST_FILTER_OUTPUT_VARIABLE "LIST_FILTER_internal_output")
  78 ENDIF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  79 SET(${LIST_FILTER_OUTPUT_VARIABLE})
  80 # Extract input list from arguments
  81 LIST(GET LIST_FILTER_DEFAULT_ARGS 0 LIST_FILTER_input_list)
  82 LIST(REMOVE_AT LIST_FILTER_DEFAULT_ARGS 0)
  83 FOREACH(LIST_FILTER_item ${${LIST_FILTER_input_list}})
  84   FOREACH(LIST_FILTER_regexp_var ${LIST_FILTER_DEFAULT_ARGS})
  85         FOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  86           IF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  87                 LIST(APPEND ${LIST_FILTER_OUTPUT_VARIABLE} ${LIST_FILTER_item})
  88           ENDIF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  89         ENDFOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  90   ENDFOREACH(LIST_FILTER_regexp_var)
  91 ENDFOREACH(LIST_FILTER_item)
  92 # If OUTPUT_VARIABLE is not specified, overwrite the input list.
  93 IF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  94   SET(${LIST_FILTER_input_list} ${${LIST_FILTER_OUTPUT_VARIABLE}})
  95 ENDIF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  96 ENDMACRO(LIST_FILTER)
  97
  98 # Generic useful macro
  99 # -----------------------
 100 macro(PROJECT_TARGET_ADD TARGET_NAME)
 101         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
 102         set(TARGET_NAME ${TARGET_NAME})
 103 endmacro(PROJECT_TARGET_ADD)
 104
 105 macro(PROJECT_PKGDEP_ADD PKG_NAME)
 106         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
 107 endmacro(PROJECT_PKGDEP_ADD)
 108
 109 macro(defstr name value)
 110         add_definitions(-D${name}=${value})
 111 endmacro(defstr)
 112
 113 macro(configure_files_in_dir dir)
 114         file(GLOB filelist "${dir}/*in")
 115         foreach(file ${filelist})
 116                 get_filename_component(filename ${file} NAME)
 117                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
 118                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
 119                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
 120                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
 121         endforeach()
 122 endmacro(configure_files_in_dir)
 123
 124 macro(add_required_module PKG_CONFIG)
 125         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
 126         PKG_CHECK_MODULES(${XPREFIX} REQUIRED ${PKG_CONFIG})
 127
 128         INCLUDE_DIRECTORIES(${${XPREFIX}_INCLUDE_DIRS})
 129         list(APPEND link_libraries ${${XPREFIX}_LDFLAGS})
 130         add_compile_options (${${XPREFIX}_CFLAGS})
 131 endmacro(add_required_module)
 132
 133 # Create custom target dedicated for HTML5 and DATA AGL target type
 134 macro(add_input_files INPUT_FILES)
 135         if(NOT DEFINED XML_FILES)
 136                 set(ext_reg "xml$")
 137                 set(XML_LIST ${INPUT_FILES})
 138                 list_filter(XML_LIST ext_reg)
 139         endif()
 140         if(NOT DEFINED LUA_LIST)
 141                 set(ext_reg "lua$")
 142                 set(LUA_LIST ${INPUT_FILES})
 143                 list_filter(LUA_LIST ext_reg)
 144         endif()
 145         if(NOT DEFINED JSON_FILES)
 146                 set(ext_reg "json$")
 147                 set(JSON_LIST ${INPUT_FILES})
 148                 list_filter(JSON_LIST ext_reg)
 149         endif()
 150
 151         # These are v3.6 subcommand. Not used as default for now as
 152         # many dev use Ubuntu 16.04 which have only 3.5 version
 153         #list(FILTER XML_LIST INCLUDE REGEX "xml$")
 154         #list(FILTER LUA_LIST INCLUDE REGEX "lua$")
 155         #list(FILTER JSON_LIST INCLUDE REGEX "json$")
 156
 157         add_custom_target(${TARGET_NAME}
 158         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 159         )
 160
 161         foreach(file ${XML_LIST})
 162                 add_custom_command(TARGET ${TARGET_NAME}
 163                         PRE_BUILD
 164                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 165                         COMMAND ${XML_CHECKER} ${file}
 166                 )
 167         endforeach()
 168         foreach(file ${LUA_LIST})
 169         add_custom_command(TARGET ${TARGET_NAME}
 170                 PRE_BUILD
 171                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 172                 COMMAND ${LUA_CHECKER} ${file}
 173         )
 174         endforeach()
 175         foreach(file ${JSON_LIST})
 176         add_custom_command(TARGET ${TARGET_NAME}
 177                 PRE_BUILD
 178                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 179                 COMMAND cat ${file} | ${JSON_CHECKER}
 180         )
 181         endforeach()
 182
 183         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 184         DEPENDS ${INPUT_FILES}
 185         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 186         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 187         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 188         )
 189 endmacro()
 190
 191 # Set the name of the OPENAPI definition JSON file for binding v2
 192 macro(set_openapi_filename openapi_filename)
 193         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
 194 endmacro()
 195
 196 # Pre-packaging
 197 macro(project_targets_populate)
 198         # Default Widget default directory
 199         set(BINDIR bin)
 200         set(ETCDIR etc)
 201         set(LIBDIR lib)
 202         set(HTTPDIR htdocs)
 203         set(DATADIR data)
 204         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/${BINDIR})
 205         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/${ETCDIR})
 206         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/${LIBDIR})
 207         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/${HTTPDIR})
 208         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/${DATADIR})
 209
 210         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 211                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 212         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 213
 214         INSTALL(CODE "execute_process(COMMAND make populate)")
 215         INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 216                 DESTINATION ${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME}
 217         )
 218
 219         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 220         foreach(TARGET ${PROJECT_TARGETS})
 221         get_target_property(T ${TARGET} LABELS)
 222         if(T)
 223                 # Declaration of a custom command that will populate widget tree with the target
 224                 set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 225
 226                 get_target_property(P ${TARGET} PREFIX)
 227                 get_target_property(BD ${TARGET} BINARY_DIR)
 228                 get_target_property(SD ${TARGET} SOURCE_DIR)
 229                 get_target_property(OUT ${TARGET} OUTPUT_NAME)
 230
 231                 if(P MATCHES "NOTFOUND$")
 232                         if (${T} STREQUAL "BINDING")
 233                                 set(P "lib")
 234                         else()
 235                                 set(P "")
 236                         endif()
 237                 endif()
 238
 239                 if(${T} STREQUAL "BINDING")
 240                         list(APPEND BINDINGS_LIST "${P}${OUT}")
 241                         add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 242                                 DEPENDS ${BD}/${P}${OUT}.so
 243                                 COMMAND mkdir -p ${PACKAGE_LIBDIR}
 244                                 COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 245                         )
 246                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 247                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 248                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 249                 elseif(${T} STREQUAL "BINDINGV2")
 250                         if (OPENAPI_DEF)
 251                                 add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 252                                         DEPENDS ${SD}/${OPENAPI_DEF}.json
 253                                         COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 254                                 )
 255                                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 256                                         COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 257                                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 258                         else()
 259                                 add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 260                                         DEPENDS ${SD}/${OUT}-apidef.json
 261                                         COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 262                                 )
 263                                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 264                                         COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 265                                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 266                         endif()
 267
 268                         add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 269                                         DEPENDS ${BD}/${P}${OUT}.so
 270                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 271                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 272                                 )
 273                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 274                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 275                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 276                 elseif(${T} STREQUAL "EXECUTABLE")
 277                         add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
 278                                 DEPENDS ${BD}/${P}${OUT}
 279                                 COMMAND mkdir -p ${PACKAGE_BINDIR}
 280                                 COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 281                         )
 282                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${OUT})
 283                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 284                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 285                 elseif(${T} STREQUAL "HTDOCS")
 286                         add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 287                                 DEPENDS ${BD}/${P}${OUT}
 288                                 COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 289                                 COMMAND touch ${PACKAGE_HTTPDIR}
 290                                 COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 291                         )
 292                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 293                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 294                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 295                 elseif(${T} STREQUAL "DATA")
 296                         # Generate list of output files instead of just one output directory
 297                         get_target_property(SF ${TARGET} SOURCES)
 298                         foreach(file ${SF})
 299                                 get_filename_component(JUST_FILENAME ${file} NAME)
 300                                 list(APPEND OUTPUT_FILES ${PACKAGE_DATADIR}/${JUST_FILENAME})
 301                         endforeach()
 302                         add_custom_target(${POPULE_PACKAGE_TARGET})
 303                         add_custom_command(TARGET ${POPULE_PACKAGE_TARGET}
 304                                 POST_BUILD
 305                                 COMMAND mkdir -p ${PACKAGE_DATADIR}
 306                                 COMMAND touch ${PACKAGE_DATADIR}
 307                                 COMMAND cp -r ${BD}/${TARGET} ${PACKAGE_DATADIR}
 308                         )
 309                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 310                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 311                 endif(${T} STREQUAL "BINDING")
 312                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 313                         MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 314                 endif()
 315         endforeach()
 316 endmacro(project_targets_populate)
 317
 318 macro(remote_targets_populate)
 319         if (DEFINED ENV{RSYNC_TARGET})
 320                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 321         endif()
 322         if (DEFINED ENV{RSYNC_PREFIX})
 323                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 324         endif()
 325
 326         set(
 327                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 328                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 329         )
 330
 331         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 332                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 333                 add_custom_target(remote-target-populate
 334                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 335                         COMMAND exit -1
 336                 )
 337         else()
 338                 set(BINDINGS_REGEX "not_set")
 339                 if(DEFINED BINDINGS_LIST)
 340                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 341                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 342                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 343                                 string(APPEND BINDINGS_REGEX ".so")
 344                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 345                                 foreach(B IN LISTS BINDINGS_LIST)
 346                                         STRING(APPEND BINDINGS_STR "${B}|")
 347                                 endforeach()
 348                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 349                         endif()
 350                 endif()
 351
 352                 configure_files_in_dir(${TEMPLATE_DIR})
 353                 configure_files_in_dir(${TEMPLATE_DIR})
 354
 355                 add_custom_target(remote-target-populate
 356                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 357                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 358                         COMMENT "${REMOTE_LAUNCH}"
 359                 )
 360                 add_dependencies(remote-target-populate populate)
 361         endif()
 362 endmacro(remote_targets_populate)
 363
 364 macro(wgt_package_build)
 365         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 366                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 367         endif()
 368         if(NOT WIDGET_TYPE)
 369                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 370         endif()
 371         if(NOT DEFINED PROJECT_ICON)
 372                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 373                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 374                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 375                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 376                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 377                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 378                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 379                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 380                 endif()
 381         elseif(EXISTS "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 382                 set(ICON_PATH "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 383         elseif(EXISTS "${WIDGET_ICON}")
 384                 set(ICON_PATH "${WIDGET_ICON}")
 385         else()
 386                 set(ICON_PATH ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/wgt/icon-default.png)
 387         endif()
 388
 389         if(NOT WIDGET_ENTRY_POINT)
 390                 set(WIDGET_ENTRY_POINT lib)
 391         endif()
 392
 393         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 394                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 395                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 396
 397         )
 398         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 399
 400         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 401         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 402         if(${PROJECT_CONF_FILES})
 403                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 404         endif(${PROJECT_CONF_FILES})
 405
 406         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 407                 DEPENDS ${PROJECT_TARGETS}
 408                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 409         )
 410
 411         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 412         add_dependencies(widget populate packaging_wgt)
 413         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 414
 415         if(NOT RSYNC_TARGET)
 416                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 417                 add_custom_target(widget-target-install
 418                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 419                         COMMAND exit -1
 420                 )
 421         else()
 422         configure_files_in_dir(${TEMPLATE_DIR})
 423         add_custom_target(widget-target-install
 424         DEPENDS widget
 425         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 426         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 427         )
 428 endif()
 429
 430         if(PACKAGE_MESSAGE)
 431         add_custom_command(TARGET widget
 432                 POST_BUILD
 433                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 434         endif()
 435 endmacro(wgt_package_build)
 436
 437 macro(rpm_package_build)
 438         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 439                 DEPENDS ${PROJECT_TARGETS}
 440                                 archive
 441                                 packaging
 442                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 443         )
 444
 445         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 446         add_dependencies(rpm populate packaging)
 447
 448         if(PACKAGE_MESSAGE)
 449         add_custom_command(TARGET rpm
 450                 POST_BUILD
 451                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 452         endif()
 453 endmacro(rpm_package_build)
 454
 455 macro(deb_package_build)
 456 #TODO
 457 endmacro(deb_package_build)
 458
 459 macro(project_package_build)
 460         if(EXISTS ${TEMPLATE_DIR})
 461                 rpm_package_build()
 462         endif()
 463
 464         if(EXISTS ${TEMPLATE_DIR})
 465                 wgt_package_build()
 466         endif()
 467
 468         if(EXISTS ${TEMPLATE_DIR})
 469                 deb_package_build()
 470         endif()
 471 endmacro(project_package_build)
 472
 473 macro(project_subdirs_add)
 474         set (ARGSLIST ${ARGN})
 475         list(LENGTH ARGSLIST ARGSNUM)
 476         if(${ARGSNUM} GREATER 0)
 477                 file(GLOB filelist "${ARGV0}")
 478         else()
 479         file(GLOB filelist "*")
 480         endif()
 481
 482         foreach(filename ${filelist})
 483                 if(EXISTS "${filename}/CMakeLists.txt")
 484                         add_subdirectory(${filename})
 485                 endif(EXISTS "${filename}/CMakeLists.txt")
 486         endforeach()
 487 endmacro(project_subdirs_add)
 488
 489 # Print developer helper message when build is done
 490 # -------------------------------------------------------
 491 macro(project_closing_msg)
 492         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 493         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 494         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 495                 add_custom_target(${PROJECT_NAME}_build_done ALL
 496                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 497                 )
 498                  add_dependencies(${PROJECT_NAME}_build_done
 499                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 500         endif()
 501 endmacro()