cmake/cmake.d/03-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # CMake 3.6 imported macros to simulate list(FILTER ...) subcommand
  26 #--------------------------------------------------------------------------
  27 MACRO(prevent_in_source_build)
  28         execute_process(COMMAND rm -rf ${CMAKE_SOURCE_DIR}/CMakeCache.txt ${CMAKE_SOURCE_DIR}/CMakeCacheForScript.cmake ${CMAKE_SOURCE_DIR}/CMakeFiles ${CMAKE_SOURCE_DIR}/cmake_install.cmake)
  29
  30         get_filename_component(srcdir "${CMAKE_SOURCE_DIR}" REALPATH)
  31         get_filename_component(bindir "${CMAKE_BINARY_DIR}" REALPATH)
  32
  33         if(${srcdir} STREQUAL ${bindir})
  34                 message(FATAL_ERROR "${Red}**** ERROR: You trying to build the project from the source directory or a previous build in-source occured. This isn't allowed, you have to clean CMakeCache.txt file from your source directory (${srcdir}), and build from a separate directory. ****\n")
  35         endif()
  36 ENDMACRO(prevent_in_source_build)
  37
  38 MACRO(PARSE_ARGUMENTS prefix arg_names option_names)
  39         SET(DEFAULT_ARGS)
  40         FOREACH(arg_name ${arg_names})
  41         SET(${prefix}_${arg_name})
  42         ENDFOREACH(arg_name)
  43         FOREACH(option ${option_names})
  44         SET(${prefix}_${option} FALSE)
  45         ENDFOREACH(option)
  46
  47         SET(current_arg_name DEFAULT_ARGS)
  48         SET(current_arg_list)
  49         FOREACH(arg ${ARGN})
  50         LIST_CONTAINS(is_arg_name ${arg} ${arg_names})
  51         IF (is_arg_name)
  52                 SET(${prefix}_${current_arg_name} ${current_arg_list})
  53                 SET(current_arg_name ${arg})
  54                 SET(current_arg_list)
  55         ELSE (is_arg_name)
  56                 LIST_CONTAINS(is_option ${arg} ${option_names})
  57                 IF (is_option)
  58         SET(${prefix}_${arg} TRUE)
  59                 ELSE (is_option)
  60         SET(current_arg_list ${current_arg_list} ${arg})
  61                 ENDIF (is_option)
  62         ENDIF (is_arg_name)
  63         ENDFOREACH(arg)
  64         SET(${prefix}_${current_arg_name} ${current_arg_list})
  65 ENDMACRO(PARSE_ARGUMENTS)
  66
  67 MACRO(LIST_CONTAINS var value)
  68 SET(${var})
  69 FOREACH (value2 ${ARGN})
  70   IF (${value} STREQUAL ${value2})
  71         SET(${var} TRUE)
  72   ENDIF (${value} STREQUAL ${value2})
  73 ENDFOREACH (value2)
  74 ENDMACRO(LIST_CONTAINS)
  75
  76 MACRO(LIST_FILTER)
  77 PARSE_ARGUMENTS(LIST_FILTER "OUTPUT_VARIABLE" "" ${ARGV})
  78 # Check arguments.
  79 LIST(LENGTH LIST_FILTER_DEFAULT_ARGS LIST_FILTER_default_length)
  80 IF(${LIST_FILTER_default_length} EQUAL 0)
  81   MESSAGE(FATAL_ERROR "LIST_FILTER: missing list variable.")
  82 ENDIF(${LIST_FILTER_default_length} EQUAL 0)
  83 IF(${LIST_FILTER_default_length} EQUAL 1)
  84   MESSAGE(FATAL_ERROR "LIST_FILTER: missing regular expression variable.")
  85 ENDIF(${LIST_FILTER_default_length} EQUAL 1)
  86 # Reset output variable
  87 IF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  88   SET(LIST_FILTER_OUTPUT_VARIABLE "LIST_FILTER_internal_output")
  89 ENDIF(NOT LIST_FILTER_OUTPUT_VARIABLE)
  90 SET(${LIST_FILTER_OUTPUT_VARIABLE})
  91 # Extract input list from arguments
  92 LIST(GET LIST_FILTER_DEFAULT_ARGS 0 LIST_FILTER_input_list)
  93 LIST(REMOVE_AT LIST_FILTER_DEFAULT_ARGS 0)
  94 FOREACH(LIST_FILTER_item ${${LIST_FILTER_input_list}})
  95   FOREACH(LIST_FILTER_regexp_var ${LIST_FILTER_DEFAULT_ARGS})
  96         FOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
  97           IF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
  98                 LIST(APPEND ${LIST_FILTER_OUTPUT_VARIABLE} ${LIST_FILTER_item})
  99           ENDIF(${LIST_FILTER_item} MATCHES ${LIST_FILTER_regexp})
 100         ENDFOREACH(LIST_FILTER_regexp ${${LIST_FILTER_regexp_var}})
 101   ENDFOREACH(LIST_FILTER_regexp_var)
 102 ENDFOREACH(LIST_FILTER_item)
 103 # If OUTPUT_VARIABLE is not specified, overwrite the input list.
 104 IF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
 105   SET(${LIST_FILTER_input_list} ${${LIST_FILTER_OUTPUT_VARIABLE}})
 106 ENDIF(${LIST_FILTER_OUTPUT_VARIABLE} STREQUAL "LIST_FILTER_internal_output")
 107 ENDMACRO(LIST_FILTER)
 108
 109 # Generic useful macro
 110 # -----------------------
 111 macro(set_install_prefix)
 112         if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND INSTALL_PREFIX)
 113                 message(STATUS "-- Overwrite the CMAKE default install prefix with ${INSTALL_PREFIX}")
 114                 set(CMAKE_INSTALL_PREFIX ${INSTALL_PREFIX} CACHE PATH "Install prefix" FORCE)
 115         endif()
 116         # (BUG!!!) as PKG_CONFIG_PATH does not work [should be an env variable]
 117         # ---------------------------------------------------------------------
 118         set(CMAKE_PREFIX_PATH ${CMAKE_INSTALL_PREFIX}/lib64/pkgconfig ${CMAKE_INSTALL_PREFIX}/lib/pkgconfig CACHE PATH 'Prefix Path list used by pkgconfig module')
 119         set(LD_LIBRARY_PATH ${CMAKE_INSTALL_PREFIX}/lib64 ${CMAKE_INSTALL_PREFIX}/lib CACHE PATH 'Path list where to search for libraries')
 120 endmacro()
 121
 122 macro(PROJECT_TARGET_ADD TARGET_NAME)
 123         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
 124         set(TARGET_NAME ${TARGET_NAME})
 125 endmacro(PROJECT_TARGET_ADD)
 126
 127 macro(PROJECT_PKGDEP_ADD PKG_NAME)
 128         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
 129 endmacro(PROJECT_PKGDEP_ADD)
 130
 131 macro(defstr name value)
 132         add_definitions(-D${name}=${value})
 133 endmacro(defstr)
 134
 135 macro(configure_files_in_dir dir)
 136         file(GLOB filelist "${dir}/*in")
 137         foreach(file ${filelist})
 138                 get_filename_component(filename ${file} NAME)
 139                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
 140                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
 141                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
 142                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
 143         endforeach()
 144 endmacro(configure_files_in_dir)
 145
 146 # Create custom target dedicated for HTML5 and DATA AGL target type
 147 macro(add_input_files INPUT_FILES)
 148         if(NOT DEFINED XML_FILES)
 149                 set(ext_reg "xml$")
 150                 set(XML_LIST ${INPUT_FILES})
 151                 list_filter(XML_LIST ext_reg)
 152                 execute_process(
 153                         COMMAND which ${XML_CHECKER}
 154                         RESULT_VARIABLE XML_CHECKER_PRESENT
 155                         OUTPUT_QUIET ERROR_QUIET
 156                 )
 157         endif()
 158         if(NOT DEFINED LUA_LIST)
 159                 set(ext_reg "lua$")
 160                 set(LUA_LIST ${INPUT_FILES})
 161                 list_filter(LUA_LIST ext_reg)
 162                 execute_process(
 163                         COMMAND which ${LUA_CHECKER}
 164                         RESULT_VARIABLE LUA_CHECKER_PRESENT
 165                         OUTPUT_QUIET ERROR_QUIET
 166                 )
 167         endif()
 168         if(NOT DEFINED JSON_FILES)
 169                 set(ext_reg "json$")
 170                 set(JSON_LIST ${INPUT_FILES})
 171                 list_filter(JSON_LIST ext_reg)
 172                 execute_process(
 173                         COMMAND which ${JSON_CHECKER}
 174                         RESULT_VARIABLE JSON_CHECKER_PRESENT
 175                         OUTPUT_QUIET ERROR_QUIET
 176                 )
 177         endif()
 178
 179         # These are v3.6 subcommand. Not used as default for now as
 180         # many dev use Ubuntu 16.04 which have only 3.5 version
 181         #list(FILTER XML_LIST INCLUDE REGEX "xml$")
 182         #list(FILTER LUA_LIST INCLUDE REGEX "lua$")
 183         #list(FILTER JSON_LIST INCLUDE REGEX "json$")
 184
 185         add_custom_target(${TARGET_NAME} ALL
 186         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 187         )
 188
 189         if(XML_CHECKER_PRESENT EQUAL 0)
 190                 foreach(file ${XML_LIST})
 191                         add_custom_command(TARGET ${TARGET_NAME}
 192                                 PRE_BUILD
 193                                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 194                                 COMMAND ${XML_CHECKER} ${file}
 195                         )
 196                 endforeach()
 197         elseif(XML_LIST)
 198         add_custom_command(TARGET ${TARGET_NAME}
 199         PRE_BUILD
 200         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 201         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: XML_CHECKER not found. Not verification made on files !")
 202         endif()
 203         if(LUA_CHECKER_PRESENT EQUAL 0)
 204                 foreach(file ${LUA_LIST})
 205                 add_custom_command(TARGET ${TARGET_NAME}
 206                         PRE_BUILD
 207                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 208                         COMMAND ${LUA_CHECKER} ${file}
 209                 )
 210                 endforeach()
 211         elseif(LUA_LIST)
 212                 add_custom_command(TARGET ${TARGET_NAME}
 213                         PRE_BUILD
 214                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 215                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: LUA_CHECKER not found. Not verification made on files !")
 216         endif()
 217         if(JSON_CHECKER_PRESENT EQUAL 0)
 218                 foreach(file ${JSON_LIST})
 219                 add_custom_command(TARGET ${TARGET_NAME}
 220                         PRE_BUILD
 221                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 222                         COMMAND ${JSON_CHECKER} ${file}
 223                 )
 224                 endforeach()
 225         elseif(JSON_LIST)
 226         add_custom_command(TARGET ${TARGET_NAME}
 227         PRE_BUILD
 228         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 229         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --red "Warning: JSON_CHECKER not found. Not verification made on files !")
 230         endif()
 231
 232         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 233         DEPENDS ${INPUT_FILES}
 234         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 235         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 236         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
 237         )
 238 endmacro()
 239
 240 # Set the name of the OPENAPI definition JSON file for binding v2
 241 macro(set_openapi_filename openapi_filename)
 242         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
 243 endmacro()
 244
 245 # Common command to call inside project_targets_populate macro
 246 macro(generate_one_populate_target OUTPUTFILES PKG_DESTDIR)
 247         add_custom_command(OUTPUT ${PKG_DESTDIR}/${OUTPUTFILES}
 248                 DEPENDS ${BD}/${OUTPUTFILES}
 249                 COMMAND mkdir -p ${PKG_DESTDIR}
 250                 COMMAND touch ${PKG_DESTDIR}
 251                 COMMAND cp -r ${BD}/${OUTPUTFILES}/* ${PKG_DESTDIR} 2> /dev/null || cp ${BD}/${OUTPUTFILES} ${PKG_DESTDIR}
 252         )
 253
 254         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PKG_DESTDIR}/${OUTPUTFILES})
 255         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 256         add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 257 endmacro()
 258
 259 # To be call inside project_targets_populate macro
 260 macro(afb_genskel)
 261         set (ARGSLIST ${ARGN})
 262
 263         if ("${PROJECT_LANGUAGES}" MATCHES "CXX")
 264                 list(APPEND ARGSLIST "--cpp")
 265         endif()
 266
 267         if (OPENAPI_DEF)
 268                 add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 269                         DEPENDS ${SD}/${OPENAPI_DEF}.json
 270                         COMMAND afb-genskel ${ARGSLIST} ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 271                 )
 272                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 273                         COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 274                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 275         else()
 276                 add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 277                         DEPENDS ${SD}/${OUT}-apidef.json
 278                         COMMAND afb-genskel ${ARGSLIST} ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 279                 )
 280                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 281                         COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 282                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 283         endif()
 284 endmacro()
 285
 286 # Pre-packaging
 287 macro(project_targets_populate)
 288         # Default Widget default directory
 289         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/${BINDIR})
 290         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/${ETCDIR})
 291         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/${LIBDIR})
 292         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/${HTTPDIR})
 293         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/${DATADIR})
 294         # Default test Widget default directory
 295         string(REGEX REPLACE "/([^/]*)$" "/\\1-test" PROJECT_PKG_TEST_DIR "${PROJECT_PKG_BUILD_DIR}")
 296         set(PACKAGE_TEST_BINDIR  ${PROJECT_PKG_TEST_DIR}/${BINDIR})
 297         set(PACKAGE_TEST_ETCDIR  ${PROJECT_PKG_TEST_DIR}/${ETCDIR})
 298         set(PACKAGE_TEST_LIBDIR  ${PROJECT_PKG_TEST_DIR}/${LIBDIR})
 299         set(PACKAGE_TEST_HTTPDIR ${PROJECT_PKG_TEST_DIR}/${HTTPDIR})
 300         set(PACKAGE_TEST_DATADIR ${PROJECT_PKG_TEST_DIR}/${DATADIR})
 301
 302         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR} ${PACKAGE_TEST_BINDIR} ${PACKAGE_TEST_ETCDIR} ${PACKAGE_TEST_LIBDIR} ${PACKAGE_TEST_HTTPDIR} ${PACKAGE_TEST_DATADIR}
 303         COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
 304         COMMAND mkdir -p ${PACKAGE_TEST_BINDIR} ${PACKAGE_TEST_ETCDIR} ${PACKAGE_TEST_LIBDIR} ${PACKAGE_TEST_HTTPDIR} ${PACKAGE_TEST_DATADIR})
 305 add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR} ${PACKAGE_TEST_BINDIR} ${PACKAGE_TEST_ETCDIR} ${PACKAGE_TEST_LIBDIR} ${PACKAGE_TEST_HTTPDIR} ${PACKAGE_TEST_DATADIR})
 306
 307         # Dirty trick to define a default INSTALL command for app-templates handled
 308         # targets
 309         INSTALL(CODE "execute_process(COMMAND make populate)")
 310         if(NO_DEDICATED_INSTALL_DIR)
 311                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 312                         DESTINATION ${CMAKE_INSTALL_PREFIX}
 313                 )
 314         else()
 315                 INSTALL(DIRECTORY ${PROJECT_PKG_BUILD_DIR}/
 316                         DESTINATION ${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME}
 317                 )
 318         endif()
 319
 320         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 321         foreach(TARGET ${PROJECT_TARGETS})
 322                 # Declaration of a custom command that will populate widget tree with the target
 323                 set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
 324                 get_target_property(T ${TARGET} LABELS)
 325
 326                 if(T)
 327                         get_target_property(P ${TARGET} PREFIX)
 328                         get_target_property(S ${TARGET} SUFFIX)
 329                         get_target_property(BD ${TARGET} BINARY_DIR)
 330                         get_target_property(SD ${TARGET} SOURCE_DIR)
 331                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 332
 333                         if(P MATCHES "NOTFOUND$")
 334                                 if (${T} STREQUAL "LIBRARY")
 335                                         set(P "lib")
 336                                 else()
 337                                         set(P "")
 338                                 endif()
 339                         endif()
 340
 341                         get_target_property(IMPPATH ${TARGET} IMPORTED_LOCATION)
 342                         if(${T} STREQUAL "LIBRARY")
 343                                 unset(BD)
 344                                 generate_one_populate_target(${IMPPATH} ${PACKAGE_LIBDIR})
 345                         elseif(${T} STREQUAL "TEST-LIBRARY")
 346                                 unset(BD)
 347                                 generate_one_populate_target(${IMPPATH} ${PACKAGE_TEST_LIBDIR})
 348                         elseif(${T} STREQUAL "PLUGIN")
 349                                 if(NOT S)
 350                                         set(S ".ctlso")
 351                                 endif()
 352                                 generate_one_populate_target(${P}${OUT}${S} "${PACKAGE_LIBDIR}/plugins")
 353                         elseif(${T} STREQUAL "TEST-PLUGIN")
 354                                 if(NOT S)
 355                                         set(S ".ctlso")
 356                                 endif()
 357                                 generate_one_populate_target(${P}${OUT}${S} "${PACKAGE_TEST_LIBDIR}/plugins")
 358                         elseif(${T} STREQUAL "BINDING")
 359                                 if(NOT S)
 360                                         set(S ".so")
 361                                 endif()
 362                                 list(APPEND BINDINGS_LIST "${P}${OUT}${S}")
 363                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 364                                 SET_TARGET_PROPERTIES(${TARGET} PROPERTIES
 365                                         LINK_FLAGS  ${BINDINGS_LINK_FLAG}
 366                                 )
 367                         elseif(${T} STREQUAL "BINDINGV2")
 368                                 if(NOT S)
 369                                         set(S ".so")
 370                                 endif()
 371                                 afb_genskel("-2")
 372                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 373                                 SET_TARGET_PROPERTIES(${TARGET} PROPERTIES
 374                                         LINK_FLAGS  ${BINDINGS_LINK_FLAG}
 375                                 )
 376                         elseif(${T} STREQUAL "BINDINGV3")
 377                                 if(NOT S)
 378                                         set(S ".so")
 379                                 endif()
 380                                 afb_genskel("-3")
 381                                 generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_LIBDIR})
 382                                 SET_TARGET_PROPERTIES(${TARGET} PROPERTIES
 383                                         LINK_FLAGS  ${BINDINGS_LINK_FLAG}
 384                                 )
 385                         elseif(${T} STREQUAL "EXECUTABLE")
 386                                 if(NOT S)
 387                                         set(S "")
 388                                 endif()
 389                                 if(NOT OUT AND IMPPATH)
 390                                         unset(BD)
 391                                         generate_one_populate_target(${IMPPATH} ${PACKAGE_BINDIR})
 392                                 else()
 393                                         generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_BINDIR})
 394                                 endif()
 395                         elseif(${T} STREQUAL "TEST-EXECUTABLE")
 396                                 if(NOT S)
 397                                         set(S "")
 398                                 endif()
 399                                 if(NOT OUT AND IMPPATH)
 400                                         unset(BD)
 401                                         generate_one_populate_target(${IMPPATH} ${PACKAGE_TEST_BINDIR})
 402                                 else()
 403                                         generate_one_populate_target(${P}${OUT}${S} ${PACKAGE_TEST_BINDIR})
 404                                 endif()
 405                         elseif(${T} STREQUAL "HTDOCS")
 406                                 generate_one_populate_target(${P}${OUT} ${PACKAGE_HTTPDIR})
 407                         elseif(${T} STREQUAL "TEST-HTDOCS")
 408                                 generate_one_populate_target(${P}${OUT} ${PACKAGE_HTTPDIR})
 409                         elseif(${T} STREQUAL "DATA" )
 410                                 generate_one_populate_target(${TARGET} ${PACKAGE_DATADIR})
 411                         elseif(${T} STREQUAL "TEST-DATA")
 412                                 generate_one_populate_target(${TARGET} ${PACKAGE_TEST_DATADIR})
 413                         elseif(${T} STREQUAL "BINDING-CONFIG" )
 414                                 generate_one_populate_target(${TARGET} ${PACKAGE_ETCDIR})
 415                         elseif(${T} STREQUAL "TEST-CONFIG")
 416                                 generate_one_populate_target(${TARGET} ${PACKAGE_TEST_ETCDIR})
 417                         endif()
 418                         elseif("${CMAKE_BUILD_TYPE}" MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 419                                 MESSAGE("${Yellow}.. Warning: ${TARGET} ignored when packaging.${ColourReset}")
 420                 endif()
 421         endforeach()
 422 endmacro(project_targets_populate)
 423
 424 macro(remote_targets_populate)
 425         if (DEFINED ENV{RSYNC_TARGET})
 426                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 427         endif()
 428         if (DEFINED ENV{RSYNC_PREFIX})
 429                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 430         endif()
 431
 432         set(
 433                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 434                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 435         )
 436
 437         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 438                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 439                 add_custom_target(remote-target-populate
 440                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 441                         COMMAND exit -1
 442                 )
 443         else()
 444                 set(BINDINGS_REGEX "not_set")
 445                 if(DEFINED BINDINGS_LIST)
 446                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 447                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 448                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 449                                 string(APPEND BINDINGS_REGEX ".so")
 450                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 451                                 foreach(B IN LISTS BINDINGS_LIST)
 452                                         STRING(APPEND BINDINGS_STR "${B}|")
 453                                 endforeach()
 454                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 455                         endif()
 456                 endif()
 457
 458                 configure_files_in_dir(${TEMPLATE_DIR})
 459                 configure_files_in_dir(${TEMPLATE_DIR})
 460
 461                 add_custom_target(remote-target-populate
 462                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 463                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 464                 )
 465
 466                 add_custom_command(TARGET remote-target-populate
 467                 POST_BUILD
 468                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --green --bold ${REMOTE_LAUNCH}
 469                 )
 470
 471                 add_dependencies(remote-target-populate populate)
 472         endif()
 473 endmacro(remote_targets_populate)
 474
 475 macro(wgt_package_build)
 476         if(NOT EXISTS ${TEST_WIDGET_CONFIG_TEMPLATE})
 477                 MESSAGE(STATUS "${BoldBlue}Notice!:Using default test widget configuration's file.\n-- If you want to use a customized test-config.xml template then specify TEST_WIDGET_CONFIG_TEMPLATE in your config.cmake file.${ColourReset}")
 478                 set(TEST_WIDGET_CONFIG_TEMPLATE "${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/test-wgt/test-config.xml.in" CACHE PATH "Path to the test widget config file template (test-config.xml.in)")
 479         endif()
 480         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 481                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 482         endif()
 483         if(NOT WIDGET_TYPE)
 484                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 485         endif()
 486         if(NOT DEFINED PROJECT_ICON)
 487                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 488                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 489                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 490                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 491                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 492                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 493                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 494                         set(ICON_PATH ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 495                 endif()
 496         elseif(EXISTS "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 497                 set(ICON_PATH "${CMAKE_SOURCE_DIR}/${WIDGET_ICON}")
 498         elseif(EXISTS "${WIDGET_ICON}")
 499                 set(ICON_PATH "${WIDGET_ICON}")
 500         else()
 501                 set(ICON_PATH ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/wgt/icon-default.png)
 502         endif()
 503
 504         if(NOT WIDGET_ENTRY_POINT)
 505                 set(WIDGET_ENTRY_POINT lib)
 506         endif()
 507
 508         if(NOT ${CMAKE_BUILD_TYPE} STREQUAL "RELEASE")
 509                 string(TOLOWER "${PROJECT_NAME}-${CMAKE_BUILD_TYPE}" WGT_NAME)
 510         else()
 511                 string(TOLOWER "${PROJECT_NAME}" WGT_NAME)
 512         endif()
 513
 514         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 515         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 516         if(${PROJECT_CONF_FILES})
 517                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 518         endif(${PROJECT_CONF_FILES})
 519
 520         find_program(wgtpkgCMD "wgtpkg-pack")
 521         if(wgtpkgCMD)
 522                 set(packCMD ${wgtpkgCMD} "-f" "-o" "${WGT_NAME}.wgt" ${PROJECT_PKG_BUILD_DIR})
 523                 set(packCMDTest ${wgtpkgCMD} "-f" "-o" "${WGT_NAME}-test.wgt" ${PROJECT_PKG_TEST_DIR})
 524         else()
 525                 find_program(wgtpkgCMD "zip")
 526                 if(wgtpkgCMD)
 527                         set(packCMD ${CMAKE_COMMAND} -E cmake_echo_color --yellow "Warning: Widget will be built using Zip, NOT using the Application Framework widget pack command." && cd ${PROJECT_PKG_BUILD_DIR} && ${wgtpkgCMD} "../${WGT_NAME}.wgt" "*")
 528                         set(packCMDTest ${CMAKE_COMMAND} -E cmake_echo_color --yellow "Warning: Test widget will be built using Zip, NOT using the Application Framework widget pack command." && cd ${PROJECT_PKG_TEST_DIR} && ${wgtpkgCMD} "../${WGT_NAME}-test.wgt" "*")
 529                 else()
 530                         set(packCMD ${CMAKE_COMMAND} -E cmake_echo_color --red "Error: No utility found to build a widget. Either install wgtpkg-pack from App Framework or zip command")
 531                 endif()
 532         endif()
 533
 534         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 535                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 536                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 537         )
 538         add_custom_command(OUTPUT ${PROJECT_PKG_TEST_DIR}/config.xml ${PROJECT_PKG_TEST_DIR}/bin/launcher
 539                 COMMAND ${CMAKE_COMMAND} -DINFILE=${TEST_WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_TEST_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 540                 COMMAND mkdir -p ${PROJECT_PKG_TEST_DIR}/bin
 541                 COMMAND cp ${ICON_PATH} ${PROJECT_PKG_TEST_DIR}/${PROJECT_ICON}
 542                 COMMAND cp ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/test-wgt/launcher.sh.in ${PROJECT_PKG_TEST_DIR}/bin/launcher
 543         )
 544
 545         add_custom_command(OUTPUT ${WGT_NAME}.wgt
 546                 DEPENDS ${PROJECT_TARGETS}
 547                 COMMAND ${packCMD}
 548         )
 549
 550         add_custom_command(OUTPUT ${WGT_NAME}-test.wgt
 551                 DEPENDS ${PROJECT_TARGETS}
 552                 COMMAND ${packCMDTest}
 553         )
 554
 555         if(${BUILD_TEST_WGT})
 556                 add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml ${PROJECT_PKG_TEST_DIR}/config.xml ${PROJECT_PKG_TEST_DIR}/bin/launcher)
 557                 add_custom_target(widget DEPENDS ${WGT_NAME}.wgt ${WGT_NAME}-test.wgt)
 558                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${WGT_NAME}-test.wgt")
 559         else()
 560                 add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 561                 add_custom_target(widget DEPENDS ${WGT_NAME}.wgt)
 562                 add_custom_target(packaging_test_wgt DEPENDS ${PROJECT_PKG_TEST_DIR}/config.xml ${PROJECT_PKG_TEST_DIR}/bin/launcher)
 563                 add_custom_target(test_widget DEPENDS ${WGT_NAME}-test.wgt)
 564         endif()
 565
 566         add_dependencies(widget populate packaging_wgt)
 567         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${WGT_NAME}.wgt")
 568
 569         if(NOT RSYNC_TARGET)
 570                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 571                 add_custom_target(widget-target-install
 572                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 573                         COMMAND exit -1
 574                 )
 575         else()
 576                 configure_files_in_dir(${TEMPLATE_DIR})
 577                 add_custom_target(widget-target-install
 578                         DEPENDS widget
 579                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 580                         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 581                 )
 582         endif()
 583
 584         if(PACKAGE_MESSAGE)
 585         add_custom_command(TARGET widget
 586                 POST_BUILD
 587                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 588         endif()
 589 endmacro(wgt_package_build)
 590
 591 macro(rpm_package_build)
 592         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 593                 DEPENDS ${PROJECT_TARGETS}
 594                                 archive
 595                                 packaging
 596                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 597         )
 598
 599         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 600         add_dependencies(rpm populate packaging)
 601
 602         if(PACKAGE_MESSAGE)
 603         add_custom_command(TARGET rpm
 604                 POST_BUILD
 605                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 606         endif()
 607 endmacro(rpm_package_build)
 608
 609 macro(project_package_build)
 610         if(EXISTS ${TEMPLATE_DIR})
 611                 wgt_package_build()
 612         endif()
 613 endmacro(project_package_build)
 614
 615 macro(project_subdirs_add)
 616         set (ARGSLIST ${ARGN})
 617         list(LENGTH ARGSLIST ARGSNUM)
 618         if(${ARGSNUM} GREATER 0)
 619                 file(GLOB filelist "${ARGV0}")
 620         else()
 621         file(GLOB filelist "*")
 622         endif()
 623
 624         foreach(filename ${filelist})
 625                 if(EXISTS "${filename}/CMakeLists.txt")
 626                         add_subdirectory(${filename})
 627                 elseif(${filename} MATCHES "^.*\\.cmake$")
 628                         include(${filename})
 629                 endif(EXISTS "${filename}/CMakeLists.txt")
 630         endforeach()
 631 endmacro(project_subdirs_add)
 632
 633 # Print developer helper message when build is done
 634 # -------------------------------------------------------
 635 macro(project_closing_msg)
 636         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 637         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 638         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 639                 add_custom_target(${PROJECT_NAME}_build_done ALL
 640                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 641                 )
 642                 add_dependencies(${PROJECT_NAME}_build_done
 643                         ${PROJECT_TARGETS} populate)
 644         endif()
 645 endmacro()
 646
 647 macro(check_version)
 648         if(GIT_PROJECT_VERSION)
 649                 if(${GIT_PROJECT_VERSION} VERSION_GREATER ${APP_TEMPLATES_VERSION})
 650                         message(STATUS "${Yellow}.. Your app-templates submodule version seems outdated. You should update it with 'git submodule update --remote ${PROJECT_APP_TEMPLATES_DIR}'.
 651                 - App-templates version: ${APP_TEMPLATES_VERSION}
 652                 - Project version according AGL Git tag: ${GIT_PROJECT_VERSION}"
 653                 )
 654                 endif()
 655         elseif(PROJECT_VERSION)
 656                 if(${PROJECT_VERSION} VERSION_GREATER ${APP_TEMPLATES_VERSION})
 657                         message(STATUS "${Yellow}.. Your app-templates submodule version seems outdated. You should update it with 'git submodule update --remote ${PROJECT_APP_TEMPLATES_DIR}'.
 658                 - App-templates version: ${APP_TEMPLATES_VERSION}
 659                 - Project version according AGL Git tag: ${PROJECT_VERSION}"
 660                 )
 661                 endif()
 662         else()
 663                 message(STATUS "${Yellow} Your git project repo doesn't have any version tags nor hosted by AGL gerrit infrastructure. Can't compare version between project and app-templates ${APP_TEMPLATES_VERSION} ${ColourReset}")
 664         endif()
 665 endmacro()