cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # CMake 3.6 imported macros to simulate list(FILTER ...) subcommand
  26 # -----------------------
  27 MACRO(PARSE_ARGUMENTS prefix arg_names option_names)
  28 SET(DEFAULT_ARGS)
  29 FOREACH(arg_name ${arg_names})
  30   SET(${prefix}_${arg_name})
  31 ENDFOREACH(arg_name)
  32 FOREACH(option ${option_names})
  33   SET(${prefix}_${option} FALSE)
  34 ENDFOREACH(option)
  35
  36 SET(current_arg_name DEFAULT_ARGS)
  37 SET(current_arg_list)
  38 FOREACH(arg ${ARGN})
  39   LIST_CONTAINS(is_arg_name ${arg} ${arg_names})
  40   IF (is_arg_name)
  41         SET(${prefix}_${current_arg_name} ${current_arg_list})
  42         SET(current_arg_name ${arg})
  43         SET(current_arg_list)
  44   ELSE (is_arg_name)
  45         LIST_CONTAINS(is_option ${arg} ${option_names})
  46         IF (is_option)
  47   SET(${prefix}_${arg} TRUE)
  48         ELSE (is_option)
  49   SET(current_arg_list ${current_arg_list} ${arg})
  50         ENDIF (is_option)
  51   ENDIF (is_arg_name)
  52 ENDFOREACH(arg)
  53 SET(${prefix}_${current_arg_name} ${current_arg_list})
  54 ENDMACRO(PARSE_ARGUMENTS)
  55
  56 MACRO(LIST_CONTAINS var value)
  57 SET(${var})
  58 FOREACH (value2 ${ARGN})
  59   IF (${value} STREQUAL ${value2})
  60         SET(${var} TRUE)
  61   ENDIF (${value} STREQUAL ${value2})
  62 ENDFOREACH (value2)
  63 ENDMACRO(LIST_CONTAINS)
  64
  65 MACRO(LIST_FILTER)
  66 PARSE_ARGUMENTS(LIST_FILTER "OUTPUT_VARIABLE" "" ${ARGV})
  67 # Check arguments.
  68 LIST(LENGTH LIST_FILTER_DEFAULT_ARGS LIST_FILTER_default_length)
  69 IF(${LIST_FILTER_default_length} EQUAL 0)
  70   MESSAGE(FATAL_ERROR "LIST_FILTER: missing list variable.")
  71 ENDIF(${LIST_FILTER_default_length} EQUAL 0)
  72 IF(${LIST_FILTER_default_length} EQUAL 1)
  73   MESSAGE(FATAL_ERROR "LIST_FILTER: missing regular expression variable.")
  74 ENDIF(${LIST_FILTER_default_length} EQUAL 1)
  75 # Reset output variable
  76 IF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  77   SET(LIST_FILTER_OUTPUT_VARIABLE "LIST_FILTER_internal_output")
  78 ENDIF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  79 SET(${LIST_FILTER_OUTPUT_VARIABLE})
  80 # Extract input list from arguments
  81 LIST(GET LIST_FILTER_DEFAULT_ARGS 0 LIST_FILTER_input_list)
  82 LIST(REMOVE_AT LIST_FILTER_DEFAULT_ARGS 0)
  83 FOREACH(LIST_FILTER_item ${${LIST_FILTER_input_list}})
  84   FOREACH(LIST_FILTER_regexp_var ${LIST_FILTER_DEFAULT_ARGS})
  85         FOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  86           IF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  87                 LIST(APPEND ${LIST_FILTER_OUTPUT_VARIABLE} ${LIST_FILTER_item})
  88           ENDIF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  89         ENDFOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  90   ENDFOREACH(LIST_FILTER_regexp_var)
  91 ENDFOREACH(LIST_FILTER_item)
  92 # If OUTPUT_VARIABLE is not specified, overwrite the input list.
  93 IF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  94   SET(${LIST_FILTER_input_list} ${${LIST_FILTER_OUTPUT_VARIABLE}})
  95 ENDIF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
  96 ENDMACRO(LIST_FILTER)
  97
  98 # Generic useful macro
  99 # -----------------------
 100 macro(PROJECT_TARGET_ADD TARGET_NAME)
 101         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
 102         set(TARGET_NAME ${TARGET_NAME})
 103 endmacro(PROJECT_TARGET_ADD)
 104
 105 macro(PROJECT_PKGDEP_ADD PKG_NAME)
 106         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
 107 endmacro(PROJECT_PKGDEP_ADD)
 108
 109 macro(defstr name value)
 110         add_definitions(-D${name}=${value})
 111 endmacro(defstr)
 112
 113 macro(configure_files_in_dir dir)
 114         file(GLOB filelist "${dir}/*in")
 115         foreach(file ${filelist})
 116                 get_filename_component(filename ${file} NAME)
 117                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
 118                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
 119                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
 120                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
 121         endforeach()
 122 endmacro(configure_files_in_dir)
 123
 124 # Create custom target dedicated for HTML5 and DATA AGL target type
 125 macro(add_input_files INPUT_FILES)
 126         set(XML_LIST ${INPUT_FILES})
 127         set(LUA_LIST ${INPUT_FILES})
 128         set(JSON_LIST ${INPUT_FILES})
 129         # These are v3.6 subcommand. Not used as default for now as
 130         # many dev use Ubuntu 16.04 which have only 3.5 version
 131         #list(FILTER XML_LIST INCLUDE REGEX "xml$")
 132         #list(FILTER LUA_LIST INCLUDE REGEX "lua$")
 133         #list(FILTER JSON_LIST INCLUDE REGEX "json$")
 134         list_filter(XML_LIST "xml$")
 135         list_filter(LUA_LIST "lua$")
 136         list_filter(JSON_LIST "json$")
 137
 138         add_custom_target(${TARGET_NAME}
 139         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 140         )
 141
 142         foreach(file ${XML_LIST})
 143                 add_custom_command(TARGET ${TARGET_NAME}
 144                         PRE_BUILD
 145                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 146                         COMMAND ${XML_CHECKER} ${file}
 147                 )
 148         endforeach()
 149         foreach(file ${LUA_LIST})
 150         add_custom_command(TARGET ${TARGET_NAME}
 151                 PRE_BUILD
 152                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 153                 COMMAND ${LUA_CHECKER} ${file}
 154         )
 155         endforeach()
 156         foreach(file ${JSON_LIST})
 157         add_custom_command(TARGET ${TARGET_NAME}
 158                 PRE_BUILD
 159                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 160                 COMMAND cat ${file} | ${JSON_CHECKER}
 161         )
 162         endforeach()
 163
 164         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 165         DEPENDS ${INPUT_FILES}
 166         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 167         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 168         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 169         )
 170 endmacro()
 171
 172 # Set the name of the OPENAPI definition JSON file for binding v2
 173 macro(set_openapi_filename openapi_filename)
 174         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
 175 endmacro()
 176
 177 # Pre-packaging
 178 macro(project_targets_populate)
 179         # Default Widget default directory
 180         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
 181         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
 182         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
 183         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
 184         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
 185
 186         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 187                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 188         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 189                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 190         foreach(TARGET ${PROJECT_TARGETS})
 191                 get_target_property(T ${TARGET} LABELS)
 192                 if(T)
 193                         # Declaration of a custom command that will populate widget tree with the target
 194                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 195
 196                         get_target_property(P ${TARGET} PREFIX)
 197                         get_target_property(BD ${TARGET} BINARY_DIR)
 198                         get_target_property(SD ${TARGET} SOURCE_DIR)
 199                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 200
 201                         if(P MATCHES "NOTFOUND$")
 202                                 if (${T} STREQUAL "BINDING")
 203                                         set(P "lib")
 204                                 else()
 205                                         set(P "")
 206                                 endif()
 207                         endif()
 208
 209                         if(${T} STREQUAL "BINDING")
 210                                 list(APPEND BINDINGS_LIST "${P}${OUT}")
 211                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 212                                         DEPENDS ${BD}/${P}${OUT}.so
 213                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 214                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 215                                 )
 216                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 217                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 218                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 219                         elseif(${T} STREQUAL "BINDINGV2")
 220                                 if (OPENAPI_DEF)
 221                                         add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 222                                                 DEPENDS ${SD}/${OPENAPI_DEF}.json
 223                                                 COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 224                                         )
 225                                         add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 226                                                 COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 227                                         add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 228                                 else()
 229                                         add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 230                                                 DEPENDS ${SD}/${OUT}-apidef.json
 231                                                 COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 232                                         )
 233                                         add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 234                                                 COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 235                                         add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 236                                 endif()
 237
 238                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 239                                                 DEPENDS ${BD}/${P}${OUT}.so
 240                                                 COMMAND mkdir -p ${PACKAGE_LIBDIR}
 241                                                 COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 242                                         )
 243                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 244                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 245                                         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 246                         elseif(${T} STREQUAL "EXECUTABLE")
 247                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
 248                                         DEPENDS ${BD}/${P}${OUT}
 249                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 250                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 251                                 )
 252                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${OUT})
 253                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 254                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 255                         elseif(${T} STREQUAL "HTDOCS")
 256                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 257                                         DEPENDS ${BD}/${P}${OUT}
 258                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 259                                         COMMAND touch ${PACKAGE_HTTPDIR}
 260                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 261                                 )
 262                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 263                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 264                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 265                         elseif(${T} STREQUAL "DATA")
 266                                 # Generate list of output files instead of just one output directory
 267                                 get_target_property(SF ${TARGET} SOURCES)
 268                                 foreach(file ${SF})
 269                                         get_filename_component(JUST_FILENAME ${file} NAME)
 270                                         list(APPEND OUTPUT_FILES ${PACKAGE_DATADIR}/${JUST_FILENAME})
 271                                 endforeach()
 272                                 add_custom_target(${POPULE_PACKAGE_TARGET})
 273                                 add_custom_command(TARGET ${POPULE_PACKAGE_TARGET}
 274                                         POST_BUILD
 275                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 276                                         COMMAND touch ${PACKAGE_DATADIR}
 277                                         COMMAND cp -r ${BD}/${TARGET} ${PACKAGE_DATADIR}
 278                                 )
 279                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 280                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 281                         endif(${T} STREQUAL "BINDING")
 282                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 283                         MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 284                 endif()
 285         endforeach()
 286 endmacro(project_targets_populate)
 287
 288 macro(remote_targets_populate)
 289         if (DEFINED ENV{RSYNC_TARGET})
 290                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 291         endif()
 292         if (DEFINED ENV{RSYNC_PREFIX})
 293                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 294         endif()
 295
 296         set(
 297                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 298                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 299         )
 300
 301         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 302                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 303                 add_custom_target(remote-target-populate
 304                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 305                         COMMAND exit -1
 306                 )
 307         else()
 308                 set(BINDINGS_REGEX "not_set")
 309                 if(DEFINED BINDINGS_LIST)
 310                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 311                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 312                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 313                                 string(APPEND BINDINGS_REGEX ".so")
 314                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 315                                 foreach(B IN LISTS BINDINGS_LIST)
 316                                         STRING(APPEND BINDINGS_STR "${B}|")
 317                                 endforeach()
 318                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 319                         endif()
 320                 endif()
 321
 322                 configure_files_in_dir(${TEMPLATE_DIR})
 323                 configure_files_in_dir(${TEMPLATE_DIR})
 324
 325                 add_custom_target(remote-target-populate
 326                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 327                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 328                         COMMENT "${REMOTE_LAUNCH}"
 329                 )
 330                 add_dependencies(remote-target-populate populate)
 331         endif()
 332 endmacro(remote_targets_populate)
 333
 334 macro(wgt_package_build)
 335         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 336                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 337         endif()
 338         if(NOT WIDGET_TYPE)
 339                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 340         endif()
 341         if(NOT DEFINED PROJECT_ICON)
 342                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 343                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 344                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 345                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 346                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 347                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 348                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 349                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 350                 endif()
 351         elseif(EXISTS "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 352                 set(ICON_PATH "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 353         elseif(EXISTS "${WIDGET_ICON}")
 354                 set(ICON_PATH "${WIDGET_ICON}")
 355         else()
 356                 set(ICON_PATH ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/wgt/icon-default.png)
 357         endif()
 358
 359         if(NOT WIDGET_ENTRY_POINT)
 360                 set(WIDGET_ENTRY_POINT lib)
 361         endif()
 362
 363         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 364                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 365                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 366
 367         )
 368         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 369
 370         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 371         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 372         if(${PROJECT_CONF_FILES})
 373                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 374         endif(${PROJECT_CONF_FILES})
 375
 376         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 377                 DEPENDS ${PROJECT_TARGETS}
 378                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 379         )
 380
 381         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 382         add_dependencies(widget populate packaging_wgt)
 383         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 384
 385         if(NOT RSYNC_TARGET)
 386                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 387                 add_custom_target(widget-target-install
 388                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 389                         COMMAND exit -1
 390                 )
 391         else()
 392         configure_files_in_dir(${TEMPLATE_DIR})
 393         add_custom_target(widget-target-install
 394         DEPENDS widget
 395         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 396         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 397         )
 398 endif()
 399
 400         if(PACKAGE_MESSAGE)
 401         add_custom_command(TARGET widget
 402                 POST_BUILD
 403                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 404         endif()
 405 endmacro(wgt_package_build)
 406
 407 macro(rpm_package_build)
 408         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 409                 DEPENDS ${PROJECT_TARGETS}
 410                                 archive
 411                                 packaging
 412                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 413         )
 414
 415         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 416         add_dependencies(rpm populate packaging)
 417
 418         if(PACKAGE_MESSAGE)
 419         add_custom_command(TARGET rpm
 420                 POST_BUILD
 421                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 422         endif()
 423 endmacro(rpm_package_build)
 424
 425 macro(deb_package_build)
 426 #TODO
 427 endmacro(deb_package_build)
 428
 429 macro(project_package_build)
 430         if(EXISTS ${TEMPLATE_DIR})
 431                 rpm_package_build()
 432         endif()
 433
 434         if(EXISTS ${TEMPLATE_DIR})
 435                 wgt_package_build()
 436         endif()
 437
 438         if(EXISTS ${TEMPLATE_DIR})
 439                 deb_package_build()
 440         endif()
 441 endmacro(project_package_build)
 442
 443 macro(project_subdirs_add)
 444         set (ARGSLIST ${ARGN})
 445         list(LENGTH ARGSLIST ARGSNUM)
 446         if(${ARGSNUM} GREATER 0)
 447                 file(GLOB filelist "${ARGV0}")
 448         else()
 449         file(GLOB filelist "*")
 450         endif()
 451
 452         foreach(filename ${filelist})
 453                 if(EXISTS "${filename}/CMakeLists.txt")
 454                         add_subdirectory(${filename})
 455                 endif(EXISTS "${filename}/CMakeLists.txt")
 456         endforeach()
 457 endmacro(project_subdirs_add)
 458
 459 # Print developer helper message when build is done
 460 # -------------------------------------------------------
 461 macro(project_closing_msg)
 462         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 463         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 464         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 465                 add_custom_target(${PROJECT_NAME}_build_done ALL
 466                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 467                 )
 468                  add_dependencies(${PROJECT_NAME}_build_done
 469                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 470         endif()
 471 endmacro()