cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # CMake 3.6 imported macros to simulate list(FILTER ...) subcommand
  26 #--------------------------------------------------------------------------
  27 MACRO(prevent_in_source_build)
  28         execute_process(COMMAND rm -rf ${CMAKE_SOURCE_DIR}/CMakeCache.txt ${CMAKE_SOURCE_DIR}/CMakeCacheForScript.cmake ${CMAKE_SOURCE_DIR}/CMakeFiles ${CMAKE_SOURCE_DIR}/cmake_install.cmake)
  29
  30         get_filename_component(srcdir "${CMAKE_SOURCE_DIR}" REALPATH)
  31         get_filename_component(bindir "${CMAKE_BINARY_DIR}" REALPATH)
  32
  33         if(${srcdir} STREQUAL ${bindir})
  34                 message(FATAL_ERROR "${Red}**** ERROR: You trying to build the project from the source directory or a previous build in-source occured. This isn't allowed, you have to clean CMakeCache.txt file from your source directory (${srcdir}), and build from a separate directory. ****\n")
  35         endif()
  36 ENDMACRO(prevent_in_source_build)
  37
  38 MACRO(PARSE_ARGUMENTS prefix arg_names option_names)
  39         SET(DEFAULT_ARGS)
  40         FOREACH(arg_name ${arg_names})
  41         SET(${prefix}_${arg_name})
  42         ENDFOREACH(arg_name)
  43         FOREACH(option ${option_names})
  44         SET(${prefix}_${option} FALSE)
  45         ENDFOREACH(option)
  46
  47         SET(current_arg_name DEFAULT_ARGS)
  48         SET(current_arg_list)
  49         FOREACH(arg ${ARGN})
  50         LIST_CONTAINS(is_arg_name ${arg} ${arg_names})
  51         IF (is_arg_name)
  52                 SET(${prefix}_${current_arg_name} ${current_arg_list})
  53                 SET(current_arg_name ${arg})
  54                 SET(current_arg_list)
  55         ELSE (is_arg_name)
  56                 LIST_CONTAINS(is_option ${arg} ${option_names})
  57                 IF (is_option)
  58         SET(${prefix}_${arg} TRUE)
  59                 ELSE (is_option)
  60         SET(current_arg_list ${current_arg_list} ${arg})
  61                 ENDIF (is_option)
  62         ENDIF (is_arg_name)
  63         ENDFOREACH(arg)
  64         SET(${prefix}_${current_arg_name} ${current_arg_list})
  65 ENDMACRO(PARSE_ARGUMENTS)
  66
  67 MACRO(LIST_CONTAINS var value)
  68 SET(${var})
  69 FOREACH (value2 ${ARGN})
  70   IF (${value} STREQUAL ${value2})
  71         SET(${var} TRUE)
  72   ENDIF (${value} STREQUAL ${value2})
  73 ENDFOREACH (value2)
  74 ENDMACRO(LIST_CONTAINS)
  75
  76 MACRO(LIST_FILTER)
  77 PARSE_ARGUMENTS(LIST_FILTER "OUTPUT_VARIABLE" "" ${ARGV})
  78 # Check arguments.
  79 LIST(LENGTH LIST_FILTER_DEFAULT_ARGS LIST_FILTER_default_length)
  80 IF(${LIST_FILTER_default_length} EQUAL 0)
  81   MESSAGE(FATAL_ERROR "LIST_FILTER: missing list variable.")
  82 ENDIF(${LIST_FILTER_default_length} EQUAL 0)
  83 IF(${LIST_FILTER_default_length} EQUAL 1)
  84   MESSAGE(FATAL_ERROR "LIST_FILTER: missing regular expression variable.")
  85 ENDIF(${LIST_FILTER_default_length} EQUAL 1)
  86 # Reset output variable
  87 IF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  88   SET(LIST_FILTER_OUTPUT_VARIABLE "LIST_FILTER_internal_output")
  89 ENDIF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  90 SET(${LIST_FILTER_OUTPUT_VARIABLE})
  91 # Extract input list from arguments
  92 LIST(GET LIST_FILTER_DEFAULT_ARGS 0 LIST_FILTER_input_list)
  93 LIST(REMOVE_AT LIST_FILTER_DEFAULT_ARGS 0)
  94 FOREACH(LIST_FILTER_item ${${LIST_FILTER_input_list}})
  95   FOREACH(LIST_FILTER_regexp_var ${LIST_FILTER_DEFAULT_ARGS})
  96         FOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  97           IF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  98                 LIST(APPEND ${LIST_FILTER_OUTPUT_VARIABLE} ${LIST_FILTER_item})
  99           ENDIF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
 100         ENDFOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
 101   ENDFOREACH(LIST_FILTER_regexp_var)
 102 ENDFOREACH(LIST_FILTER_item)
 103 # If OUTPUT_VARIABLE is not specified, overwrite the input list.
 104 IF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
 105   SET(${LIST_FILTER_input_list} ${${LIST_FILTER_OUTPUT_VARIABLE}})
 106 ENDIF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
 107 ENDMACRO(LIST_FILTER)
 108
 109 # Generic useful macro
 110 # -----------------------
 111 macro(set_install_prefix)
 112         if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND INSTALL_PREFIX)
 113                 message(STATUS "-- Overwrite the CMAKE default install prefix with ${INSTALL_PREFIX}")
 114                 set(CMAKE_INSTALL_PREFIX ${INSTALL_PREFIX} CACHE PATH "Install prefix" FORCE)
 115         endif()
 116 endmacro()
 117
 118 macro(PROJECT_TARGET_ADD TARGET_NAME)
 119         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
 120         set(TARGET_NAME ${TARGET_NAME})
 121 endmacro(PROJECT_TARGET_ADD)
 122
 123 macro(PROJECT_PKGDEP_ADD PKG_NAME)
 124         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
 125 endmacro(PROJECT_PKGDEP_ADD)
 126
 127 macro(defstr name value)
 128         add_definitions(-D${name}=${value})
 129 endmacro(defstr)
 130
 131 macro(configure_files_in_dir dir)
 132         file(GLOB filelist "${dir}/*in")
 133         foreach(file ${filelist})
 134                 get_filename_component(filename ${file} NAME)
 135                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
 136                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
 137                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
 138                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
 139         endforeach()
 140 endmacro(configure_files_in_dir)
 141
 142 # Create custom target dedicated for HTML5 and DATA AGL target type
 143 macro(add_input_files INPUT_FILES)
 144         if(NOT DEFINED XML_FILES)
 145                 set(ext_reg "xml$")
 146                 set(XML_LIST ${INPUT_FILES})
 147                 list_filter(XML_LIST ext_reg)
 148                 execute_process(
 149                         COMMAND which ${XML_CHECKER}
 150                         RESULT_VARIABLE XML_CHECKER_PRESENT
 151                         OUTPUT_QUIET ERROR_QUIET
 152                 )
 153         endif()
 154         if(NOT DEFINED LUA_LIST)
 155                 set(ext_reg "lua$")
 156                 set(LUA_LIST ${INPUT_FILES})
 157                 list_filter(LUA_LIST ext_reg)
 158                 execute_process(
 159                         COMMAND which ${LUA_CHECKER}
 160                         RESULT_VARIABLE LUA_CHECKER_PRESENT
 161                         OUTPUT_QUIET ERROR_QUIET
 162                 )
 163         endif()
 164         if(NOT DEFINED JSON_FILES)
 165                 set(ext_reg "json$")
 166                 set(JSON_LIST ${INPUT_FILES})
 167                 list_filter(JSON_LIST ext_reg)
 168                 execute_process(
 169                         COMMAND which ${JSON_CHECKER}
 170                         RESULT_VARIABLE JSON_CHECKER_PRESENT
 171                         OUTPUT_QUIET ERROR_QUIET
 172                 )
 173         endif()
 174
 175         # These are v3.6 subcommand. Not used as default for now as
 176         # many dev use Ubuntu 16.04 which have only 3.5 version
 177         #list(FILTER XML_LIST INCLUDE REGEX "xml$")
 178         #list(FILTER LUA_LIST INCLUDE REGEX "lua$")
 179         #list(FILTER JSON_LIST INCLUDE REGEX "json$")
 180
 181         add_custom_target(${TARGET_NAME} ALL
 182         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 183         )
 184
 185         if(XML_CHECKER_PRESENT EQUAL 0)
 186                 foreach(file ${XML_LIST})
 187                         add_custom_command(TARGET ${TARGET_NAME}
 188                                 PRE_BUILD
 189                                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 190                                 COMMAND ${XML_CHECKER} ${file}
 191                         )
 192                 endforeach()
 193         elseif(XML_LIST)
 194         add_custom_command(TARGET ${TARGET_NAME}
 195         PRE_BUILD
 196         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 197         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: XML_CHECKER not found. Not verification made on files !")
 198         endif()
 199         if(LUA_CHECKER_PRESENT EQUAL 0)
 200                 foreach(file ${LUA_LIST})
 201                 add_custom_command(TARGET ${TARGET_NAME}
 202                         PRE_BUILD
 203                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 204                         COMMAND ${LUA_CHECKER} ${file}
 205                 )
 206                 endforeach()
 207         elseif(LUA_LIST)
 208                 add_custom_command(TARGET ${TARGET_NAME}
 209                         PRE_BUILD
 210                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 211                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: LUA_CHECKER not found. Not verification made on files !")
 212         endif()
 213         if(JSON_CHECKER_PRESENT EQUAL 0)
 214                 foreach(file ${JSON_LIST})
 215                 add_custom_command(TARGET ${TARGET_NAME}
 216                         PRE_BUILD
 217                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 218                         COMMAND ${JSON_CHECKER} ${file}
 219                 )
 220                 endforeach()
 221         elseif(JSON_LIST)
 222         add_custom_command(TARGET ${TARGET_NAME}
 223         PRE_BUILD
 224         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 225         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: JSON_CHECKER not found. Not verification made on files !")
 226         endif()
 227
 228         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 229         DEPENDS ${INPUT_FILES}
 230         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 231         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 232         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 233         )
 234 endmacro()
 235
 236 # Set the name of the OPENAPI definition JSON file for binding v2
 237 macro(set_openapi_filename openapi_filename)
 238         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
 239 endmacro()
 240
 241 # Common command to call inside project_targets_populate macro
 242 macro(generate_one_populate_target OUTPUTFILES PKG_DESTDIR)
 243         add_custom_command(OUTPUT ${PKG_DESTDIR}/${OUTPUTFILES}
 244                 DEPENDS ${BD}/${OUTPUTFILES}
 245                 COMMAND mkdir -p ${PKG_DESTDIR}
 246                 COMMAND touch ${PKG_DESTDIR}
 247                 COMMAND cp -r ${BD}/${OUTPUTFILES}/* ${PKG_DESTDIR} 2> /dev/null || cp ${BD}/${OUTPUTFILES} ${PKG_DESTDIR}
 248         )
 249
 250         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PKG_DESTDIR}/${OUTPUTFILES})
 251         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 252         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 253 endmacro()
 254
 255 # To be call inside project_targets_populate macro
 256 macro(afb_genskel)
 257         if ("${PROJECT_LANGUAGES}" MATCHES "CXX")
 258                 list(APPEND GENSKEL_OPTS "--cpp")
 259         endif()
 260         if (OPENAPI_DEF)
 261                 add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 262                         DEPENDS ${SD}/${OPENAPI_DEF}.json
 263                         COMMAND afb-genskel ${GENSKEL_OPTS} ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 264                 )
 265                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 266                         COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 267                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 268         else()
 269                 add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 270                         DEPENDS ${SD}/${OUT}-apidef.json
 271                         COMMAND afb-genskel ${GENSKEL_OPTS} ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 272                 )
 273                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 274                         COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 275                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 276         endif()
 277 endmacro()
 278
 279 # Pre-packaging
 280 macro(project_targets_populate)
 281         # Default Widget default directory
 282         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/${BINDIR})
 283         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/${ETCDIR})
 284         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/${LIBDIR})
 285         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/${HTTPDIR})
 286         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/${DATADIR})
 287
 288         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 289                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 290         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
 291
 292         # Dirty trick to define a default INSTALL command for app-templates handled
 293         # targets
 294         INSTALL(CODE "execute_process(COMMAND make populate)")
 295         if(NO_DEDICATED_INSTALL_DIR)
 296                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 297                         DESTINATION ${CMAKE_INSTALL_PREFIX}
 298                 )
 299         else()
 300                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 301                         DESTINATION ${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME}
 302                 )
 303         endif()
 304
 305         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 306         foreach(TARGET ${PROJECT_TARGETS})
 307                 # Declaration of a custom command that will populate widget tree with the target
 308                 set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 309                 get_target_property(T ${TARGET} LABELS)
 310
 311                 if(T)
 312                         get_target_property(P ${TARGET} PREFIX)
 313                         get_target_property(S ${TARGET} SUFFIX)
 314                         get_target_property(BD ${TARGET} BINARY_DIR)
 315                         get_target_property(SD ${TARGET} SOURCE_DIR)
 316                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 317
 318                         if(P MATCHES "NOTFOUND$")
 319                                 if (${T} STREQUAL "LIBRARY")
 320                                         set(P "lib")
 321                                 else()
 322                                         set(P "")
 323                                 endif()
 324                         endif()
 325
 326                         get_target_property(IMPPATH ${TARGET} IMPORTED_LOCATION)
 327                         if(${T} STREQUAL "LIBRARY")
 328                                 unset(BD)
 329                                 generate_one_populate_target(${IMPPATH} ${PACKAGE_LIBDIR})
 330                         elseif(${T} STREQUAL "PLUGIN")
 331                                 if(NOT S)
 332                                         set(S ".ctlso")
 333                                 endif()
 334                                 generate_one_populate_target(${P}${OUT}${S} "${PACKAGE_LIBDIR}/plugins")
 335                         elseif(${T} STREQUAL "BINDING")
 336                                 if(NOT S)
 337                                         set(S ".so")
 338                                 endif()
 339                                 list(APPEND BINDINGS_LIST "${P}${OUT}${S}")
 340                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 341                         elseif(${T} STREQUAL "BINDINGV2")
 342                                 if(NOT S)
 343                                         set(S ".so")
 344                                 endif()
 345                                 afb_genskel()
 346                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 347                         elseif(${T} STREQUAL "EXECUTABLE")
 348                                 if(NOT S)
 349                                         set(S "")
 350                                 endif()
 351                                 if(NOT OUT AND IMPPATH)
 352                                         unset(BD)
 353                                         generate_one_populate_target(${IMPPATH} ${PACKAGE_BINDIR})
 354                                 else()
 355                                         generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_BINDIR})
 356                                 endif()
 357                         elseif(${T} STREQUAL "HTDOCS")
 358                                 generate_one_populate_target(${P}${OUT} ${PACKAGE_HTTPDIR})
 359                         elseif(${T} STREQUAL "DATA")
 360                                 generate_one_populate_target(${TARGET} ${PACKAGE_DATADIR})
 361                         elseif(${T} STREQUAL "BINDING-CONFIG")
 362                                 generate_one_populate_target(${TARGET} ${PACKAGE_ETCDIR})
 363                         endif()
 364                         elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 365                                 MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 366                 endif()
 367         endforeach()
 368 endmacro(project_targets_populate)
 369
 370 macro(remote_targets_populate)
 371         if (DEFINED ENV{RSYNC_TARGET})
 372                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 373         endif()
 374         if (DEFINED ENV{RSYNC_PREFIX})
 375                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 376         endif()
 377
 378         set(
 379                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 380                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 381         )
 382
 383         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 384                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 385                 add_custom_target(remote-target-populate
 386                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 387                         COMMAND exit -1
 388                 )
 389         else()
 390                 set(BINDINGS_REGEX "not_set")
 391                 if(DEFINED BINDINGS_LIST)
 392                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 393                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 394                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 395                                 string(APPEND BINDINGS_REGEX ".so")
 396                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 397                                 foreach(B IN LISTS BINDINGS_LIST)
 398                                         STRING(APPEND BINDINGS_STR "${B}|")
 399                                 endforeach()
 400                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 401                         endif()
 402                 endif()
 403
 404                 configure_files_in_dir(${TEMPLATE_DIR})
 405                 configure_files_in_dir(${TEMPLATE_DIR})
 406
 407                 add_custom_target(remote-target-populate
 408                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 409                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 410                 )
 411
 412                 add_custom_command(TARGET remote-target-populate
 413                 POST_BUILD
 414                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --green --bold ${REMOTE_LAUNCH}
 415                 )
 416
 417                 add_dependencies(remote-target-populate populate)
 418         endif()
 419 endmacro(remote_targets_populate)
 420
 421 macro(wgt_package_build)
 422         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 423                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 424         endif()
 425         if(NOT WIDGET_TYPE)
 426                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 427         endif()
 428         if(NOT DEFINED PROJECT_ICON)
 429                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 430                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 431                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 432                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 433                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 434                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 435                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 436                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 437                 endif()
 438         elseif(EXISTS "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 439                 set(ICON_PATH "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 440         elseif(EXISTS "${WIDGET_ICON}")
 441                 set(ICON_PATH "${WIDGET_ICON}")
 442         else()
 443                 set(ICON_PATH ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/wgt/icon-default.png)
 444         endif()
 445
 446         if(NOT WIDGET_ENTRY_POINT)
 447                 set(WIDGET_ENTRY_POINT lib)
 448         endif()
 449
 450         if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "RELEASE")
 451                 string(TOLOWER "${PROJECT_NAME}-${CMAKE_BUILD_TYPE}" WGT_NAME)
 452         else()
 453                 string(TOLOWER "${PROJECT_NAME}" WGT_NAME)
 454         endif()
 455
 456         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 457                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 458                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 459
 460         )
 461         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 462
 463         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 464         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 465         if(${PROJECT_CONF_FILES})
 466                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 467         endif(${PROJECT_CONF_FILES})
 468
 469         find_program(wgtpkgCMD "wgtpkg-pack")
 470         if(wgtpkgCMD)
 471                 set(packCMD ${wgtpkgCMD} "-f" "-o" "${WGT_NAME}.wgt" ${PROJECT_PKG_BUILD_DIR})
 472         else()
 473                 set(packCMD cd ${PROJECT_PKG_BUILD_DIR} && ${CMAKE_COMMAND} "-E" "tar" "cf" "../${WGT_NAME}.wgt" "--format=zip" "*")
 474         endif()
 475
 476         add_custom_command(OUTPUT ${WGT_NAME}.wgt
 477                 DEPENDS ${PROJECT_TARGETS}
 478                 COMMAND ${packCMD}
 479         )
 480
 481         add_custom_target(widget DEPENDS ${WGT_NAME}.wgt)
 482         add_dependencies(widget populate packaging_wgt)
 483         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${WGT_NAME}.wgt")
 484
 485         if(NOT RSYNC_TARGET)
 486                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 487                 add_custom_target(widget-target-install
 488                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 489                         COMMAND exit -1
 490                 )
 491         else()
 492         configure_files_in_dir(${TEMPLATE_DIR})
 493         add_custom_target(widget-target-install
 494         DEPENDS widget
 495         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 496         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 497         )
 498 endif()
 499
 500         if(PACKAGE_MESSAGE)
 501         add_custom_command(TARGET widget
 502                 POST_BUILD
 503                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 504         endif()
 505 endmacro(wgt_package_build)
 506
 507 macro(rpm_package_build)
 508         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 509                 DEPENDS ${PROJECT_TARGETS}
 510                                 archive
 511                                 packaging
 512                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 513         )
 514
 515         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 516         add_dependencies(rpm populate packaging)
 517
 518         if(PACKAGE_MESSAGE)
 519         add_custom_command(TARGET rpm
 520                 POST_BUILD
 521                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 522         endif()
 523 endmacro(rpm_package_build)
 524
 525 macro(project_package_build)
 526         if(EXISTS ${TEMPLATE_DIR})
 527                 wgt_package_build()
 528         endif()
 529 endmacro(project_package_build)
 530
 531 macro(project_subdirs_add)
 532         set (ARGSLIST ${ARGN})
 533         list(LENGTH ARGSLIST ARGSNUM)
 534         if(${ARGSNUM} GREATER 0)
 535                 file(GLOB filelist "${ARGV0}")
 536         else()
 537         file(GLOB filelist "*")
 538         endif()
 539
 540         foreach(filename ${filelist})
 541                 if(EXISTS "${filename}/CMakeLists.txt")
 542                         add_subdirectory(${filename})
 543                 elseif(${filename} MATCHES "^.*\\.cmake$")
 544                         include(${filename})
 545                 endif(EXISTS "${filename}/CMakeLists.txt")
 546         endforeach()
 547 endmacro(project_subdirs_add)
 548
 549 # Print developer helper message when build is done
 550 # -------------------------------------------------------
 551 macro(project_closing_msg)
 552         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 553         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 554         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 555                 add_custom_target(${PROJECT_NAME}_build_done ALL
 556                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 557                 )
 558                 add_dependencies(${PROJECT_NAME}_build_done
 559                         ${PROJECT_TARGETS} populate)
 560         endif()
 561 endmacro()
 562
 563 macro(check_version)
 564         if(GIT_PROJECT_VERSION)
 565                 if(${GIT_PROJECT_VERSION} VERSION_GREATER ${APP_TEMPLATES_VERSION})
 566                         message(STATUS "${Yellow}.. Your app-templates submodule version seems outdated. You should update it with 'git submodule update --remote ${PROJECT_APP_TEMPLATES_DIR}'.
 567                 - App-templates version: ${APP_TEMPLATES_VERSION}
 568                 - Project version according AGL Git tag: ${GIT_PROJECT_VERSION}"
 569                 )
 570                 endif()
 571         elseif(PROJECT_VERSION)
 572                 if(${PROJECT_VERSION} VERSION_GREATER ${APP_TEMPLATES_VERSION})
 573                         message(STATUS "${Yellow}.. Your app-templates submodule version seems outdated. You should update it with 'git submodule update --remote ${PROJECT_APP_TEMPLATES_DIR}'.
 574                 - App-templates version: ${APP_TEMPLATES_VERSION}
 575                 - Project version according AGL Git tag: ${PROJECT_VERSION}"
 576                 )
 577                 endif()
 578         else()
 579                 message(STATUS "${Yellow} Your git project repo doesn't have any version tags nor hosted by AGL gerrit infrastructure. Can't compare version between project and app-templates ${APP_TEMPLATES_VERSION} ${ColourReset}")
 580         endif()
 581 endmacro()